Menu System

RuRuRu612754 · **Author**

We review how to create a menu.
However, fail to compile.
Is there a mistake where?

PHP Code:


			
#include <amxmodx>



public plugin_init()

{

    register_plugin("Choose Menu", "1.0.0", "AMX Mod X")





    register_clcmd( "choose_menu", "create_choose_menu")



    register_dictionary("choose_menu.txt")

}



public create_choose_menu(id)

{

    new menu = menu_create("%L", "CHOOSE_MENU_NAME", "show_choose_menu")



    menu_additem(menu, "%L", "CHOOSE_MENU_ITEM_1", "1", 0)

    menu_additem(menu, "%L", "CHOOSE_MENU_ITEM_2", "2", 0)

    menu_additem(menu, "%L", "CHOOSE_MENU_ITEM_3", "3", 0)



    menu_addblank(menu)



    menu_addtext(menu, "%L", "CHOOSE_MENU_TEXT")



    menu_display(id, menu, 0)

}



public show_choose_menu(id, menu, item)

{

    new data[6], szName[64]

    new access, callback



    menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback)



    new key = str_to_num(data)



    switch(key)

    {

        case 1:

        {

            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_1")

        }

        case 2:

        {

            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_2")

        }

        case 3:

        {

            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_3")

        }

    }

    menu_destroy(menu)



    return PLUGIN_HANDLED

}

ConnorMcLeod · 02-04-2012 , 08:45 Re: Menu System

Learn first how to use ML system.
And then, format menu strings in an array and use this array in menu_additem.

RuRuRu612754 · 02-04-2012 , 20:14 Re: Menu System

@ConnorMcLeod

Thanks!!
omg. need format?
i cannot format

Zer0Cool · 02-05-2012 , 05:04 Re: Menu System

Hello.
This should work

PHP Code:


			
#include <amxmodx> 
public plugin_init() 
{ 
    register_plugin("Choose Menu", "1.0.0", "AMX Mod X") 

    register_clcmd( "choose_menu", "create_choose_menu") 
    register_dictionary("choose_menu.txt") 
}
public create_choose_menu(id) 
{ 
    new szText[ 555 char ];
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_NAME" );
    new menu = menu_create( szText, "shop_handler" );
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_1" );
    menu_additem( menu, szText, "1", 0 ); 
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_2" );
    menu_additem( menu, szText, "2", 0 );
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_3" );
    menu_additem( menu, szText, "3", 0 );
    menu_display(id, menu, 0) 
}
public show_choose_menu(id, menu, item) 
{ 
    new data[6], szName[64] 
    new access, callback 
    menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback) 
    new key = str_to_num(data) 
    switch(key) 
    { 
        case 1: 
        { 
            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_1") 
        } 
        case 2: 
        { 
            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_2") 
        } 
        case 3: 
        { 
            client_print(id, print_chat, "%L", "CHOOSE_MENU_MESSAGE_3") 
        } 
    } 
    menu_destroy(menu) 
    return PLUGIN_HANDLED 
}

RuRuRu612754 · 02-05-2012 , 09:22 Re: Menu System

@Zer0Cool

Hello.
Character has been displayed properly.
This "show_amxx_menu" but will not be executed.
I modified your code a little
Do you have a problem where?

amxx_menu.sma

PHP Code:


			
#include <amxmodx>



public plugin_init()

{

    register_plugin("amxx_menu", "1.0.0", "AMX Mod X")



    register_clcmd("amxx_menu", "create_amxx_menu")



    register_dictionary("amxx_menu.txt")

}



public create_amxx_menu(id)

{

    new szText[555 char]



    formatex(szText, charsmax(szText), "%L", id, "AMXX_MENU_NAME")

    new menu = menu_create(szText, "show_amxx_menu")



    formatex(szText, charsmax(szText), "%L", id, "AMXX_MENU_ITEM_1")

    menu_additem(menu, szText, "1", 0)

    formatex(szText, charsmax(szText), "%L", id, "AMXX_MENU_ITEM_2")

    menu_additem(menu, szText, "2", 0)

    formatex(szText, charsmax(szText), "%L", id, "AMXX_MENU_ITEM_3")

    menu_additem(menu, szText, "3", 0)



    menu_addblank(menu)



    formatex(szText, charsmax(szText), "%L", id, "AMXX_MENU_TEXT")

    menu_addtext(menu, szText)



    menu_display(id, menu, 0)

}

public show_amxx_menu(id, menu, item)

{

    new data[6], szName[64]

    new access, callback



    menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback)



    new key = str_to_num(data)



    switch(key)

    { 

        case 1:

        { 

            client_print(id, print_chat, "%L", "AMXX_MENU_MESSAGE_1")

        }

        case 2:

        {

            client_print(id, print_chat, "%L", "AMXX_MENU_MESSAGE_2")

        }

        case 3:

        {

            client_print(id, print_chat, "%L", "AMXX_MENU_MESSAGE_3")

        }

    }

    menu_destroy(menu)



    return PLUGIN_HANDLED

}

amxx_menu.txt

PHP Code:


			
[en]

AMXX_MENU_NAME = \gAMXX Menu :

AMXX_MENU_ITEM_1 = \wAMXX Item 1

AMXX_MENU_ITEM_2 = \wAMXX Item 2

AMXX_MENU_ITEM_3 = \wAMXX Item 3

AMXX_MENU_TEXT = AMXX Menu 1.0.0 by AMX Mod X

AMXX_MENU_MESSAGE_1 = You serect AMXX Item 1

AMXX_MENU_MESSAGE_2 = You serect AMXX Item 2

AMXX_MENU_MESSAGE_3 = You serect AMXX Item 3

ConnorMcLeod · 02-05-2012 , 10:07 Re: Menu System

PHP Code:


			
#include <amxmodx>

public plugin_init() 
{ 
    register_plugin("Choose Menu", "1.0.0", "AMX Mod X") 

    register_clcmd( "choose_menu", "create_choose_menu") 
    register_dictionary("amxx_menu.txt") 
}

public create_choose_menu(id) 
{ 
    new szText[128]
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_NAME" )
    new menu = menu_create( szText, "choose_menu_handled" )
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_1" )
    menu_additem( menu, szText)
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_2" )
    menu_additem( menu, szText)
    formatex( szText, charsmax( szText ), "%L", id, "CHOOSE_MENU_ITEM_3" )
    menu_additem( menu, szText)
    menu_display(id, menu) 
}

public choose_menu_handled(id, menu, item) 
{
    switch(item) 
    { 
        case 0: 
        { 
            client_print(id, print_chat, "%L", id, "CHOOSE_MENU_MESSAGE_1") 
        } 
        case 1: 
        { 
            client_print(id, print_chat, "%L", id, "CHOOSE_MENU_MESSAGE_2") 
        } 
        case 2: 
        { 
            client_print(id, print_chat, "%L", id, "CHOOSE_MENU_MESSAGE_3") 
        } 
    } 
    menu_destroy(menu) 
    return PLUGIN_HANDLED 
}

RuRuRu612754 · 02-06-2012 , 03:23 Re: Menu System

@ConnorMcLeod

Thnaks!!
Was operating normally.
Where is the problem?

ConnorMcLeod · 02-06-2012 , 11:36 Re: Menu System

handlers/callbacks names were not matching.
ML was not used correctly in menu handler.