[SnowHP]

Can someone made a code that only AWP/Knife is allow on the server?

[trzmielu]

Hello,

have you tried this: https://forums.alliedmods.net/showthread.php?p=950174

Regards

[SnowHP]

Originally Posted by trzmielu Hello, have you tried this: https://forums.alliedmods.net/showthread.php?p=950174 Regards

I know! But that plugin prints mensages to chat Want something simpler

[zperkitny]

Here's something:

The players are unable to purchase any weapons and whenever they spawn, their pistols are removed, and are given an AWP.

Source:

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <cstrike>

#define PLUGIN_VERSION "0.0.2"

ConVar g_wrEnabled;

public Plugin myinfo =
{
    name = "Weapon Restriction",
    author = "Zach",
    description = "Restricts weapons to an AWP and Knife.",
    version = PLUGIN_VERSION
};

public void OnPluginStart()
{
  g_wrEnabled = CreateConVar("wr_enabled", "1", "Used to enable/disable AWP/Knife Weapon Restrictions.");
  g_wrEnabled.AddChangeHook(EnabledChange);
  HookEvent("player_spawn", Event_OnPlayerSpawn);
}

/* used to prevent users from buying items */
public Action CS_OnBuyCommand(int client, const char[] weapon)
{
  if(g_wrEnabled.IntValue){ // if enabled
    return Plugin_Handled;
  }
  return Plugin_Continue;
}

public void Event_OnPlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
  if(!g_wrEnabled.IntValue){ //if disabled, dont do anything
    return;
  }
  int client = GetClientOfUserId(event.GetInt("userid"));
  if(client) //ensure valid user
    removeWeaponsAndGiveAwp(client);
}

public void EnabledChange(ConVar convar, char[] oldValue, char[] newValue)
{
  bool wasEnabled = !StrEqual(oldValue, "0");
  bool enabled = !StrEqual(newValue, "0");
  if(!wasEnabled && enabled)
  {
    int i;
    for(i = 1; i <= MaxClients; i++){
      if(IsClientConnected(i)){
        removeWeaponsAndGiveAwp(i);
      }
    }
  }
}

void removeWeaponsAndGiveAwp(client){
  int team = GetClientTeam(client);
  if(team != 1) // if the player isn't a spectator
  {
    int i;
    for(i = 0; i < 5; i++) // remove all weapons
    {
      int weapon;
      while((weapon = GetPlayerWeaponSlot(client, i)) != -1)
      {
        RemovePlayerItem(client, weapon);
      }
    }
    GivePlayerItem(client, "weapon_knife");
    GivePlayerItem(client, "weapon_awp");
  }
} 


[martvonk]

Originally Posted by zperkitny Here's something: The players are unable to purchase any weapons and whenever they spawn, their pistols are removed, and are given an AWP. Source: PHP Code: #include <sourcemod> #include <sdktools> #include <cstrike> #define PLUGIN_VERSION "0.0.1" public Plugin myinfo = {     name = "Weapon Restriction",     author = "Zach",     description = "Restricts weapons to an AWP and Knife.",     version = PLUGIN_VERSION }; public void OnPluginStart() {   HookEvent("player_spawn", Event_OnPlayerSpawn); } /* used to prevent users from buying items */ public Action CS_OnBuyCommand(int client, const char[] weapon) {   return Plugin_Handled; } public void Event_OnPlayerSpawn(Event event, const char[] name, bool dontBroadcast) {   int client = GetClientOfUserId(event.GetInt("userid"));   if(client) // ensure valid userid   {     int team = GetClientTeam(client);     if(team != 1) // if the player isn't a spectator     {       /* remove pistol (slot id 1) */       int weapon = GetPlayerWeaponSlot(client, 1);       if(weapon != -1) // make sure weapon exists         RemovePlayerItem(client, weapon);       /* give user an awp */       GivePlayerItem(client, "weapon_awp");     }   } }

thx, can you add a cvar, soo we disable/enable it,

[zperkitny]

Originally Posted by martvonk thx, can you add a cvar, soo we disable/enable it,

Yes I will, I have some work to do right now, but I'll update the code sometime this evening.

[SnowHP]

Originally Posted by zperkitny Here's something: The players are unable to purchase any weapons and whenever they spawn, their pistols are removed, and are given an AWP. Source: PHP Code: #include <sourcemod> #include <sdktools> #include <cstrike> #define PLUGIN_VERSION "0.0.1" public Plugin myinfo = {     name = "Weapon Restriction",     author = "Zach",     description = "Restricts weapons to an AWP and Knife.",     version = PLUGIN_VERSION }; public void OnPluginStart() {   HookEvent("player_spawn", Event_OnPlayerSpawn); } /* used to prevent users from buying items */ public Action CS_OnBuyCommand(int client, const char[] weapon) {   return Plugin_Handled; } public void Event_OnPlayerSpawn(Event event, const char[] name, bool dontBroadcast) {   int client = GetClientOfUserId(event.GetInt("userid"));   if(client) // ensure valid userid   {     int team = GetClientTeam(client);     if(team != 1) // if the player isn't a spectator     {       /* remove pistol (slot id 1) */       int weapon = GetPlayerWeaponSlot(client, 1);       if(weapon != -1) // make sure weapon exists         RemovePlayerItem(client, weapon);       /* give user an awp */       GivePlayerItem(client, "weapon_awp");     }   } }

Thx For Help

[zperkitny]

Originally Posted by SnowHP Thx For Help

I updated my original response with a convar for enabling/disabling the plugin. If, for example, you decide to enable the plugin in the middle of the round, it will remove every player's (including bots) weapons and give them an awp and a knife. I haven't tested it, so let me know if there's anything you want me change/fix.

[SnowHP]

Originally Posted by zperkitny I updated my original response with a convar for enabling/disabling the plugin. If, for example, you decide to enable the plugin in the middle of the round, it will remove every player's (including bots) weapons and give them an awp and a knife. I haven't tested it, so let me know if there's anything you want me change/fix.

For me this is perfect! 100% working thx