[Wooky_]

PHP Code:

#include <sourcemod>

public Plugin:myinfo = 
{
    name = "Music Kit Valve",
    author = "Wooky",
    description = "give music kit",
    version = "1.0",
    url = "http://steamcommunity.com/id/wooky01"
} 

public OnPluginStart()
{
    RegConsoleCmd("sm_kit", testik);
}

public Action testik(client, args)
{
    new Handle:menu = CreateMenu(test, MenuAction_Select | MenuAction_End);
    SetMenuTitle(menu, "MUSIC KIT");

    AddMenuItem(menu, "jedna", "default");
    AddMenuItem(menu, "tri", "Daniel Sadowski, Crimson Assault"); 
    
}

public test(Handle:menu, MenuAction:action, param1, param2, client)
{
    switch (action)
    {
        case MenuAction_Select:
        {
            //param1 is client, param2 is item

            new String:item[64];
            GetMenuItem(menu, param2, item, sizeof(item));

            if (StrEqual(item, "jedna"))
            {
              SetEntProp(client, Prop_Send, "m_unMusicID", 1);
            }
            else if (StrEqual(item, "tri"))
            {
                SetEntProp(client, Prop_Send, "m_unMusicID", 3);
            }
        }

        case MenuAction_End:
        {
            //param1 is MenuEnd reason, if canceled param2 is MenuCancel reason
            CloseHandle(menu);

        }

    }
} 


(19) : error 100: function prototypes do not match

I'm confused....

[Halt]

What line is 19?

Edit:

PHP Code:

#include <sourcemod>

public Plugin:myinfo = 
{
name = "Music Kit Valve",
author = "Wooky",
description = "give music kit",
version = "1.0",
url = "http://steamcommunity.com/id/wooky01"
} 

public OnPluginStart()
{
    RegConsoleCmd("sm_kit", testik);
}

public Action testik(client, args)
{
    new Handle:menu = CreateMenu(test, MenuAction_Select | MenuAction_End);
    SetMenuTitle(menu, "MUSIC KIT");

    AddMenuItem(menu, "jedna", "default");
    AddMenuItem(menu, "tri", "Daniel Sadowski, Crimson Assault"); 
}

public test(Handle:menu, MenuAction:action, param1, param2)
{
    switch (action)
    {
    case MenuAction_Select:
    {
    //param1 is client, param2 is item

    new String:item[64];
    GetMenuItem(menu, param2, item, sizeof(item));

    if (StrEqual(item, "jedna"))
    {
    SetEntProp(param1, Prop_Send, "m_unMusicID", 1);
    }
    else if (StrEqual(item, "tri"))
    {
    SetEntProp(param1, Prop_Send, "m_unMusicID", 3);
    }
    }

    case MenuAction_End:
    {
    //param1 is MenuEnd reason, if canceled param2 is MenuCancel reason
    CloseHandle(menu);
    }
    }
} 


1. Next time use [PHP and /PHP] or [CODE and /CODE] if you want help. Most people will ignore your post if you half ass it.
2. You didn't need client on lines 40 & 44. Param1 acts as the client index.

[Wooky_]

I'am so sorry . 19line is new Handle:menu = CreateMenu(test, MenuAction_Select | MenuAction_End

[Neuro Toxin]

For the love of god, put ur code in code blocks. Dont expect us to copy paste and nest your code just to try and help you.

[fiction]

Quite a few more errors than that. That specific error is because of this line:

PHP Code:

public test(Handle:menu, MenuAction:action, param1, param2, client) 


That 5th paramter doesn't exit, it's just menu, action, param1 and param2. Adding any more will give you the function prototypes do not match error.
Try this and read over the menu api: https://wiki.alliedmods.net/Menu_API_(SourceMod)

PHP Code:

#include <sourcemod>

public Plugin myinfo = {
    name = "Music Kit Valve",
    author = "Wooky",
    description = "give music kit",
    version = "1.0",
    url = "http://steamcommunity.com/id/wooky01"
}

public void OnPluginStart()
{
    RegConsoleCmd("sm_kit", Command_Kit);
}

public Action Command_Kit(int client, int args)
{
    Menu menu = new Menu(MenuHandler_Kit);
    menu.SetTitle("MUSIC KIT");

    menu.AddItem("jedna", "default");
    menu.AddItem("tri", "Daniel Sadowski, Crimson Assault"); 
    
    menu.Display(client, MENU_TIME_FOREVER);
    return Plugin_Handled;
}

public int MenuHandler_Kit(Menu menu, MenuAction action, int param1, int param2)
{
    switch(action)
    {
        case MenuAction_Select:
        {
            char sInfo[64];
            if (!menu.GetItem(param2, sInfo, sizeof(sInfo)))
                return 0;

            if (StrEqual(sInfo, "jedna"))
            {
                SetEntProp(param1, Prop_Send, "m_unMusicID", 1);
            }
            else if (StrEqual(sInfo, "tri"))
            {
                SetEntProp(param1, Prop_Send, "m_unMusicID", 3);
            }
        }
        case MenuAction_End:
        {
            delete menu;
        }
    }
} 


[Wooky_]

Thank you so much everyone . I use/php next time.

[B3none]

Originally Posted by Neuro Toxin For the love of god, put ur code in code blocks. Dont expect us to copy paste and nest your code just to try and help you.

Agreed. Wrap your code in PHP tags

[Wooky_]

I would also like to ask. How to set the values you've chosen to retain after changing the map.

[Neuro Toxin]

Store them in globals.