[wendigo]

My l4d2 server randomly crashes. And I suspect it might have something to do with this plugin someone was kind enough to make for me o nthe fly, a very very long time ago. Untested by anybody except only uploaded on my server.
The plugin reflects any teamdamage, back to the shooter. But not for admin. For admin, he can teamkill anybody.
Could anybody help me clean or see if any changes are needed?
This is the plugin that was made.

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdkhooks>

bool bSmoked[MAXPLAYERS+1];

public void OnPluginStart()
{
    HookEvent("round_start", OnRoundStart);
    
    HookEvent("tongue_grab", OnTongueGrab);
    HookEvent("tongue_release", OnTongueRelease);
}

public void OnPluginEnd()
{
    UnhookEvent("round_start", OnRoundStart);
    
    UnhookEvent("tongue_grab", OnTongueGrab);
    UnhookEvent("tongue_release", OnTongueRelease);
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            SDKUnhook(i, SDKHook_OnTakeDamage, OnTakeDamage);
        }
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3])
{
    if (!IsSurvivor(victim) || IsDominated(victim) || IsGettingUp(victim) || !IsSurvivor(attacker) || !IsPlayerAlive(attacker) || attacker == victim)
    {
        return Plugin_Continue;
    }
    
    if (CheckCommandAccess(attacker, "sm_admin", ADMFLAG_GENERIC) || IsPhysicsProp(inflictor) || IsGrenade(inflictor))
    {
        return Plugin_Continue;
    }
    
    SDKHooks_TakeDamage(attacker, inflictor, attacker, damage, damagetype, weapon, damageForce, damagePosition);
    
    damage = 0.0;
    return Plugin_Changed;
}

public void OnClientDisconnect(int client)
{
    SDKUnhook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public void OnMapStart()
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            bSmoked[i] = false;
        }
    }
}

public void OnRoundStart(Event event, const char[] name, bool dontBroadcast)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            bSmoked[i] = false;
        }
    }
}

public void OnTongueGrab(Event event, const char[] name, bool dontBroadcast)
{
    int grabbed = GetClientOfUserId(event.GetInt("victim"));
    if (!IsSurvivor(grabbed) || bSmoked[grabbed])
    {
        return;
    }
    
    bSmoked[grabbed] = true;
}

public void OnTongueRelease(Event event, const char[] name, bool dontBroadcast)
{
    int released = GetClientOfUserId(event.GetInt("victim"));
    if (!IsSurvivor(released) || !bSmoked[released])
    {
        return;
    }
    
    bSmoked[released] = false;
}

bool IsDominated(int client)
{
    return (GetEntProp(client, Prop_Send, "m_isIncapacitated", 1) || bSmoked[client] || GetEntPropEnt(client, Prop_Send, "m_pounceAttacker") > 0 || 
        GetEntPropEnt(client, Prop_Send, "m_jockeyAttacker") > 0 || GetEntPropEnt(client, Prop_Send, "m_carryAttacker") > 0 || GetEntPropEnt(client, Prop_Send, "m_pummelAttacker") > 0);
}

