[Supremache]

Hello alliedmoders ,
As what i typed in the title, iam try to remove line from the file.
I created a vip system and i want to add option for remove who has date expired and i have searched for how to do that and found some ways and i used one that recommend by HamletEagle but i got an issue and don't know how to fix it

PHP Code:

RemoveExpired( const szIdentity[ ] )
{
    new const szTempFileName[ ] = "tempfile.ini";

    new szFormat[ 128 ], szData[ 192 ], szIdentity2[ MAX_NAME_LENGTH ];
    
    new szTempFilePath[ 64 ];
    formatex( szTempFilePath, charsmax( szTempFilePath ), "%s/%s", g_szConfigs, szTempFileName );
    formatex( szFormat, charsmax( szFormat ), "%s/%s", g_szConfigs, g_iAccountFile );
    
    new iFilePointer = fopen( szFormat, "rt" );
    
    if( iFilePointer )
    {
        new iInputFilePointer = fopen( szTempFilePath, "wt" )
        if( iInputFilePointer )
        {
            while( fgets( iFilePointer, szData, charsmax( szData ) ) )
            {
                if( szData[ 0 ] != EOS )
                {
                    parse( szData, szIdentity2, charsmax( szIdentity2 ) );
                    trim( szIdentity2 );
                    
                    if( !equali( szIdentity, szIdentity2 ) ) 
                    {
                        fprintf( iInputFilePointer, szData );
                    }
                }
            }
            fclose( iInputFilePointer );
            fclose( iFilePointer );
            delete_file( szFormat ); 
            rename_file( szTempFilePath, szFormat, 1 );
        }
    }
    return 0;
} 


After creating the new file with remove the line of the user who expired the file does not deleted or renamed

Another question: Is it possible to do that by using "TrieDeleteKey" ?

[fysiks]

If you're trying to remove entries based on the timestamp, maybe consider using nvault since it has a built in mechanism to prune the data based on timestamps.

[Supremache]

Originally Posted by fysiks If you're trying to remove entries based on the timestamp, maybe consider using nvault since it has a built in mechanism to prune the data based on timestamps.

No, i created a vip system works like "Name|SteamID" "Pw" "Flags" "Expire Date", if the user has expired will lost his access but i try to add new option for remove the user from the file when expired.

I tried to use stock that i mentioned in the first post:

ReloadFile( )
{
    TrieClear( g_tDatabase );
    
    new g_szFile[ 128 ]
    
    formatex( g_szFile, charsmax( g_szFile ), "%s/%s", g_szConfigs, g_iAccountFile )
    
    new iFile = fopen( g_szFile, "rt" );
    
    if( iFile )
    {
        new szData[ 512 ]
        
        while( fgets( iFile, szData, charsmax( szData ) ) )
        {    
            trim( szData );
            
            switch( szData[ 0 ] )
            {
                case EOS, ';',  '#', '/':
                {
                    continue;
                }

                default:
                {
                    if
                    ( 
                        parse 
                        ( 
                            szData, eData[ Player_Name ]        , charsmax( eData[ Player_Name ] ),
                            eData[ Player_Password ]        , charsmax( eData[ Player_Password ] ),
                            eData[ Player_AccessFlags ]  , charsmax( eData[ Player_AccessFlags ] ),
                            eData[ Player_Expire_Date ]  , charsmax( eData[ Player_Expire_Date ] ) 
                        ) < 4 
                    )
                    {
                        continue;
                    }
                    
                    if( eData[ Player_Expire_Date ][ 0 ] )
                    {
                        if( HasDateExpired( eData[ Player_Expire_Date ] ) )
                        {
                            eData[ Player_Suspended ] = true;
                            RemoveExpired( eData[ Player_Name ] );
                        }
                    }
                    
                    if( eData[ Player_Name ][ 0 ] )
                    {
                        TrieSetArray( g_tDatabase, eData[ Player_Name ], eData, sizeof eData );
                    }
                    
                    arrayset( eData, 0, sizeof( eData ) );
                }
            }
        }
        fclose( iFile );
    }
}

It's work like create a new file without line of the user who expired and delete old file and rename the new file but as you see the old file didn't deleted etc..


I'm not sure if i can do that using "TrieDeleteKey" but tried and it did not work:

PHP Code:

