[Tauphi]

hello,

for my public servers i would like to a plugin, which makes it possible, that i as alive player can read, what dead people write ...

generally no problem, i can hook the say commands and can send messages from dead player to alive players, too ...

but ... is it possible to create colored nicknames in red or blue? tried the \xxx values ... but only green is working :-(

thx for help

[ferret]

Put in a feature request and I'll consider adding this to basecomm as part of sm_deadtalk.

[Tauphi]

and what about the blue and red text colors ? is it possible to use them in scripts ?

[ferret]

I've seen it done but I don't remember the exact method off the top of my head.

[Tauphi]

do you think you can find it out again? how to color chat text red or blue would interest me for different ideas

[Tauphi]

ah i found it ... messages have to start with \x01 to enable the color mode ... but the printToChat() function use always the green color instead of the team color ...

with this function

PHP Code:

stock SayText2( client_index , author_index , const String:message[] ) {
   new Handle:buffer = StartMessageOne("SayText2", client_index);
   if (buffer != INVALID_HANDLE) {
      BfWriteByte(buffer, author_index);
      BfWriteByte(buffer, true);
      BfWriteString(buffer, message);
      EndMessage();
   }
} 


and this call

PHP Code:

SayText2(xxx,client,"\x01 This word is red or blue: \x03 colored_text"); 


the "colored_text" should be red or blue ...

[Tauphi]

a working version for cs:s ... alive players can read the chat of dead players ...

PHP Code:

#include <sourcemod>
#include <sdktools>

#define PLUGIN_VERSION "1.0.0"

#define TEAM_T 2
#define TEAM_CT 3

new maxclients;

public Plugin:myinfo = {
    name = "DeadChat",
    author = "tF",
    description = "Read what dead people chat",
    version = PLUGIN_VERSION,
    url = "http://www.saigns.de"
};

public OnPluginStart() {
    maxclients = GetMaxClients();
    RegConsoleCmd("say", Command_Say);
}

public OnMapStart() {
    maxclients = GetMaxClients();
}

public Action:Command_Say(client, args) {
    new myteam = GetClientTeam(client);
    if ( !IsPlayerAlive(client) && (myteam == TEAM_T || myteam == TEAM_CT) ) {
        new String:message[255];
        GetCmdArgString(message,255);

        new startidx = 0
        if (message[0] == '"') {
            startidx = 1;
            /* Strip the ending quote, if there is one */
            new len = strlen(message);
            if (message[len-1] == '"') {
                message[len-1] = '\0';
            }
        }

        new String:name[32];
        GetClientName(client,name,sizeof(name));

        new String:nm[255];
        Format(nm,sizeof(nm),"\x01 *DEAD* \x03%s \x01: %s",name,message[startidx]);

        for( new to = 1 ; to <= maxclients ; to++ ) {
            if( !IsClientInGame(to) || !IsValidEdict(to) || !IsPlayerAlive(to) ) continue;
            SayText2(to,client,nm);
        }
    }
    return Plugin_Continue;
}

stock SayText2( client_index , author_index , const String:message[] ) {
    new Handle:buffer = StartMessageOne("SayText2", client_index);
    if (buffer != INVALID_HANDLE) {
        BfWriteByte(buffer, author_index);
        BfWriteByte(buffer, true);
        BfWriteString(buffer, message);
        EndMessage();
    }
} 


[ferret]

Yes, currently to use the team color you have to send the message as SayText2 directly. I'll have to look into getting a direct native for it setup.

[bjornwitteman]

Originally Posted by ferret Yes, currently to use the team color you have to send the message as SayText2 directly. I'll have to look into getting a direct native for it setup.

is there a also code that only admins can see deathchat??