[Athena AI]

I've been trying lately to spawn a shield via this Spawn Weapon stock I found. But nothing I try its working and it keeps crashing the server if anyone can help it would be appreciated a lot.

stock SpawnWeapon(client, String:name[], index, level, qual, String:att[])
{
	new Handle:hWeapon=TF2Items_CreateItem(OVERRIDE_ALL|FORCE_GENERATION);
	if(hWeapon==INVALID_HANDLE)
	{
		return -1;
	}

	TF2Items_SetClassname(hWeapon, name);
	TF2Items_SetItemIndex(hWeapon, index);
	TF2Items_SetLevel(hWeapon, level);
	TF2Items_SetQuality(hWeapon, qual);
	new String:atts[32][32];
	new count=ExplodeString(att, ";", atts, 32, 32);

	if(count % 2)
	{
		--count;
	}

	if(count>0)
	{
		TF2Items_SetNumAttributes(hWeapon, count/2);
		new i2;
		for(new i; i<count; i+=2)
		{
			new attrib=StringToInt(atts[i]);
			if(!attrib)
			{
				LogError("Bad weapon attribute passed: %s ; %s", atts[i], atts[i+1]);
				CloseHandle(hWeapon);
				return -1;
			}

			TF2Items_SetAttribute(hWeapon, i2, attrib, StringToFloat(atts[i+1]));
			i2++;
		}
	}
	else
	{
		TF2Items_SetNumAttributes(hWeapon, 0);
	}

	new entity=TF2Items_GiveNamedItem(client, hWeapon);
	CloseHandle(hWeapon);
	EquipPlayerWeapon(client, entity);
	return entity;
}

[Facksy]

This is what i use to create demoshield, just change the definition index and the model path

public void OnPluginStart(){
	Handle hGameConf = LoadGameConfigFile("tf2.wearables");
	if (hGameConf == null) return;
	StartPrepSDKCall(SDKCall_Player);
	PrepSDKCall_SetFromConf(hGameConf, SDKConf_Virtual, "CTFPlayer::EquipWearable");
	PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);
	hSDKEquipWearable = EndPrepSDKCall();
}

void CreateShield(int client){
	TF2_RemoveWeaponSlot(client, 1);
	int ent = CreateEntityByName("tf_wearable_demoshield");
	SetEntProp(ent, Prop_Send, "m_nModelIndexOverrides", PrecacheModel("models/weapons/c_models/c_persian_shield/c_persian_shield_all.mdl"));
	SetEntProp(ent, Prop_Send, "m_iItemDefinitionIndex", 406);
	DispatchSpawn(ent);
	SDKCall(hSDKEquipWearable, client, ent);
}

And here is tf2.wearables.txt

"Games"
{
	"tf"
	{
		"Offsets"
		{
			"CTFPlayer::EquipWearable"
			{
				"windows"	"430"
				"linux"		"431"
				"mac"		"431"
			}
		}
	}
}

It doesnt work and it crashes your server because a demoshield is considered as a wearable, and not a weapon, thats why

[Athena AI]

Huh interesting but is there any way to edit its attributes and assign custom ones as well? And does it also charge and keep its normal attrributes?

[PC Gamer]

I did this a different way. I used TF2Items Give Weapon and TF2Attributes, but I ran into a problem.

I am unable to set attributes on the shield after it is given.

GiveFestiveTarge(client)
{
	if (IsValidClient(client))
	{
		TF2_RemoveWeaponSlot(client, 1);
		TF2Items_GiveWeapon(client, 1144);
		new weapon = GetPlayerWeaponSlot(client, 1); 
		TF2Attrib_SetByName(weapon, "charge time increased", 2.0);
		TF2Attrib_SetByName(weapon, "charge recharge rate increased", 2.0);
		TF2Attrib_SetByName(weapon, "charge impact damage increased", 2.0);	
		TF2Attrib_SetByName(weapon, "mult charge turn control", 5.0);
	}
}

It gives the weapon, and I can apply attributes to any other slot except slot 1. Once slot 1 is removed any attempt to set an attribute on slot 1 results in Ivalid entity (iEntity=-1). I'm using slot 1 since the TF2 Wiki (link: https://wiki.alliedmods.net/Team_For....5BSlot_1.5D_4 ) shows demoshields belong in slot 1.

Does anyone know how to apply attributes to a demoshield after it is given?

[Facksy]

Originally Posted by PC Gamer I did this a different way. I used TF2Items Give Weapon and TF2Attributes, but I ran into a problem. I am unable to set attributes on the shield after it is given. GiveFestiveTarge(client) { if (IsValidClient(client)) { TF2_RemoveWeaponSlot(client, 1); TF2Items_GiveWeapon(client, 1144); new weapon = GetPlayerWeaponSlot(client, 1); TF2Attrib_SetByName(weapon, "charge time increased", 2.0); TF2Attrib_SetByName(weapon, "charge recharge rate increased", 2.0); TF2Attrib_SetByName(weapon, "charge impact damage increased", 2.0); TF2Attrib_SetByName(weapon, "mult charge turn control", 5.0); } } It gives the weapon, and I can apply attributes to any other slot except slot 1. Once slot 1 is removed any attempt to set an attribute on slot 1 results in Ivalid entity (iEntity=-1). I'm using slot 1 since the TF2 Wiki (link: https://wiki.alliedmods.net/Team_For....5BSlot_1.5D_4 ) shows demoshields belong in slot 1. Does anyone know how to apply attributes to a demoshield after it is given?

The demoshield is not considered as a weapon, but as a wearable ("tf_wearable_demoshield"), so GetPlayerWeaponSlot() will return -1 since thats not a weapon, if you want to modify attibutes, you can loop through all entities with classname "tf_wearable_demoshield", check the "m_hOwnerEntity", and then you can apply attributes on the shield, tested and it works for me

[PC Gamer]

Thanks Facksy, that helped!

Athena AI... The attached code will allow you to give a Festive Targe with sample attributes to a target player. I'm trying to improve my coding skills so please feel free to edit/critique.

Solution:

GiveFestiveTarge(client)
{
	if (IsValidClient(client))
	{
		TF2_RemoveWeaponSlot(client, 1);
		TF2Items_GiveWeapon(client, 1144);
		
		new iEntity = -1;
		while ((iEntity = FindEntityByClassname(iEntity, "tf_wearable_demoshield")) != -1)
		{
			if (client == GetEntPropEnt(iEntity, Prop_Data, "m_hOwnerEntity"))
			{
				TF2Attrib_SetByName(iEntity, "charge time increased", 4.0);
				TF2Attrib_SetByName(iEntity, "charge recharge rate increased", 3.0);
				break;
			}
		}			
	}
}

Plugin Command: givetarge
can target self or others
to target self: !givetarge
to target others: !givetarge playername

Enjoy!

[Athena AI]

Hey, that's pretty cool thanks a lot for it, man!