[Addicted.]

I have a quick question for you guys.

How would I push a value into an array in a specific location.

For example this puts them to the end of the array:

PHP Code:

new iIndex = FindValueInArray(g_aQueue, iClient);
if(iIndex == -1)
    iIndex = PushArrayCell(g_aQueue, iClient); 


How would I push a value to the front or to a specified location in the array?

[KissLick]

Not exactly sure about that, but I would try to use ShiftArrayUp and then SetArrayCell.

[Addicted.]

Something like this then?

PHP Code:

new iIndex = FindValueInArray(g_aQueue, iClient);
if(iIndex == -1)
{
    if (CheckCommandAccess(iClient, "", ADMFLAG_RESERVATION, true))
    {
        ShiftArrayUp(g_aQueue, 0);
        SetArrayCell(g_aQueue, 0, iClient);
        iIndex = g_aQueue[iClient];
    }

    else
    {
    iIndex = PushArrayCell(g_aQueue, iClient);
    }
} 


[KissLick]

Guess so, I never did something like this.

[Potato Uno]

Why do you want to do this? Maybe a trie (hash map) might work better?

[Addicted.]

Originally Posted by Potato Uno Why do you want to do this? Maybe a trie (hash map) might work better?

I am trying to allow clients with a specific flag to bypass a queue that can be entered by any user via a command.

[Addicted.]

So I tested what I wrote above and it does not seem to be working. Do you guys have any ideas?

[Powerlord]

When you say array, you are talking about an adt_array (aka ArrayList) right?

[KissLick]

Code:

PHP Code:

#include <sourcemod>

public Plugin:myinfo =
{
    name = "Test-Array",
    author = "Raska",
    description = "Test Array",
    version = "0.1",
    url = ""
}

public OnPluginStart()
{
    new Handle:hArray = CreateArray();
    
    PushArrayCell(hArray, 'A');
    PushArrayCell(hArray, 'B');
    PushArrayCell(hArray, 'C');
    PushArrayCell(hArray, 'D');
    
    for (new i = 0; i < GetArraySize(hArray); i++) {
        LogMessage("Array[%d] = '%c'", i, GetArrayCell(hArray, i));
    }
    
    ShiftArrayUp(hArray, 0);
    SetArrayCell(hArray, 0, '+');
    
    for (new i = 0; i < GetArraySize(hArray); i++) {
        LogMessage("Array[%d] = '%c'", i, GetArrayCell(hArray, i));
    }
} 


Log:

PHP Code:

L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[0] = 'A'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[1] = 'B'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[2] = 'C'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[3] = 'D'

L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[0] = '+'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[1] = 'A'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[2] = 'B'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[3] = 'C'
L 06/19/2015 - 17:09:51: [Test-Array.smx] Array[4] = 'D' 


[Addicted.]

Thanks KissLick!

I realized I had to mess around with some other functions too but the ShiftArrayUp then SetArrayCell worked like a charm.