Played Time Counter ( The problem of saving )

BerkayF · **Author**

The Problem of Saving

I am Using nVault as the Database
But I can't register the information!
If you can help me, I'll be happy

PHP Code:


			
/*

| =============================

| Generated by Berk

| Made in Turkey

| Keep It Ready

| =============================

*/



#include <amxmodx>

#include <amxmisc>

#include <zombieplague>

#include <nvault>



#define PLUGIN "Played Timer"

#define VERSION "BK TEAM - 4.0"

#define AUTHOR "Berk"



new played_time_second[33]

new played_time_minute[33]

new played_time_hour[33]

new played_time_day[33]



new p_Vault



public plugin_init() {

    register_plugin(PLUGIN, VERSION, AUTHOR)

}



public plugin_cfg()

{

    p_Vault = nvault_open("played_time")



    if ( p_Vault == INVALID_HANDLE )

        set_fail_state( "Error opening played_time nVault, file does not exist!" )

}



public played_time(id)

{

    // It Will Be 1 Minute

    if(played_time_second[id] != 60)

    {

        played_time_second[id]++

    }

    

    // It's Been 1 Minute

    if(played_time_second[id] == 60)

    {

        played_time_second[id] = 0

        played_time_minute[id]++

    }

    

    // It Will Be 1 Hour

    if(played_time_minute[id] == 60)

    {

        played_time_minute[id] = 0

        played_time_hour[id]++

    }

    

    // It Will Be 1 Day

    if(played_time_hour[id] == 24)

    {

        played_time_hour[id] = 0

        played_time_day[id]++

    }

}



public played_hud(id)

{

    if(is_user_alive(id))

    set_hudmessage(80, 255, 150, 0.01, 0.19, 0, 0.5, 1.0, 0.5, 0.5)

    show_hudmessage(id, "[ Played Time System ]^n| Day: %i^n| Hour: %i^n| Minute: %i^n| Second: %i^n[ %s ]", played_time_day[id], played_time_hour[id], played_time_minute[id], played_time_second[id], VERSION)

}



public played_msg(id)

{

    new name[18]

    get_user_name(id, name, 17)

    client_print(0, print_chat, "[Play Time] Name: %s | D: %i | H: %i | M: %i | S: %i", name, played_time_day[id], played_time_hour[id], played_time_minute[id], played_time_second[id] )

}



public client_putinserver(id)

{

    set_task(1.0, "played_hud", id, _, _, "b")

    set_task(1.0, "played_time", id, _, _, "b")

    set_task(8.0, "played_msg", id)

}



#if AMXX_VERSION_NUM < 183

public client_disconnect(id)

#else 

public client_disconnected(id)

#endif

{

    SavePlayed(id)

    

    played_time_day[id] = 0

    played_time_hour[id] = 0

    played_time_minute[id] = 0

    played_time_second[id] = 0

    remove_task(id);

} 



public client_connect(id)

{

    LoadPlayed(id)

}



SavePlayed(id)

{

    new szAuth[33];

    new szKey[64];

    

    get_user_authid(id , szAuth , charsmax(szAuth))

    formatex(szKey , 63 , "%s-ID" , szAuth)

    

    new szData[256]

        

    formatex(szData , 255 , "%i#%i#%i#%i" , played_time_second[id], played_time_minute[id], played_time_hour[id], played_time_day[id])

    

    nvault_pset(p_Vault , szKey , szData)

}



LoadPlayed(id)

{

    new szAuth[33];

    new szKey[40];

    

    get_user_authid(id , szAuth , charsmax(szAuth))

    formatex(szKey , 63 , "%s-ID" , szAuth)

    

    new szData[256];

    

    formatex(szData , 255 , "%i#%i#%i#%i" , played_time_second[id], played_time_minute[id], played_time_hour[id], played_time_day[id])

    

    nvault_get(p_Vault, szKey, szData, 255)

    

    replace_all(szData , 255, "#", " ")

    new day[32], hour[32], minute[32], second[32]

    parse(szData, second, 31, minute, 31, hour, 31, day, 31)

    played_time_day[id] = str_to_num(day)

    played_time_hour[id] = str_to_num(hour)

    played_time_minute[id] = str_to_num(minute)

    played_time_second[id] = str_to_num(second)

}

