[jedyny]

Hello,

I need a plugin that would show TOP 3 players with most kills in HUD using ShowHudText.

It would look like this:

Player1 Kills: 15
Player2 Kills: 12
Player2 Kills: 10

Thanks in advance!

[Ilusion9]

PHP Code:


#include <sourcemod>
#include <sdktools>
#include <cstrike>

#pragma newdecls required

int g_ClientKills[MAXPLAYERS + 1];

public void OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
    
    CreateTimer(1.0, Timer_DisplayTopKills, _, TIMER_REPEAT);
}

public Action Timer_DisplayTopKills(any data)
{
    DisplayTopKills();
}

public void OnClientConnected(int client)
{
    g_ClientKills[client] = 0;
}

public void Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    int client = GetClientOfUserId(event.GetInt("userid"));

    if (attacker && attacker != client)
    {
        g_ClientKills[attacker]++;
        DisplayTopKills();
    }
}

void DisplayTopKills()
{
    int num, clients[MAXPLAYERS + 1];
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            clients[num] = i;
            num++;
        }
    }
    
    if (num)
    {
        SortCustom1D(clients, num, sortKills);
        
        char buffer[256];
        Format(buffer, sizeof(buffer), "1.%N - %d kills\n", clients[0], g_ClientKills[clients[0]]);
        
        if (num > 1)
        {
            Format(buffer, sizeof(buffer), "%s2.%N - %d kills\n", buffer, clients[1], g_ClientKills[clients[1]]);
        }
        
        if (num > 2)
        {
            Format(buffer, sizeof(buffer), "%s3.%N - %d kills", buffer, clients[2], g_ClientKills[clients[2]]);
        }
        
        PrintHintTextToAll(buffer);
    }
}

int sortKills(int elem1, int elem2, const int[] array, Handle hndl)
{
    if (g_ClientKills[elem1] > g_ClientKills[elem2])
    {
        return -1;
    }
    
    else if (g_ClientKills[elem1] < g_ClientKills[elem2])
    {
        return 1;
    }
    
    return 0;
} 


[jedyny]

Works perfectly. Thank you!

Just one more thing - I would like to add player position so it would look like this:

1. Player1 Kills X
2. Player2 Kills X

How can I do that?

[Ilusion9]

Originally Posted by jedyny Works perfectly. Thank you! Just one more thing - I would like to add player position so it would look like this: 1. Player1 Kills X 2. Player2 Kills X How can I do that?

Done, check my previous post again.

[jedyny]

Thank you

[XHUNTERX]

warning 203: symbol is never used: "hndl"

warning 203: symbol is never used: "array"

help pls ?