[puntoini]

Como hago para agregar una linea al users.ini ? Digamos lo que quiero hacer es que desde un comando que el usuario pone en say se le abra un menu de players on, al seleccionar un usuario se le dé uno o mas permisos, por ej Kick, Slay y Ban entonces por ej , elije Usuario: Jaimito a jaimito se le dá Kick, Slay y ban y doy un reload a los admins. No entiendo como armarlo, ayuda?

[Ayudante]

Lo de menu de players online hay u tuto mira lo!

[puntoini]

Originally Posted by Ayudante Lo de menu de players online hay u tuto mira lo!

Si, eso es fácil. Lo que quiero es la base para al seleccionar a "x" usuario, se le den los permisos desde el user.ini.

[chetah]

La otra vez mex dejo varios

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Admin-SEt"
#define VERSION "1.0"
#define AUTHOR "[M]etrikcz"

new g_AdminsTypes, Array:Admins, g_maxplayers, target_menu, g_tipe

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    load()
    
    g_maxplayers = get_maxplayers()
    
    register_concmd("amx_set_admin", "cmd_set_admin", ADMIN_RCON, "- Show Set Admin Menu", 1)
}
public load()
{
    g_AdminsTypes = 0
    Admins = ArrayCreate(64, 1)
    
    new File[100]; get_configsdir(File, 99)
    add(File, 99, "/admin.ini")
    
    new open = fopen(File, "rt")
    
    new Linea[75]
    while(!feof(open))
    {
        fgets(open, Linea, charsmax(Linea))
        trim(Linea)
        
        if(Linea[0] == ';' || !Linea[0])
            continue;    
            
        ArrayPushString(Admins, Linea)
        g_AdminsTypes++
    }
}
public cmd_set_admin(id, level, cid)
{
    if(!cmd_access(id, level, cid, 2))
        return PLUGIN_HANDLED;
        
    show_admin_set(id)
    
    return PLUGIN_HANDLED;
}
show_admin_set(id)
{
    new szname[50], num[2], menu = menu_create("Seleccione al jugador que le dara Admin", "handler_menu")
    
    for(new i = 1; i <= g_maxplayers; i++)
    {
        if(!is_user_connected(i) || id == i)
            continue;
        
        get_user_name(i, szname, 49)
        
        if(is_user_admin(i))
            add(szname, 49, " - \r[Admin]")
            
        num[0] = i
        num[1] = 0
        
        menu_additem(menu, szname, num)
    }
    
    menu_setprop(menu, MPROP_BACKNAME, "\rAtras")
    menu_setprop(menu, MPROP_NEXTNAME, "\rSiguiente")
    menu_setprop(menu, MPROP_EXITNAME, "\rSalir")
    
    menu_display(id, menu, 0)
}
public handler_menu(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED;
    }
    
    new buffer[2], deal, playerid
    menu_item_getinfo(menu, item, deal, buffer, charsmax(buffer), _, _, deal)
    playerid = buffer[0]
    
    if(!is_user_connected(playerid))
    {
        client_print(id, print_chat, "[AMXX] User seleccionado ya no esta conectado")
        return PLUGIN_HANDLED;
    }
    target_menu = playerid
    menu_admin_i(id)

    return PLUGIN_HANDLED;
}
menu_admin_i(id)
{
    new szname[33]; get_user_name(id, szname, 32)
    new len[75]; formatex(len, 74, "Seleccione a que identificador le pondra admin a %s", szname)
    new menu = menu_create(len, "handler_admin_i")
    
    menu_additem(menu, "Nombre", "1")
    menu_additem(menu, "Steam", "2")
    menu_additem(menu, "IP", "3")
    
    menu_display(id, menu, 0)
}
public handler_admin_i(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        show_admin_set(id)
        return PLUGIN_HANDLED;
    }
    
    
    if(!is_user_connected(target_menu))
    {
        client_print(id, print_chat, "El usuario seleccionado se desconecto")
        return PLUGIN_HANDLED;
    }
    g_tipe = item
    show_admintipe_menu(id)
    return PLUGIN_HANDLED;
}
show_admintipe_menu(id)
{
    new Linea[75], TargetName[33]; get_user_name(target_menu, TargetName, 32)
    new len[100]; formatex(len, charsmax(len), "Seleccione el tipo de admin que le dara a \r%s", TargetName)
    new menu = menu_create(len, "handler_admintipe")
    new AdminTipeName[15], AdminFlags[30], num[2] 
    
    for(new i = 0; i < g_AdminsTypes; i++)
    {
        ArrayGetString(Admins, i, Linea, charsmax(Linea))
        parse(Linea, AdminTipeName, charsmax(AdminTipeName), AdminFlags, charsmax(AdminFlags))
        
        formatex(len, charsmax(len), "%s - \r(%s)", AdminTipeName, AdminFlags)
        num_to_str(i, num, 1)
        menu_additem(menu, len, num)
    }
    
    menu_display(id, menu, 0)
}
public handler_admintipe(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        show_admin_set(id)
        return PLUGIN_HANDLED;
    }
    
    if(!is_user_connected(target_menu))
    {
        client_print(id, print_chat, "[AMXX] El jugador seleccionado se desconecto")
        return PLUGIN_HANDLED;
    }
    
    new DuenoName[33], NewAdminName[33]
    get_user_name(id, DuenoName, 32)
    get_user_name(target_menu, NewAdminName, 32)

    new AdminTipeName[15], AdminFlags[30], Linea[75]
    ArrayGetString(Admins, item, Linea, charsmax(Linea))
    
    parse(Linea, AdminTipeName, charsmax(AdminTipeName), AdminFlags, charsmax(AdminFlags))
    
    set_admin(target_menu, AdminFlags, g_tipe)
    
    client_print(0, print_chat, "%s Le dio Admin %s a %s", DuenoName, AdminTipeName, NewAdminName)
    
    return PLUGIN_HANDLED;
}
set_admin(user, flags[], tipo)
{
    new ident[33]
    new pw[5]; formatex(pw, 4, "%d%d%d%d", random_num(1, 9), random_num(1, 9), random_num(1, 9), random_num(1, 9))
    
    switch(tipo)
    {
        case 0:
        {
            get_user_name(user, ident, 32)
            server_cmd("amx_addadmin ^"%s^" ^"%s^" ^"%s^" ^"a^"", ident, pw, flags)
            console_print(user, "TU PASSWORD DE ADMIN ES %s", pw)
            console_print(user, "DEBERAS PONES EN TU CONSOLA: setinfo _pw %s", pw)
            server_cmd("kick #%d ^"Se te ha kikeado porque se te ha agregado admin, tu pw es %s, revisa tu consola para mas informacion^"", get_user_userid(user), pw)
        }
        case 1:
        {
            get_user_authid(user, ident, 32)
            server_cmd("amx_addadmin ^"%s^" ^"^" ^"%s^" ^"ce^"", ident, flags)
        }
        case 2:
        {
            get_user_ip(user, ident, 32)
            server_cmd("amx_addadmin ^"%s^" ^"^" ^"%s^" ^"de^"", ident, flags)
        }    
    }
    server_cmd("amx_reloadadmins")
} 