This way Saving

Code:

VALVE_XASH_9343ca513ad227f9f00ff-ID0#0#0#0#

HTML Code:

VALVE_XASH What is?
Xash3D FWGS

**Bugsy** · 07-18-2022 , 23:15 Re: Played Time Counter ( The problem of saving )

1. Is it tracking time correctly during a connection and only failing to remember time on re-connect?
2. If 1 is yes, did you do some debugging to ensure your parse() is working correctly to assign the correct day/hour/minute/second values into the variables?
3. You can simplify this by instead using a unix timestamps and deriving the weeks/days/minutes/etc.. See the below plugin I quickly put together.

PHP Code:


			


#include <amxmodx>

#include <nvault>



new const Version[] = "0.1";



enum PlayerData

{

    AuthID[ 35 ],

    ConnectTS,

    TotalTime

}



new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

new g_Vault;



public plugin_init() 

{

    register_plugin( "Time Played" , Version , "bugsy" );

    

    g_Vault = nvault_open( "timeVault" );

    

    register_clcmd( "say /time" , "ShowTime" );

}



public plugin_end() 

{

    nvault_close( g_Vault );

}



public client_authorized( id )

{

    new szTime[ 10 ] , iTS;

    

    get_user_authid( id , g_pdData[ id ][ AuthID ] , charsmax( g_pdData[][ AuthID ] ) );

    

    g_pdData[ id ][ ConnectTS ] = get_systime();

    g_pdData[ id ][ TotalTime ] = 0;

    

    if ( nvault_lookup( g_Vault , g_pdData[ id ][ AuthID ] , szTime , charsmax( szTime ) , iTS ) )

    {

        g_pdData[ id ][ TotalTime ] = str_to_num( szTime );

    }

}



#if AMXX_VERSION_NUM >= 190 

public client_disconnected( id )

#else

public client_disconnect( id )

#endif

{

    new szTime[ 10 ] , iTime , iTS;

    

    if ( nvault_lookup( g_Vault , g_pdData[ id ][ AuthID ] , szTime , charsmax( szTime ) , iTS ) )

    {

        iTime = str_to_num( szTime );

    }

    

    num_to_str( ( get_systime() - g_pdData[ id ][ ConnectTS ] ) + iTime , szTime , charsmax( szTime ) );

    nvault_set( g_Vault , g_pdData[ id ][ AuthID ] , szTime );

}



public ShowTime( id )

{

    new iWeeks , iDays , iHours , iMinutes , iSeconds;

    

    ConvertTimeStamp( g_pdData[ id ][ TotalTime ] + ( get_systime() - g_pdData[ id ][ ConnectTS ] ) , iWeeks , iDays , iHours , iMinutes , iSeconds );

    client_print( id , print_chat , "* Time played: %d weeks, %d days, %d hours, %d minutes, %d seconds" , iWeeks , iDays , iHours , iMinutes , iSeconds );

}



ConvertTimeStamp( iTimestamp , &iWeeks , &iDays , &iHours , &iMinutes , &iSeconds )

{

    if ( iTimestamp >= 604800 )

    {

        iWeeks = iTimestamp / 604800;

        iTimestamp -= ( iWeeks * 604800 );

    }

    

    if ( iTimestamp >= 86400 )

    {

        iDays = iTimestamp / 86400;

        iTimestamp -= ( iDays * 86400 );

    }

    

    if ( iTimestamp >= 3600 )

    {

        iHours = ( iTimestamp / 3600 );

        iTimestamp -= ( iHours * 3600 );

    }

    

    if ( iTimestamp >= 60 )

    {

        iMinutes = ( iTimestamp / 60 );

        iTimestamp -= ( iMinutes * 60 );

    }

    

    iSeconds = iTimestamp;

}