bool IsGettingUp(int client)
{
    int iSequence = GetEntProp(client, Prop_Send, "m_nSequence");
    
    char sModel[128];
    GetEntPropString(client, Prop_Data, "m_ModelName", sModel, sizeof(sModel));
    if (StrEqual(sModel, "models/survivors/survivor_gambler.mdl", false))
    {
        if (iSequence == 620 || iSequence == 629 || iSequence == 667 || iSequence == 671 || iSequence == 672)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_producer", false) || StrEqual(sModel, "models/survivors/survivor_adawong.mdl", false))
    {
        if (iSequence == 629 || iSequence == 637 || iSequence == 674 || iSequence == 678 || iSequence == 679)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_coach.mdl", false))
    {
        if (iSequence == 621 || iSequence == 629 || iSequence == 656 || iSequence == 660 || iSequence == 661)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_mechanic.mdl", false))
    {
        if (iSequence == 625 || iSequence == 634 || iSequence == 671 || iSequence == 675 || iSequence == 676)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_namvet.mdl", false) || StrEqual(sModel, "models/survivors/survivor_manager.mdl", false))
    {
        if (iSequence == 528 || iSequence == 537 || iSequence == 759 || iSequence == 763 || iSequence == 764)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_teenangst.mdl", false))
    {
        if (iSequence == 537 || iSequence == 546 || iSequence == 819 || iSequence == 823 || iSequence == 824)
        {
            return true;
        }
    }
    else if (StrEqual(sModel, "models/survivors/survivor_biker.mdl", false))
    {
        if (iSequence == 531 || iSequence == 540 || iSequence == 762 || iSequence == 766 || iSequence == 767)
        {
            return true;
        }
    }
    
    return false;
}

stock bool IsSurvivor(int client)
{
    return (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2);
}

stock bool IsPhysicsProp(int entity)
{
    if (entity > 0 && IsValidEntity(entity) && IsValidEdict(entity))
    {
        char sEntityClass[64];
        GetEdictClassname(entity, sEntityClass, sizeof(sEntityClass));
        return StrEqual(sEntityClass, "prop_physics");
    }
    
    return false;
}

stock bool IsGrenade(int entity)
{
    if (entity > 0 && IsValidEntity(entity) && IsValidEdict(entity))
    {
        char sEntityClass[64];
        GetEdictClassname(entity, sEntityClass, sizeof(sEntityClass));
        return (StrEqual(sEntityClass, "inferno") || StrEqual(sEntityClass, "pipe_bomb_projectile"));
    }
    
    return false;
} 


[Marttt]

Remove the plugin and test if it crashes without it, this is the first trial you should do.

Also, this "Unkook" stuff isn't necessary cause SM already does that for you on client disconnect and plugin end.

Probably someone else will ask for you to install Accelerator crash dump (if you don't have it) and share the dump.

[Grey83]

Originally Posted by wendigo Could anybody help me clean or see if any changes are needed?

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sdkhooks>

bool
    bSmoked[MAXPLAYERS+1];
char
    sBuffer[44];

public void OnPluginStart()
{
    HookEvent("round_start", OnRoundStart);

    HookEvent("tongue_grab", OnTongueAction);
    HookEvent("tongue_release", OnTongueAction);

    for(int i = 1; i <= MaxClients; i++) if(IsClientInGame(i)) SDKHook(i, SDKHook_OnTakeDamage, OnTakeDamage);
}

public void OnMapStart()
{
    for(int i = 1; i <= MaxClients; i++) if(bSmoked[i]) bSmoked[i] = false;
}

public void OnRoundStart(Event event, const char[] name, bool dontBroadcast)
{
    OnMapStart();
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public void OnClientDisconnect(int client)
{
    bSmoked[client] = false;
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3])
{
    if(GetClientTeam(victim) != 2 || IsDominated(victim) || IsGettingUp(victim) || !IsSurvivor(attacker)
    || !IsPlayerAlive(attacker) || attacker == victim || CheckCommandAccess(attacker, "sm_admin", ADMFLAG_GENERIC)
    || IsPhysicsProp(inflictor) || IsGrenade(inflictor))
        return Plugin_Continue;

    SDKHooks_TakeDamage(attacker, inflictor, attacker, damage, damagetype, weapon, damageForce, damagePosition);

    damage = 0.0;
    return Plugin_Changed;
}

public void OnTongueAction(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("victim"));
    if(IsSurvivor(client)) bSmoked[client] = name[7] == 'g';
}

bool IsDominated(int client)
{
    return GetEntProp(client, Prop_Send, "m_isIncapacitated", 1) || bSmoked[client]
        || GetEntPropEnt(client, Prop_Send, "m_pounceAttacker") > 0
        || GetEntPropEnt(client, Prop_Send, "m_jockeyAttacker") > 0
        || GetEntPropEnt(client, Prop_Send, "m_carryAttacker") > 0
        || GetEntPropEnt(client, Prop_Send, "m_pummelAttacker") > 0;
}

bool IsGettingUp(int client)
{
    GetEntPropString(client, Prop_Data, "m_ModelName", sBuffer, sizeof(sBuffer));
    if(strncmp(sBuffer, "models/survivors/survivor_", 26, false))
        return false;

    int iSequence = GetEntProp(client, Prop_Send, "m_nSequence");

    if(!strcmp(sBuffer[26], "gambler.mdl", false))
        return iSequence == 620 || iSequence == 629 || iSequence == 667 || iSequence == 671 || iSequence == 672;
    else if(!strcmp(sBuffer[26], "producer.mdl", false) || !strcmp(sBuffer[26], "adawong.mdl", false))
        return iSequence == 629 || iSequence == 637 || iSequence == 674 || iSequence == 678 || iSequence == 679;
    else if(!strcmp(sBuffer[26], "coach.mdl", false))
        return iSequence == 621 || iSequence == 629 || iSequence == 656 || iSequence == 660 || iSequence == 661;
    else if(!strcmp(sBuffer[26], "mechanic.mdl", false))
        return iSequence == 625 || iSequence == 634 || iSequence == 671 || iSequence == 675 || iSequence == 676;
    else if(!strcmp(sBuffer[26], "manager.mdl", false) || !strcmp(sBuffer[26], "namvet.mdl", false))
        return iSequence == 528 || iSequence == 537 || iSequence == 759 || iSequence == 763 || iSequence == 764;
    else if(!strcmp(sBuffer[26], "teenangst.mdl", false))
        return iSequence == 537 || iSequence == 546 || iSequence == 819 || iSequence == 823 || iSequence == 824;
    else if(!strcmp(sBuffer[26], "biker.mdl", false))
        return iSequence == 531 || iSequence == 540 || iSequence == 762 || iSequence == 766 || iSequence == 767;

    return false;
}

stock bool IsSurvivor(int client)
{
    return 0 < client && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2;
}

stock bool IsPhysicsProp(int entity)
{
    return MaxClients < entity && IsValidEntity(entity) && IsValidEdict(entity)
        && GetEdictClassname(entity, sBuffer, sizeof(sBuffer)) && !strcmp(sBuffer, "prop_physics");
}

stock bool IsGrenade(int entity)
{
    return MaxClients < entity && IsValidEntity(entity) && IsValidEdict(entity)
        && GetEdictClassname(entity, sBuffer, sizeof(sBuffer))
        && (!strcmp(sBuffer, "inferno") || !strcmp(sBuffer, "pipe_bomb_projectile"));
} 


[wendigo]

Thanks, I dont know what has been changed or added. But I will upload and test it

[wendigo]

Unfortunately my server still crashes. As soon I remove plugin, it doesn't crash anymore.

Is it possible to make a more simple version of this plugin here?
Like it only works for admin, and nobody else?

[Marttt]

what could crash is a bad parameter in SDKHooks_TakeDamage, I would comment this line and try the plugin without it for a while, if no crashes probably is there.

saying this because already had crash issues with TakeDamage sdkhooks functions.

Also check if you have dissolve infected plugin installed.

[Silvers]

You could try replacing "SDKHook_OnTakeDamage" with "SDKHook_OnTakeDamageAlive" I found sometimes the former crashed while the latter worked better.

[wendigo]

I really appreciate info and feedback guys.

I have below average when it comes to plugins. And you both pinpoint to SDKHook_OnTakeDamage could be the cursed one.

I will take Grey83's updated code, remove SDKHook_OnTakeDamage and paste it with add SDKHook_OnTakeDamageAlive.