[LS44]

Hello guys!

There are loads of maps, where you can pick up a weapon from the floor/field.( surf_10x_reloaded) In my case the skin does not come with the weapon if you can understand me. Could anyone help me please?
Thanks in advance (:

[brunoronning]

Originally Posted by LS44 Hello guys! There are loads of maps, where you can pick up a weapon from the floor/field.( surf_10x_reloaded) In my case the skin does not come with the weapon if you can understand me. Could anyone help me please? Thanks in advance (:

Try this:

Spoiler

PHP Code:

public void OnClientPutInServer(int iClient)
{
    SDKHook(iClient, SDKHook_WeaponEquipPost, OnWeaponEquipPost);
}

public void OnClientDisconnect(int iClient)
{
    SDKUnhook(iClient, SDKHook_WeaponEquipPost, OnWeaponEquipPost);
}

public void OnWeaponEquipPost(int iClient, int iWeapon)
{
    if (!IsValidEdict(iWeapon))
        return;

    if (GetEntProp(iWeapon, Prop_Send, "m_hPrevOwner") > 0)
        return;

    char szClass[64];
    GetEdictClassname(iWeapon, szClass, sizeof(szClass));

    if (SafeRemoveWeapon(iClient, iWeapon))
    {
        DataPack pack = new DataPack();
        RequestFrame(Frame_ReplaceWeapon, pack);
        pack.WriteCell(GetClientUserId(iClient));
        pack.WriteString(szClass);
    }
}

public void Frame_ReplaceWeapon(DataPack pack)
{
    pack.Reset();
    int iClient = GetClientOfUserId(pack.ReadCell());
    char szClass[64];
    pack.ReadString(szClass, sizeof(szClass));
    delete pack;

    if (!iClient || !IsClientInGame(iClient))
        return;

    int iWeapon = GivePlayerItem(iClient, szClass);
    EquipPlayerWeapon(iClient, iWeapon);
}

// Snippet from: https://bitbucket.org/SM91337/csgo-items/
stock bool SafeRemoveWeapon(int iClient, int iWeapon)
{
    int iDefIndex = GetEntProp(iWeapon, Prop_Send, "m_iItemDefinitionIndex");

    if (iDefIndex < 0 || iDefIndex > 700)
        return false;

    if (HasEntProp(iWeapon, Prop_Send, "m_bInitialized"))
    {
        if (GetEntProp(iWeapon, Prop_Send, "m_bInitialized") == 0)
            return false;
    }

    if (HasEntProp(iWeapon, Prop_Send, "m_bStartedArming"))
    {
        if (GetEntSendPropOffs(iWeapon, "m_bStartedArming") > -1)
            return false;
    }

    if (!RemovePlayerItem(iClient, iWeapon))
        return false;

    int iWorldModel = GetEntPropEnt(iWeapon, Prop_Send, "m_hWeaponWorldModel");

    if (IsValidEdict(iWorldModel) && IsValidEntity(iWorldModel))
    {
        if (!AcceptEntityInput(iWorldModel, "Kill"))
            return false;
    }

    if (iWeapon == GetEntPropEnt(iClient, Prop_Send, "m_hActiveWeapon"))
        SetEntPropEnt(iClient, Prop_Send, "m_hActiveWeapon", -1);

    AcceptEntityInput(iWeapon, "Kill");
    return true;
} 


[LS44]

Which config file or smth like that, should I paste this?

[brunoronning]

Originally Posted by LS44 Which config file or smth like that, should I paste this?

It's a plugin:

[LS44]

Well, it says first
Host_error: index error writing string table baseline downloadables.
Then I try to restart. and: ED_Alloc: no free edicts. This plugin causes it maybe

[brunoronning]

Originally Posted by LS44 Host_error: index error writing string table baseline downloadables.

This error has nothing to do with the plugin. This may help you: https://forums.alliedmods.net/showpo...&postcount=110

Originally Posted by LS44 Then I try to restart. and: ED_Alloc: no free edicts. This plugin causes it maybe

New version fixed with improvements. It's working!
- https://github.com/quasemago/WeaponSkinOnEquip

[Mitchell]

Doesn't this plugin do what you wanted?
https://forums.alliedmods.net/showthread.php?p=2112938

[LS44]

Works nice, thank you Brun
Both plugin are the same. Thank you Guys