BerkayF · 07-19-2022 , 06:20 Re: Played Time Counter ( The problem of saving )

Quote:

Originally Posted by Bugsy

1. Is it tracking time correctly during a connection and only failing to remember time on re-connect?
2. If 1 is yes, did you do some debugging to ensure your parse() is working correctly to assign the correct day/hour/minute/second values into the variables?
3. You can simplify this by instead using a unix timestamps and deriving the weeks/days/minutes/etc.. See the below plugin I quickly put together.

PHP Code:


			


#include <amxmodx>

#include <nvault>



new const Version[] = "0.1";



enum PlayerData

{

    AuthID[ 35 ],

    ConnectTS,

    TotalTime

}



new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

new g_Vault;



public plugin_init() 

{

    register_plugin( "Time Played" , Version , "bugsy" );

    

    g_Vault = nvault_open( "timeVault" );

    

    register_clcmd( "say /time" , "ShowTime" );

}



public plugin_end() 

{

    nvault_close( g_Vault );

}



public client_authorized( id )

{

    new szTime[ 10 ] , iTS;

    

    get_user_authid( id , g_pdData[ id ][ AuthID ] , charsmax( g_pdData[][ AuthID ] ) );

    

    g_pdData[ id ][ ConnectTS ] = get_systime();

    g_pdData[ id ][ TotalTime ] = 0;

    

    if ( nvault_lookup( g_Vault , g_pdData[ id ][ AuthID ] , szTime , charsmax( szTime ) , iTS ) )

    {

        g_pdData[ id ][ TotalTime ] = str_to_num( szTime );

    }

}



#if AMXX_VERSION_NUM >= 190 

public client_disconnected( id )

#else

public client_disconnect( id )

#endif

{

    new szTime[ 10 ] , iTime , iTS;

    

    if ( nvault_lookup( g_Vault , g_pdData[ id ][ AuthID ] , szTime , charsmax( szTime ) , iTS ) )

    {

        iTime = str_to_num( szTime );

    }

    

    num_to_str( ( get_systime() - g_pdData[ id ][ ConnectTS ] ) + iTime , szTime , charsmax( szTime ) );

    nvault_set( g_Vault , g_pdData[ id ][ AuthID ] , szTime );

}



public ShowTime( id )

{

    new iWeeks , iDays , iHours , iMinutes , iSeconds;

    

    ConvertTimeStamp( g_pdData[ id ][ TotalTime ] + ( get_systime() - g_pdData[ id ][ ConnectTS ] ) , iWeeks , iDays , iHours , iMinutes , iSeconds );

    client_print( id , print_chat , "* Time played: %d weeks, %d days, %d hours, %d minutes, %d seconds" , iWeeks , iDays , iHours , iMinutes , iSeconds );

}



ConvertTimeStamp( iTimestamp , &iWeeks , &iDays , &iHours , &iMinutes , &iSeconds )

{

    if ( iTimestamp >= 604800 )

    {

        iWeeks = iTimestamp / 604800;

        iTimestamp -= ( iWeeks * 604800 );

    }

    

    if ( iTimestamp >= 86400 )

    {

        iDays = iTimestamp / 86400;

        iTimestamp -= ( iDays * 86400 );

    }

    

    if ( iTimestamp >= 3600 )

    {

        iHours = ( iTimestamp / 3600 );

        iTimestamp -= ( iHours * 3600 );

    }

    

    if ( iTimestamp >= 60 )

    {

        iMinutes = ( iTimestamp / 60 );

        iTimestamp -= ( iMinutes * 60 );

    }

    

    iSeconds = iTimestamp;

}

A perfect code
You are an expert pawn coder
You've written things that I can't think of
Thanks

Supremache · 07-19-2022 , 15:59 Re: Played Time Counter ( The problem of saving )

Check this: https://forums.alliedmods.net/showthread.php?t=336209