[mottzi]

Hey guys,

Im trying to block the explosion of smokegrenades. At the moment, I hook the spawn of the entity and remove it if the velocity is zero. The problems are that (1) this only blocks the first smokegrenade and (2) after the block I cant give another smoke with GivePlayerItem.

Am I doing something wrong? Is there a bether way to achieve this? In cs1.6 you could just set the next think of the nade to 9999, would this be a possability in cs:go too?

PHP Code:

public OnEntityCreated(entity, const String:classname[]) 
{ 
    if(StrEqual(classname, "smokegrenade_projectile")) 
    { 
        SDKHook(entity, SDKHook_Spawn, OnEntitySpawned)
    } 
} 

public OnEntitySpawned(entity) 
{ 
    CreateTimer(0.01, TimerExec, entity, TIMER_REPEAT)
}

public Action TimerExec(Handle t, int entity) 
{ 
    new Float:fVelocity[3]; 
    GetEntPropVector(entity, Prop_Send, "m_vecVelocity", fVelocity); 
    if(fVelocity[0] == 0.0 && fVelocity[1] == 0.0 && fVelocity[2] == 0.0) 
    { 
        AcceptEntityInput(entity, "Kill");
        
        return Plugin_Stop
    }

    return Plugin_Continue
} 


[xines]

Do you mean something like this?

PHP Code:

#include <sourcemod>
#include <sdktools>

public void OnPluginStart()
{
    HookEvent("smokegrenade_detonate", OnSmokeDetonate);
}

public void OnSmokeDetonate(Event event, const char[] name, bool dontBroadcast)
{
    float origin[3];
    origin[0] = GetEventFloat(event, "x");
    origin[1] = GetEventFloat(event, "y");
    origin[2] = GetEventFloat(event, "z");
    
    int index = MaxClients+1;
    float xyz[3];
    while ((index = FindEntityByClassname(index, "smokegrenade_projectile")) != -1)
    {
        GetEntPropVector(index, Prop_Send, "m_vecOrigin", xyz);
        if (xyz[0] == origin[0] && xyz[1] == origin[1] && xyz[2] == origin[2])
        {
            AcceptEntityInput(index, "kill");
        }
    }
    
    while((index = FindEntityByClassname(index, "env_particlesmokegrenade")) != -1)
    {
        GetEntPropVector(index, Prop_Send, "m_vecOrigin", xyz);
        if (xyz[0] == origin[0] && xyz[1] == origin[1] && xyz[2] == origin[2])
        {
            AcceptEntityInput(index, "kill");
        }
    }
} 


[Totenfluch]

public OnEntityCreated(entity, const String:classname[])
{
	if(!strcmp(classname, "env_particlesmokegrenade"))
		AcceptEntityInput(entity, "Kill");
}

try this

[Neuro Toxin]

Originally Posted by Totenfluch public OnEntityCreated(entity, const String:classname[]) { if(!strcmp(classname, "env_particlesmokegrenade")) AcceptEntityInput(entity, "Kill"); } try this

Be carefull killing entities on this callback.

You should hook spawn and kill it there.

[Totenfluch]

Originally Posted by Neuro Toxin Be carefull killing entities on this callback. You should hook spawn and kill it there.

This Question may sound stupid but.. why?

[Neuro Toxin]

When create entity is called an entity index is returned.

If you kill the entity. Whatever created it might not check if the entity created is valid and attempt to call spawn entity.

This causes errors and in some cases server crashes.

Hooking spawn on the entity created callback and killing on spawn avoids this.

[milutinke]

 SetEntProp( iEntity, Prop_Data, "m_nNextThinkTick", -1 );

I am using this and it works like charm

[Totenfluch]

Originally Posted by Neuro Toxin When create entity is called an entity index is returned. If you kill the entity. Whatever created it might not check if the entity created is valid and attempt to call spawn entity. This causes errors and in some cases server crashes. Hooking spawn on the entity created callback and killing on spawn avoids this.

Thanks!

[mottzi]

Thanks guys, got it working with your help.

[B_R]

Originally Posted by xines Do you mean something like this? PHP Code: #include <sourcemod> #include <sdktools> public void OnPluginStart() {     HookEvent("smokegrenade_detonate", OnSmokeDetonate); } public void OnSmokeDetonate(Event event, const char[] name, bool dontBroadcast) {     float origin[3];     origin[0] = GetEventFloat(event, "x");     origin[1] = GetEventFloat(event, "y");     origin[2] = GetEventFloat(event, "z");          int index = MaxClients+1;     float xyz[3];     while ((index = FindEntityByClassname(index, "smokegrenade_projectile")) != -1)     {         GetEntPropVector(index, Prop_Send, "m_vecOrigin", xyz);         if (xyz[0] == origin[0] && xyz[1] == origin[1] && xyz[2] == origin[2])         {             AcceptEntityInput(index, "kill");         }     }          while((index = FindEntityByClassname(index, "env_particlesmokegrenade")) != -1)     {         GetEntPropVector(index, Prop_Send, "m_vecOrigin", xyz);         if (xyz[0] == origin[0] && xyz[1] == origin[1] && xyz[2] == origin[2])         {             AcceptEntityInput(index, "kill");         }     } }

Works bro you saved ma life, i can have smoke effect now wich doesn't make the detonate bug with molotov on ze ^^