[joaquimandrade]

I was reading the pawn manual when i stepped into a topic called "Automatons". I had studied it in the university so it wasn't news for me.
I've searched the forums to see if there were some known good use to them but just find this:

https://forums.alliedmods.net/showpo...11&postcount=2

Anyway, i have a use for it. It may give you ideas for use them somehow that it can improve plugins performance.

The code below can be used to enable/disable a Ham Forward without if clauses and without need to check if it registered.

Is it an improvement to the "normal" process? I don't know. I guess it is but, is safer to ask anyone that knows how to analyze compiled code.

PHP Code:


#include <amxmodx>
#include <hamsandwich>

#define PLUGIN    "Automaton"
#define AUTHOR    "Albernaz o Carniceiro Demoniaco"
#define VERSION    "1.0"

new HamHook:HamHookSpawn

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)        
    
    // The start point: unregistered 
    
    state unregistered;
}

public enableHam() <unregistered>
{
    // If it's unregistered and is wanted to be enabled, it must be registered
    
    HamHookSpawn = RegisterHam(Ham_Spawn,"player","playerSpawn");
    state enabled;
}

public enableHam() <disabled>
{
    // If it's disabled and is wanted to be enabled, it must be enabled
    
    EnableHamForward(HamHookSpawn);    
    state enabled;
}

public enableHam() <enabled> {}
public disableHam() <unregistered,disabled>{}
/*

The above two line can be:

public enableHam() <> {}
public disableHam() <>{}


*/


public disableHam() <enabled>
{    
    // If it's enabled and is wanted to be disabled, it must be disabled
    
    DisableHamForward(HamHookSpawn);    
    state disabled;
}

public playerSpawn(id)
{
    
} 


With the code above you would then do "enableHam()" to enable the forward, "disableHam()" to disable it.


Light version:

PHP Code:

#include <amxmodx>
#include <hamsandwich>

 #define PLUGIN    "Automaton"
#define AUTHOR    "Albernaz o Carniceiro Demoniaco"
#define VERSION    "1.0"

new HamHook:HamHookSpawn

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)                
    state unregistered;
}

public enableHam() <unregistered> state (HamHookSpawn = RegisterHam(Ham_Spawn,"player","playerSpawn") ) enabled;
public enableHam() <disabled> state (EnableHamForward(HamHookSpawn)) enabled;
public disableHam() <enabled> state (!DisableHamForward(HamHookSpawn)) disabled;
public enableHam() <> {}
public disableHam() <>{}

public playerSpawn(id)
{
    
} 


Debug version:

PHP Code:

#include <amxmodx>
#include <hamsandwich>

 #define PLUGIN    "Automaton"
#define AUTHOR    "Albernaz o Carniceiro Demoniaco"
#define VERSION    "1.0"

new HamHook:HamHookSpawn

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)        
    
    register_clcmd("enable","enable");
    register_clcmd("disable","disable");
        
    state unregistered;
}

public enable()
{
    enableHam()
    return PLUGIN_HANDLED;
}

public disable()
{
    disableHam()
    return PLUGIN_HANDLED;
}

public enableHam() <unregistered>
{
    HamHookSpawn = RegisterHam(Ham_Spawn,"player","playerSpawn");
    state enabled
    
    server_print("Registering");
}

public enableHam() <disabled>
{
    EnableHamForward(HamHookSpawn);    
    state enabled;
    
    server_print("Enabling");
}

public disableHam() <enabled>
{    
    DisableHamForward(HamHookSpawn);    
    state disabled;
    
    server_print("Disabling");
}

public enableHam() <> 
{
    server_print("Already enabled");
}
public disableHam() <>
{
    server_print("Already disabled");
}

public playerSpawn(id)
{
    
} 


Debug version usage output:

PHP Code:

] enable
Registering
] enable 
Already enabled
] disable
Disabling
] disable 
Already disabled
] enable
Enabling
] enable 
Already enabled 


[abdul-rehman]

Sorry to *Bump*
But can u give more examples on this

[Arkshine]

You can see a simple example in the InfiniteRound plugin. If I remember well, there are some more explanations in the Pawn guide.

[Seta00]

Don't use this or Albernaz o Carniceiro Demoniaco will come to get you.

[Exolent[jNr]]

Adding to the tutorial:

When using automatons on functions that have parameters:

saySomthing(id) <>
{
    client_print(id, print_chat, "This message is first time being sent, and the only time.");
    state disabled;
}

saySomething(id) <disabled>
{
    // compiler will say "id" is never used
}

To go around this, we can use a pre-compiler directive called #pragma.
In this situation, we will use #pragma unused.

saySomthing(id) <>
{
    client_print(id, print_chat, "This message is first time being sent, and the only time.");
    state disabled;
}

saySomething(id) <disabled>
{
    // tells the compiler that it is okay that the variable is never used
    #pragma unused id
}

To learn more pre-compiler directives or more information about #pragma, read the Pawn manual.

[ConnorMcLeod]

Or just do :

saySomething() <disabled>
{

}

LoL

[Arkshine]

The header has to be the same. ;)

@Exolent[jNr] : I don't have this problem. Paste the whole code.

[Exolent[jNr]]

Originally Posted by Arkshine @Exolent[jNr] : I don't have this problem. Paste the whole code.

I've experienced this is my own plugins, but I'm sure this example will also produce the same result.

PHP Code:

#include < amxmodx >

public plugin_init( )
{
    register_plugin( "Automaton Function Parameter Test", "0.0.1", "Exolent" );
    
    register_clcmd( "say /print", "CmdPrint" );
}

public CmdPrint( iPlayer )
{
    printSomething( iPlayer );
}

printSomething( iPlayer ) <>
{
    client_print( iPlayer, print_chat, "Message." );
    state printed;
}

printSomething( iPlayer ) <printed>
{
    // compiler says
    // warning 203: symbol is never used: "iPlayer"
} 


PHP Code:

#include < amxmodx >

public plugin_init( )
{
    register_plugin( "Automaton Function Parameter Test", "0.0.1", "Exolent" );
    
    register_clcmd( "say /print", "CmdPrint" );
}

public CmdPrint( iPlayer )
{
    printSomething( iPlayer );
}

printSomething( iPlayer ) <>
{
    client_print( iPlayer, print_chat, "Message." );
    state printed;
}

printSomething( iPlayer ) <printed>
{
    // compiler is happy
    #pragma unused iPlayer
} 


It also seems that if the function is public then the compiler does not care if the parameters are unused.

PHP Code:

#include < amxmodx >

public plugin_init( )
{
    register_plugin( "Automaton Function Parameter Test", "0.0.1", "Exolent" );
    
    register_clcmd( "say /print", "CmdPrint" );
}

public CmdPrint( iPlayer )
{
    printSomething( iPlayer );
}

printSomething( iPlayer ) <>
{
    client_print( iPlayer, print_chat, "Message." );
    state printed;
}

public printSomething( iPlayer ) <printed>
{
    // compiler is happy
} 


It is also strange that the compiler would allow one of them to be public and the other private.

[Arkshine]

I remember having the same issue when coding InfiniteRound, that's why I've used "public" as solution. Though no idea why there is this behavior.

[Seta00]

Originally Posted by Arkshine I remember having the same issue when coding InfiniteRound, that's why I've used "public" as solution. Though no idea why there is this behavior.

Because when calling public functions you don't have access to its signature, just like you don't have access to natives' signatures.