[PeEzZ]

My stock:

stock GetFileTypeName(String: FilePath[], String: FileType[], FileTypeLen)
{
    if(StrContains(FilePath, ".") != -1)
    {
        for(new i = strlen(FilePath); i >= 0; i--)
        {
            if(StrContains(FilePath[i], ".") != -1)
            {
                i += 1;
                strcopy(FileType, FileTypeLen, FilePath[i]);
                break;
            }
        }
    }
}

This code is working but i dont know, the code syntax is good, or it could be better.

new String: TYPE[256];
GetFileTypeName("wow/lol.mp3", TYPE, sizeof(TYPE));
PrintToServer(TYPE); // Console is saying: "mp3"

My ask: This syntax is good?

EDIT:
The answer:

stock bool:GetFileTypeName(const String:FilePath[], String:FileType[], FileTypeLen)
{
     new loc = FindCharInString(FilePath, '.', true);
     if (loc == -1)
     {
          FileType[0] = '\0';
          return false;
     }
     //strcopy(FileType, FileTypeLen, FilePath[loc]); //this get the file's name and the dot, like "lol.wav" >> ".wav"
     strcopy(FileType, FileTypeLen, FilePath[loc + 1]); //this get only the file's name like "lol.wav" >> "wav"
     return true;
}

[KissLick]

I would use upper-case only for constants. The only prog. languages where I have ever seen upper-case variables are Cobol and CL...

And ofc it's bad to declare string of size 256 when you use only 4.

[Starbish]

how about this one?

PHP Code:

stock void GetFileExtension(char[] cExtensionName, const char[] cFileName, int maxlength){

    Format(cExtensionName, maxlength, "%s", cFileName[FindCharInString(cFileName, '.', true) + 1]);
} 


[Mitchell]

Originally Posted by Starbish how about this one? PHP Code: stock void GetFileExtension(char[] cExtensionName, const char[] cFileName, int maxlength){     Format(cExtensionName, maxlength, "%s", cFileName[FindCharInString(cFileName, '.', true) + 1]); }

wouldn't that get "file.mp3" if the filename is: "some.file.mp3"

[Starbish]

Originally Posted by Mitchell wouldn't that get "file.mp3" if the filename is: "some.file.mp3"

no.

FindCharInString()'s third parameter sets whether the starting point is 0 or the last index of the string.

[Mitchell]

Originally Posted by Starbish no. FindCharInString()'s third parameter sets whether the starting point is 0 or the last index of the string.

ah nice, some reason i just assumed it was for case sensitivity. (no need to explain why, I can already guess why)

[Starbish]

Originally Posted by Mitchell ah nice, some reason i just assumed it was for case sensitivity. (no need to explain why, I can already guess why)

ya. that looks quite assumable.

[Powerlord]

The FindCharInString stock might make this simpler, plus you benefit from any optimizations that the SourceMod devs make to FindCharInString later (well... if the plugin is recompiled again later):

stock bool:GetFileTypeName(const String:FilePath[], String:FileType[], FileTypeLen)
{
    new loc = FindCharInString(FilePath, '.', true);
    if (loc == -1)
    {
        FileType[0] = '\0';
        return false;
    }

    strcopy(FileType, FileTypeLen, FilePath[loc]);
    return true;
}

Edit: This is what I get for delaying submitting this.

[Powerlord]

Originally Posted by Starbish that looks almost same as what i did.... except Format(). is strcopy() faster than Format()?

See the Edit to said post.

When I originally started typing that, there were no replies to the thread, but I got sidetracked before posting it.

As for strcopy versus Format, the answer to that is going to be yes, strcopy is faster. After all, a %s Format is going to do the same thing as strcopy does, but you have to parse the formatting string first...

[PeEzZ]

Thanks