[bLacK-bLooD]

L 11/20/2013 - 16:35:36: FATAL ERROR (shutting down): Invalid message;  cannot use broadcast message with a target entity

Ok guys, this is the error, and this is the code :

PHP Code:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "Bomb Blast"
#define VERSION "0.4"
#define AUTHOR "K.K.Lv"

new HamHook:g_BombThink

new g_Bomb

new g_SpriteCircle

new Float:g_fExplodeTime
new Float:g_fNextBlastGameTime

public plugin_precache()
{
    g_SpriteCircle = precache_model( "sprites/shockwave.spr" )
}

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, AUTHOR )
    
    if( find_ent_by_class( FM_NULLENT, "func_bomb_target" ) || find_ent_by_class( FM_NULLENT, "info_bomb_target" ) )
    {
        g_BombThink = RegisterHam( Ham_Think, "grenade", "Bomb_Think", 1 )
        
        register_event( "HLTV", "Stop", "a", "1=0", "2=0" )
        register_logevent( "Stop", 2, "1=Round_End" )
        
        register_logevent( "PlantedBomb", 3, "2=Planted_The_Bomb" )
    }
}

public Stop()
{
    g_Bomb = 0
    DisableHamForward( g_BombThink)
}

public PlantedBomb()
{
    new C4 = FM_NULLENT
    while( ( C4 = find_ent_by_class( C4, "grenade" ) ) )
    {
        if ( get_pdata_int( C4, 96 ) & ( 1<<8 ) )
        {
            g_Bomb = C4
            g_fExplodeTime = get_pdata_float( g_Bomb, 100 )
            EnableHamForward( g_BombThink )
            
            g_fNextBlastGameTime = 0.0
            break 
        }
    }
}

public Bomb_Think( iEnt )
{
    if ( g_Bomb != iEnt )
        return
    
    new Float:fGameTime = get_gametime()
    if( g_fNextBlastGameTime > fGameTime )
        return
    
    new Float:fTime, iTime, Float:fThinkTime
    
    fTime = g_fExplodeTime - fGameTime
    iTime = floatround( fTime )
    
    if ( iTime > 13 ) fThinkTime = 1.0
    else if ( iTime > 7 ) fThinkTime = 0.5
    else  fThinkTime = 0.3
    
    g_fNextBlastGameTime = fGameTime + fThinkTime
    
    create_blast_circle( iEnt )
}

public create_blast_circle( iEnt ) {
    new Float:fOrigin[ 3 ]
    
    pev( iEnt, pev_origin, fOrigin )
    
    engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin )
    write_byte( TE_BEAMCYLINDER )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] + 35 )
    write_short( g_SpriteCircle )
    write_byte( 0 )
    write_byte( 1 )
    write_byte( 6 )
    write_byte( 8 )
    write_byte( 1 )
    write_byte( 0 ) //R
    write_byte( 100 ) //G
    write_byte( 255 ) //B
    write_byte( 128 )
    write_byte( 5 )
    message_end()
    
    engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin )
    write_byte( TE_BEAMCYLINDER )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] + 70 )
    write_short( g_SpriteCircle )
    write_byte( 0 )
    write_byte( 1 )
    write_byte( 6 )
    write_byte( 8 )
    write_byte( 1 )
    write_byte( 255 ) //R
    write_byte( 0 ) //G
    write_byte( 0 ) //B
    write_byte( 128 )
    write_byte( 5 )
    message_end()
    
    engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin )
    write_byte( TE_BEAMCYLINDER )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] + 100 )
    write_short( g_SpriteCircle )
    write_byte( 0 )
    write_byte( 1 )
    write_byte( 6 )
    write_byte( 8 )
    write_byte( 1 )
    write_byte( 0 )
    write_byte( 100 ) //R
    write_byte( 255 ) //G
    write_byte( 128 ) //B
    write_byte( 5 )
    message_end()
} 


I did some research and there is just 1 topic with the same problem, but the guy couldn't find the solution either.

How can i solve this?

[akcaliberg]

engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin )

->

engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin, 0 )

[bLacK-bLooD]

Originally Posted by akcaliberg engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin ) -> engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin, 0 )

This worked, thank you.