[Addicted.]

I have been working on a plugin for my community where cts can open a gun menu and the selection is saved in a mysql db. I have gotten that part down but I am facing a problem when trying to spawn them with those weapons at the beginning of each round.

PHP Code:

public SQLGiveWeapon(Handle:owner, Handle:hndl, const String:error[], any:data)
{
    if (!IsClientInGame(data) || !IsPlayerAlive(data) || !IsClientAuthorized(data) || GetClientTeam(data) != 3)
    {
        return;
    }

    if (hndl == INVALID_HANDLE)
    {
        LogError("Query failed! %s", error);
        CPrintToChat(data, "[{blue}Guns{default}] {red}Query failed!{default}");        
    }
    
    else if (!SQL_GetRowCount(hndl)) 
    {
        return;
    }
    
    new String:Primary[1256];
    new String:Secondary[1256];
    
    SQL_FetchString(hndl, 0, Primary, sizeof(Primary));
    SQL_FetchString(hndl, 1, Secondary, sizeof(Secondary));
    
    new weapon = GetPlayerWeaponSlot(data, 0);
    RemovePlayerItem(data, weapon);    
    weapon = GetPlayerWeaponSlot(data, 1);
    RemovePlayerItem(data, weapon);    

    ServerCommand("sm_weapon \"%N\" \"%s\"", data, Primary);    
    ServerCommand("sm_weapon \"%N\" \"%s\"", data, Secondary);
}

public Action:OnPlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if (GetClientTeam(client) != 3)
    {
        return;
    }
    
    decl String:query[128];
    decl String:steamID[64];
            
    GetClientAuthId(client, AuthId_Steam2, steamID, sizeof(steamID));
    
    Format(query, sizeof(query), "SELECT Primary_Weapon, Secondary_Weapon FROM guardweaponchoice WHERE steamid = '%s'", steamID);
    SQL_TQuery(db, SQLGiveWeapon, query, client);
} 


This is what the database looks like:


There are no errors being logged.

[xerox8521]

you might need to add weapon_ either in the db or in the ServerCommand

[Addicted.]

Originally Posted by xerox8521 you might need to add weapon_ either in the db or in the ServerCommand

No the weapon plugin I am using working without the weapon_ prefix.

https://forums.alliedmods.net/showthread.php?t=195476

[h3bus]

Replace

PHP Code:

    else if (!SQL_GetRowCount(hndl)) 
    {
        return;
    } 


by

PHP Code:

    else if (!SQL_FetchRow(hndl)) 
    {
        return;
    } 


And you should have a "return" in

PHP Code:

if (hndl == INVALID_HANDLE) 


[Kailo]

I solved this.
1st, no SQL_FetchRow(hndl); before

SQL_FetchString(hndl, 0, Primary, sizeof(Primary)); 
SQL_FetchString(hndl, 1, Secondary, sizeof(Secondary));

2nd, no check if player don't have weapon.

new weapon = GetPlayerWeaponSlot(data, 0); 
RemovePlayerItem(data, weapon);     
weapon = GetPlayerWeaponSlot(data, 1); 
RemovePlayerItem(data, weapon);

[Addicted.]

Thanks for the great help!

PHP Code:

public SQLGiveWeapon(Handle:owner, Handle:hndl, const String:error[], any:data)
{
    if (!IsClientInGame(data) || !IsPlayerAlive(data) || !IsClientAuthorized(data) || GetClientTeam(data) != 3)
    {
        return;
    }

    if (hndl == INVALID_HANDLE)
    {
        LogError("Query failed! %s", error);
        CPrintToChat(data, "[{blue}Guns{default}] {red}Query failed!{default}");        
    }
    
    else if (!SQL_GetRowCount(hndl)) 
    {
        return;
    }
    
    new String:Primary[1256];
    new String:Secondary[1256];
    
    SQL_FetchRow(hndl);
    SQL_FetchString(hndl, 0, Primary, sizeof(Primary));
    SQL_FetchString(hndl, 1, Secondary, sizeof(Secondary));
    
    new weapon = -1;
    if ((weapon = GetPlayerWeaponSlot(data, 0)) != -1)
        RemovePlayerItem(data, weapon);    
    if ((weapon = GetPlayerWeaponSlot(data, 1)) != -1)
        RemovePlayerItem(data, weapon);    

    if (strlen(Primary))
        ServerCommand("sm_weapon \"%N\" \"%s\"", data, Primary);
    if (strlen(Secondary))
        ServerCommand("sm_weapon \"%N\" \"%s\"", data, Secondary);
} 


[Darkness_]

PHP Code:

ServerCommand("sm_weapon \"%N\" \"%s\"", data, Primary); 


Here you are targeting their them by name, which is dangerous. Instead target them by the userid that corresponds to their client index. Like so

PHP Code:

ServerCommand("sm_weapon \"#%i\" \"%s\"", GetClientUserId(data), Primary); 


I explained why this practice is so important here.

[Addicted.]

Originally Posted by Darkness_ PHP Code: ServerCommand("sm_weapon \"%N\" \"%s\"", data, Primary);  Here you are targeting their them by name, which is dangerous. Instead target them by the userid that corresponds to their client index. Like so PHP Code: ServerCommand("sm_weapon \"#%i\" \"%s\"", GetClientUserId(data), Primary);  I explained why this practice is so important here.

Just changed it, I think I had seen your post before but I had forgot about it.

Thanks for the heads up.