[Saint Sinner]

I want to detect distance between Id and another players...But something is wrong here

public client_PreThink(id)
{
    new Float:myOrigin[ 3 ], Float:hisOrigin[ 3 ];
    
    new Float:fDistance  

    pev( id, pev_origin, myOrigin )

    for(new i = 1 ; i <= maxplayers; i++)
    {
        pev(i, pev_origin, hisOrigin)
        fDistance = get_distance_f( myOrigin, hisOrigin)

        if( fDistance <= 62.0)
        {
            client_print(id , print_center, "Distance to entity: %.2f", fDistance )
        }

    }
}

[E1_531G]

You do not check if player (variable with name i ) is connected.

[CrazY.]

if (i == id) continue;

[Natsheh]

PHP Code:

public client_PreThink(id)
{
    if(!is_user_alive(id)) return;
    static Float:myOrigin[ 3 ], Float:hisOrigin[ 3 ], players[32], szName[32], player, i, pnum, Float:fDistance;
    pev( id, pev_origin, myOrigin )

    get_players(players, pnum, "ah");
    for(i = 0 ; i < pnum; i++)
    {
        player = players[i];

        if(player == id) continue;
        pev(player, pev_origin, hisOrigin)
        fDistance = get_distance_f( myOrigin, hisOrigin)

        if( fDistance <= 62.0)
        {
            get_user_name(player, szName, 31);
            client_print(id , print_center, "Distance to player entity(%s): %.2f", szName, fDistance)
        }

    }
} 


using static instead of new much better in a forward called each fps.

[Saint Sinner]

Now i have this error...I want to disable distance if player in my team

L 06/11/2019 - 14:29:47: [AMXX] Displaying debug trace (plugin "head.amxx", version "1.0")
L 06/11/2019 - 14:29:47: [AMXX] Run time error 10: native error (native "cs_get_user_team")
L 06/11/2019 - 14:29:47: [AMXX] [0] head.sma::client_PreThink (line 51)

this line : if (cs_get_user_team(id) == cs_get_user_team(i))

public client_PreThink(id)
{
    if(!is_user_alive(id)) return 1;

    static Float:myOrigin[ 3 ], Float:hisOrigin[ 3 ], Float:fDistance, szName[32]

    if( get_pcvar_num(active) )
    {
        pev( id, pev_origin, myOrigin )

        for(new i = 1 ; i <= maxplayers; i++)
        {
            if (i == id) continue;

            if (cs_get_user_team(id) == cs_get_user_team(i))
            {
                return PLUGIN_CONTINUE
            }

            if (is_user_connected(i))
            {
                pev(i, pev_origin, hisOrigin)
                fDistance = get_distance_f( myOrigin, hisOrigin)

                get_user_name(id, szName, charsmax(szName)) 

                if(equal(szName, "Headshoot"))
                {
                    if( fDistance <= get_pcvar_num(Attack_Distance))
                    {
	                if( get_pcvar_num(stab))
		        {
		            HeadShoot[ id ] = true;
	                }
		        else if( get_pcvar_num(slash))
		        {
                            HeadShoot[ id ] = true;
	                }
                    }
                }
            }
        }
    }
    return PLUGIN_HANDLED
}

[JocAnis]

put is_user_connected( i ) before checking his team? even better put is_user_alive there

also if you are using returns PLUGIN_HANDLED and PLUGIN_CONTINUE, then no 'need' for return 1/0

[Natsheh]

No don't put anything use get_players instead and what are you trying to achieve? There might be another (better)way without the need of use prethink

[Saint Sinner]

I want to detect distance for example

If i am TERO detect CT distance
If i am CT detect TERO distance

How can do that?

#include <amxmodx>
#include <fakemeta>
#include <engine>


public client_PreThink(id)
{
    if(!is_user_alive(id)) return;
    static Float:myOrigin[ 3 ], Float:hisOrigin[ 3 ], players[32], szName[32], player, i, pnum, fDistance;
    pev( id, pev_origin, myOrigin )

    get_players(players, pnum, "ah");
    for(i = 0 ; i < pnum; i++)
    {
        player = players[i];

        if(player == id) continue;
        pev(player, pev_origin, hisOrigin)
        fDistance = get_distance_f( myOrigin, hisOrigin)

        if( fDistance <= 62.0)
        {
            get_user_name(player, szName, 31);
            client_print(id , print_center, "Distance to player entity(%s): %.2f", szName, fDistance)
        }

    }
}

[Natsheh]

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <engine>


public client_PreThink(id)
{
    if(!is_user_alive(id)) return;
    static Float:myOrigin[ 3 ], Float:hisOrigin[ 3 ], players[32], szName[32], player, i, pnum, Float:fDistance;
    pev( id, pev_origin, myOrigin );
    get_players(players, pnum, "ahe", get_user_team(id) == 1 ? "CT":"TERRORIST");
    for(i = 0 ; i < pnum; i++)
    {
        player = players[i];

        pev(player, pev_origin, hisOrigin)
        fDistance = get_distance_f( myOrigin, hisOrigin)

        if( fDistance <= 62.0)
        {
            get_user_name(player, szName, 31);
            client_print(id , print_center, "Distance to player entity(%s): %.2f", szName, fDistance)
        }

    }
} 


Here you go..

I forgot to add the Float tag to fDistance in previous code.

[Saint Sinner]

thanks