[fysiks]

That's why I asked for more code. It's important where you build the menu. It will never work in plugin_init().

You need a function that builds the menu when the command is used. "plr" or "id" is the entity number of whoever is using the command.

[lolzin123]

can you help me at the construction of this?

[fysiks]

Try this. say /testmenu.

<attachment removed>

[lolzin123]

oh
thanx man!!!
but how i do this with this menu?

PHP Code:

gMainMenu = menu_create("\rBCM4 by joker.", "mnuMain", 0);
    menu_additem(gMainMenu, "Build Menu", "1", 0, -1);
    menu_additem(gMainMenu, "Move Menu", "2", 0, -1);
    menu_additem(gMainMenu, "Destroy", "3", accessDelete, -1);
    menu_additem(gMainMenu, "Noclip", "4", accessNoclip, -1);
    menu_additem(gMainMenu, "Load", "5", 0, -1);
    menu_additem(gMainMenu, "Save", "6", accessSave, -1);
    menu_additem(gMainMenu, "Custom Menu", "7", 0, -1); 


gCustomMenu = menu_create("Custom Menu", "mnuCustom", 0);
menu_additem(gCustomMenu, "Revive", "1", accessCustom, -1);
menu_additem(gCustomMenu, "Godmode", "2", accessCustom, -1);
menu_additem(gCustomMenu, "Scout + Usp", "3", accessCustom, -1);
menu_additem(gCustomMenu, "Healer", "4", accessCustom, -1);
menu_additem(gCustomMenu, "Sobre este plugin.", "5", 0, -1);
menu_setprop(gCustomMenu, MPROP_EXITNAME, "Main Menu");[/PHP]

This is a menu inside other menu the way you show me ... is one menu, how i do this?

[fysiks]

You just make a couple more functions. One for showing the main menu and one for the action of the main menu.

Then in the action of the main menu you would open the custom menu in case 7.

PHP Code:

#include <amxmodx>
#include <fun>

new g_pMainMenu

public plugin_init()
{
    register_clcmd("say /testmenu", "cmdMenu")

    /* Build non-changing menus here */
    g_pMainMenu = menu_create("\rBCM4 by joker.", "actionMainMenu")
    menu_additem(g_pMainMenu, "Build Menu", "1")
    menu_additem(g_pMainMenu, "Move Menu", "2")
    menu_additem(g_pMainMenu, "Destroy", "3")
    menu_additem(g_pMainMenu, "Noclip", "4")
    menu_additem(g_pMainMenu, "Load", "5")
    menu_additem(g_pMainMenu, "Save", "6")
    menu_additem(g_pMainMenu, "Custom Menu", "7")
}

public cmdMenu(id)
{
    showMainMenu(id)

    return PLUGIN_CONTINUE
}

public showMainMenu(id)
{
    // show main menu here
    menu_display(id, g_pMainMenu, 0)
}

public actionMainMenu(id, menu, item)
{
    // action of main menu here
    if( item == MENU_EXIT )
    {
        return PLUGIN_HANDLED
    }

    new szCmd[3],  _access, callback
    menu_item_getinfo(menu, item, _access, szCmd, 2, "", 0, callback)

    switch( str_to_num(szCmd) )
    {
        case 1 .. 6:
        {
            // Code here
        }
        case 7:
        {
            showCustomMenu(id)
        }
    }
    
    // Do NOT destroy Main Menu.
    return PLUGIN_HANDLED
}

public showCustomMenu(id)
{
    // Build and show the custom menu here
    static pCustomMenu
    pCustomMenu = menu_create("Custom Menu", "actionCustomMenu")
    menu_additem(pCustomMenu, "Revive", "1")
    menu_additem(pCustomMenu, get_user_godmode(id) ? "Godmode: \yOn" : "Godmode: \rOff", "2")
    menu_additem(pCustomMenu, "Scout + Usp", "3")
    menu_additem(pCustomMenu, "Healer", "4")
    menu_additem(pCustomMenu, "About Plugin", "5")
    menu_setprop(pCustomMenu, MPROP_EXITNAME, "Main Menu")

    menu_display(id, pCustomMenu, 0)
}

public actionCustomMenu(id, menu, item)
{
    // Action of the custom menu here
    if( item == MENU_EXIT )
    {
        menu_destroy(menu)
        showMainMenu(id)
        return PLUGIN_HANDLED
    }

    new szCmd[3],  _access, callback
    menu_item_getinfo(menu, item, _access, szCmd, 2, "", 0, callback)

    switch( str_to_num(szCmd) )
    {
        case 1: // Revive
        {
            // Code Here
        }
        case 2: // GodMode
        {
            set_user_godmode(id, get_user_godmode(id) ? 0 : 1)
        }
        case 3: // Scout + Usp
        {
            // Code Here
        }
        case 4: // Healer
        {
            // Code Here
        }
        case 5: // About plugin.
        {
            // Code Here
        }
    }

    menu_destroy(menu)
    showCustomMenu(id)
    return PLUGIN_HANDLED
} 


I built the Main menu in plugin_init() because I'm assuming it will never change.

[lolzin123]

thanx very much man

EDIT: Any Idea at this forun?
http://forums.alliedmods.net/showthr...039#post888039

And how i set this menu only for Admins?

[fysiks]

Originally Posted by lolzin123 thanx very much man And how i set this menu only for Admins?

That depends on if there is more then one way to get to the menu.

Do you want the main menu accessible only by admins or just the custom menu?