[bLacK-bLooD]

Hi,

I own a kreedz server and from the moment a player starts its run until he finishes, I would like to detect the maximum speed the player achieved during the run.

I have a start climb and end climb function, I just need to know how to store the climber's highest speed and show it at the end of the climb.

I am thinking:

• create a task at start_climb to run every 5 seconds
• get the current speed of the climber
• store the new one if higher

The downside of that is during the 5 seconds he might have had a higher speed and I didn't catch that.

What would be the best way to do it/most performant way to do it?

Thank you!

[Garey]

Originally Posted by bLacK-bLooD Hi, I own a kreedz server and from the moment a player starts its run until he finishes, I would like to detect the maximum speed the player achieved during the run. I have a start climb and end climb function, I just need to know how to store the climber's highest speed and show it at the end of the climb. I am thinking: create a task at start_climb to run every 5 seconds get the current speed of the climber store the new one if higher The downside of that is during the 5 seconds he might have had a higher speed and I didn't catch that. What would be the best way to do it/most performant way to do it? Thank you!

Just capture speed in PreThink? in kreedz-world there ljstats what a do many more calculations in prethink so...

[JocAnis]

yes check it in prethink...task in 5 secs will probably miss something, prethink is called in every 0,001 sec if im not mistaken

[bLacK-bLooD]

Thanks for the answere guys.

I ended up using Ham_Think on “player”, because it’s better performance wise than FM_Think, since it’s only called on players, not on all entities.

[Bugsy]

PreThink is overkill for this, use a thinking entity with a 0.1-0.3 interval to check speed.

The below will determine a players max run speed. To test, say 'start', run around, and then say 'end'.

PHP Code:


#include <amxmodx>
#include <engine>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

const Float:SpeedCheckInterval = 0.2;

new Float:g_fMaxSpeed[ MAX_PLAYERS + 1 ] , g_Entity , g_PlayersInClimb;

public plugin_init() 
{
    register_plugin( "Get Max Speed" , Version , "bugsy" );
    
    g_Entity = create_entity( "info_target" );
    entity_set_string( g_Entity , EV_SZ_classname , "speed_entity" );
    register_think( "speed_entity" , "EntityThink" );

    register_clcmd( "say start" , "ClimbStart" );
    register_clcmd( "say end" , "ClimbEnd" );
}

public ClimbStart( id )
{
    if ( !g_PlayersInClimb )
    {
        entity_set_float( g_Entity , EV_FL_nextthink , ( get_gametime() + SpeedCheckInterval ) );
    }
    
    g_PlayersInClimb |= ( 1 << ( id & 31 ) );
    
    g_fMaxSpeed[ id ] = 0.0;
}

public ClimbEnd( id )
{
    g_PlayersInClimb &= ~( 1 << ( id & 31 ) );
    
    client_print( id , print_chat , "Max speed (units/second) = %f" , g_fMaxSpeed[ id ] );
}

public EntityThink( iEntity )
{
    new iPlayers[ 32 ] , iNum , Float:fVecVelocity[ 3 ] , Float:fSpeed;
    
    if( iEntity == g_Entity ) 
    {
        get_players( iPlayers , iNum , "ah" );
        
        for ( new id , i = 0 ; i < iNum ; i++ )
        {
            id = iPlayers[ i ];
            
            if ( g_PlayersInClimb & ( 1 << ( id & 31 ) ) )
            {
                entity_get_vector( id , EV_VEC_velocity , fVecVelocity );
                fSpeed = floatsqroot( floatpower( fVecVelocity[ 0 ] , 2.0 ) + floatpower( fVecVelocity[ 1 ] , 2.0 ) );
                
                if ( fSpeed > g_fMaxSpeed[ id ] )
                {
                    g_fMaxSpeed[ id ] = fSpeed;
                }
            }
        }
    }
    
    if ( g_PlayersInClimb )
    {
        entity_set_float( g_Entity , EV_FL_nextthink , ( get_gametime() + SpeedCheckInterval ) );
    }
} 


[klippy]

It's really not overkill, in KreedZ world (supposedly this is for KreedZ) you want to be frame perfect with stats.

[bLacK-bLooD]

Yes, it is for kreedz, therefore it must be frame perfect with stats.

Should I therefore use Bugsy's approach or use Ham_Think on player?