PHP Code:

#include <amxmodx>

#define PLUGIN "Admin-Free"
#define VERSION "1.0"
#define AUTHOR "Mex"

new g_admin

#define TAG "[ADMIN-FREE]"
#define ADMIN_FREE_FLAGS "bcdefghijmnop"

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /getadmin", "clcmd_getadmin")
    g_admin = 0
}
public client_disconnect(id)
{
    if(g_admin == id)
        g_admin = 0
}
public clcmd_getadmin(id)
{
    if(g_admin == id)
    {
        client_print(id, print_chat, "%s Usted ya ha reclamado el admin free", TAG)
        return PLUGIN_HANDLED;
    }
    if(g_admin)
    {
        new AdminFreeName[33]; get_user_name(g_admin, AdminFreeName, 32)
        
        client_print(id, print_chat, "%s El usuario %s ya ha reclamado este admin", TAG, AdminFreeName)
        return PLUGIN_HANDLED;
    }
    
    new UserName[33]; get_user_name(id, UserName, 32)
    set_user_admin_free(id)
    
    client_print(0, print_chat, "%s %s Ha reclamado el AdminFree", TAG, UserName)
    return PLUGIN_HANDLED;
}
set_user_admin_free(user)
{
    new UserFlags = read_flags(ADMIN_FREE_FLAGS)
    
    remove_user_flags(user)
    set_user_flags(user, UserFlags)
    
    g_admin = user
}