CheckPlayerVIP( id )
{
    new szPassword[ 18 ];

    get_user_info( id, "_pw", szPassword, charsmax( szPassword ) );
        
    if( TrieGetArray( g_tDatabase, g_iPlayer[ id ][ AuthID ], eData, sizeof eData ) || TrieGetArray( g_tDatabase, g_iPlayer[ id ][ Name ], eData, sizeof eData ) )
    {
        if( ( eData[ Player_Password ][ 0 ] && equal( eData[ Player_Password ], szPassword ) ) || !eData[ Player_Password ][ 0 ] )
        {
            if( eData[ Player_Suspended ]  && ! eData[ Player_AccessFlags ][ 0 ] )
            {
                g_iPlayer[ id ][ VIP ] = 0;
                g_iPlayer[ id ][ VIP ] = read_flags( "z" );
                TrieDeleteKey( g_tDatabase, eData[ Player_Name ] )
                return PLUGIN_HANDLED;
            }
            else
            {
                g_iPlayer[ id ][ VIP ] |= read_flags( eData[ Player_AccessFlags ] );
                return PLUGIN_HANDLED;
            }
        }
        else if( eData[ Player_Password ][ 0 ] && ! equal( eData[ Player_Password ], szPassword ) )
        {
            server_cmd( "kick #%d ^"You have no entry to this server^"", get_user_userid( id ) );   
        }
    }
    
    return PLUGIN_CONTINUE;
} 


[OciXCrom]

TrieDeleteKey() will remove the item from the trie, not the actual file. You must recreate the entire file in order to remove a line.

Not sure what's exactly wrong in your code, but I can offer you a "cleaner" way of doing it.

Instead of making a temporary file, renaming and deleting it, store all lines of your file in a dynamic array when reading it, EXCEPT the lines that are already expired.

Then, after closing the file, open it again in write mode, loop through the array and write all lines. Pseudo-code:

new szFile[256]
get_configsdir(szFile, charsmax(szFile))
add(szFile, charsmax(szFile), "/YourFile.ini") // cleaner way with only 1 variable

new iFilePointer = fopen(szFile, "r") // open the file in "read" mode

if(iFilePointer)
{
    const MAX_LINE_LENGTH = 256
    new Array:aArray = ArrayCreate(MAX_LINE_LENGTH)

    new iLinesInFile // this will count the number of non-expired lines in the file when reading
    new bool:bShouldRewrite // this will determine whether the file should be rewritten

    new szData[MAX_LINE_LENGTH]

    while(!feof(iFilePointer))
    {
        fgets(iFilePointer, szData, charsmax(szData))
        trim(szData)

        if(/* line is expired */)
        {
            // at least one line has expired - entire file needs to be rewritten in order to remove the line(s)
            bShouldRewrite = true
        }
        else
        {
            // store the non-expired line in the array
            iLinesInFile++
            ArrayPushString(aArray, szData)
        }
    }

    fclose(iFilePointer)

    if(bShouldRewrite)
    {
        iFilePointer = fopen(szFile, "w") // open the file in "write" mode

        for(new i; i < iLinesInFile; i++) // loop through the array and write each line in the file
        {
            fprintf(iFilePointer, "%a^n", ArrayGetStringHandle(aArray, i)) // %a is used to get a string directly from a dynamic array
        }

        fclose(iFilePointer)
    }

    ArrayDestroy(aArray)
}

[Supremache]

I tested your code but i got a warrning message while complie the plugin in this line:

PHP Code:

fprintf(iFilePointer, "%a^n", ArrayGetStringHandle(g_aFileContents, i)) 


I changed g_aFileContents to aArray but i get this error and the file rewrite as empty without store the data.

L 02/12/2022 - 03:26:16: Invalid index 3 (count: 3) L 02/12/2022 - 03:26:16: [AMXX] Displaying debug trace (plugin "VipSystem.amxx", version "1.0.3") L 02/12/2022 - 03:26:16: [AMXX] Run time error 10: native error (native "ArrayGetStringHandle") L 02/12/2022 - 03:26:16: [AMXX] [0] VIPSystem.sma::ReloadFile (line 494) L 02/12/2022 - 03:26:16: [AMXX] [1] VIPSystem.sma::plugin_init (line 96)

[OciXCrom]

Try removing the +1 in the loop.
Code updated.

[Supremache]

Originally Posted by OciXCrom Try removing the +1 in the loop. Code updated.

It's work like delete all lines except for who are not expired but i think it is not helpful because if someone put this symbol ; for disabling something will be deleted too.

Exmaple:

#Confing file "Pro1" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2018 00:00:00" "Pro2" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2019 00:00:00" ;"Pro3" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2020 00:00:00" "Pro4" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2021 00:00:00" "Pro5" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2022 00:00:00" "Pro6" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2023 00:00:00" ;"Pro7" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2026 00:00:00"

"Pro5" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2022 00:00:00" "Pro6" "123+" "abcdefghijklmnopqrstuvwxy" "12/31/2023 00:00:00"

Is there another way to do that ? or what is the wrong i did in stock that i mentioned in the first post

[OciXCrom]

Simply check for that symbol and make an exception?... You already have a code that checks if it is a comment - store the comments in the array too.

[Supremache]

Originally Posted by OciXCrom Simply check for that symbol and make an exception?... You already have a code that checks if it is a comment - store the comments in the array too.

I did but i checked five symbols also using array with trie in the same function i think this is not good, anyway i known a new thing.
Thank you