[jim_yang]

I figured out an alternative way to do this stuff in linux using Orpheu:
steps:
1. Prehook & Posthook CBasePlayer::Observer_FindNextPlayer
2. in prehook function, check if watcher is SPEC, if true, do nothing
else check if watcher has admin flag, if not true, do nothing
3. patch v31 to 0 if admin has flag and not spec

if ( *(_DWORD *)(a1 + 476) != 3 )
        v31 = 1;

4. in posthook function, set it back.

anyone interested in this may have a try.

[xSav]

the problem on linux system doesnt solved
i have

amx_adminfreelook 1 amx_adminfreelookflag "d"

and

mp_forcechasecam "1" mp_forcecamera "1"

and if a choose spectator without admins rights i cant change any views.

i tried version from 35 post and 52 too
sorry for bad english

[jim_yang]

for linux, better to use an amxx plugin using Orpheu
1. Prehook & Posthook CBasePlayer::Observer_FindNextPlayer
2. In Prehook function, Checking admin, if true, set cvar mp_forcechasecam to not 1, if not true, set to 1
3, In posthook function, set that cvar to 1.
Although this method is not that efficient, but it's ok for this case and this kind of function. Try it yourself or ask someone in request section.

[xSav]

where i can find it ?

[kostov]

Some progress with the version for Linux?

[S0m3Th1nG_AwFul]

Originally Posted by Arkshine Don't know why I've not tested returning team variable. If returning works fine, so the asm line above should be pointless. Try this binary :

Unfortunately, module from this post (#52) is completely broken
With mp_forcechasecam "2" and mp_forcecamera "2" it allows to spectate everyone for admins and non-admins at the same time (like mp_forcechasecam and mp_forcecamera is set to 1) when you're in team, not only in spec...
First one (from #35 post), at least, had only bug with non-admin spec.
In any way, Thank you for your work, both of you

[jim_yang]

I'm totally out of this kind of stuff, cs, amxx, whatever. But for the sake of whom asked me for help, I decide to give it a shot to end this "free look" story.

But I'm not good at Orpheu thing, and haven't been coding for a long time. so someone(Arkshine?) may help me finish it please.

#include <amxmodx>
#include <orpheu>

#define PLUGIN	"Admin Free Look"
#define AUTHOR	"Jim"
#define VERSION	"1.0"

new g_cvar_afl
new g_cvar_aflf

new g_mp_forcechasecam
new g_mp_forcecamera

new g_forcechasecam
new g_forcecamera

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	g_cvar_afl = register_cvar("amx_adminfreelook", "1")
	g_cvar_aflf = register_cvar("amx_adminfreelookflag", "d")
	g_mp_forcechasecam = get_cvar_pointer("mp_forcechasecam")
	g_mp_forcecamera = get_cvar_pointer("mp_forcecamera")
	
	new OrpheuFunction:Observer_FindNextPlayer = OrpheuGetFunction("Observer_FindNextPlayer", "CBasePlayer")
	OrpheuRegisterHook(Observer_FindNextPlayer, "OnObserver_FindNextPlayer")
	OrpheuRegisterHook(Observer_FindNextPlayer, "OnObserver_FindNextPlayer_Post", OrpheuHookPost)
}

public OnObserver_FindNextPlayer(const player, para1, para2)
{
	g_forcechasecam = get_pcvar_num(g_mp_forcechasecam)
	g_forcecamera = get_pcvar_num(g_mp_forcecamera)
	
	if(!get_pcvar_num(g_cvar_afl))
		return
	
	if(!g_forcechasecam && !g_forcecamera)
		return

	if(get_user_flags(player) & get_pcvar_flags(g_cvar_aflf))
	{
		set_pcvar_num(g_mp_forcechasecam, 0)
		set_pcvar_num(g_mp_forcecamera, 0)
	}
}

public OnObserver_FindNextPlayer_Post(const player, para1, para2)
{
	set_pcvar_num(g_mp_forcechasecam, g_forcechasecam)
	set_pcvar_num(g_mp_forcecamera, g_forcecamera)
}

The related file is not given.

Thanks for anyone who care about this. Or maybe no one does. This is all I can do.

[Arkshine]

You can try that :

Spoiler

PHP Code:

#include <amxmodx>
#include <orpheu>
#include <fakemeta>

#define PLUGIN_NAME       "Admin Free Look"
#define PLUGIN_AUTHOR  "Jim"
#define PLUGIN_VERSION "1.0"

new CvarAdminFreelook;
new CvarAdminFreeLookFlag;

new CvarForceChaseCam;
new CvarForceCamera;

new PlayerTeam;

const m_iTeam = 114;

const TEAM_UNASSIGNED = 0;
const TEAM_SPECTATOR = 3;

public plugin_init()
{
    register_plugin( PLUGIN_NAME, PLUGIN_AUTHOR, PLUGIN_VERSION );
    
    CvarAdminFreelook     = register_cvar( "amx_adminfreelook", "1" );
    CvarAdminFreeLookFlag = register_cvar( "amx_adminfreelookflag", "d" );
    
    CvarForceChaseCam = get_cvar_pointer( "mp_forcechasecam" );
    CvarForceCamera   = get_cvar_pointer( "mp_forcecamera" );
    
    new OrpheuFunction:Observer_FindNextPlayer = OrpheuGetFunction( "Observer_FindNextPlayer", "CBasePlayer" );
    
    OrpheuRegisterHook( Observer_FindNextPlayer, "OnObserver_FindNextPlayer_Pre" , OrpheuHookPre );
    OrpheuRegisterHook( Observer_FindNextPlayer, "OnObserver_FindNextPlayer_Post", OrpheuHookPost );
}

public OnObserver_FindNextPlayer_Pre( const player, const bool:searchDown, const playerNameToSearch[] )
{
    if( get_pcvar_num( CvarAdminFreelook ) ) 
    {
        new forceChaseCam = get_pcvar_num( CvarForceChaseCam );
        new forceCamera = get_pcvar_num( CvarForceCamera );
    
        if( ( forceChaseCam || forceCamera ) && get_user_flags( player ) & get_pcvar_flags( CvarAdminFreeLookFlag ) )
        {
            PlayerTeam = get_pdata_int( player, m_iTeam );
            set_pdata_int( player, m_iTeam, TEAM_SPECTATOR );
        }
    }
}

public OnObserver_FindNextPlayer_Post( const player, const bool:searchDown, const playerNameToSearch[] )
{
    if( PlayerTeam != TEAM_UNASSIGNED ) 
    {
        set_pdata_int( player, m_iTeam, PlayerTeam );
        PlayerTeam = TEAM_UNASSIGNED;
    }
} 


And put the attached file in : orpheu/functions/CBasePlayer/

[S0m3Th1nG_AwFul]

Thanks a lot again to you both! Problem seems to be completely solved for Linux at this moment, also say_team and score-table works properly for admins unlike pure-AMXX plugin.

[jim_yang]

Thank you again, Arkshine. Like always.