[Trum]

Hi!

I need a plugin that can votekick with the regular votekick for csgo, in the top left corner where you press f1 or f2

Features:

> Only for vip (flag "a")
> You can only do it 2 times per match
> I have competitive servers so the result need's to be 4 yes to kick someone

[eyal282]

Originally Posted by Trum Hi! I need a plugin that can votekick with the regular votekick for csgo, in the top left corner where you press f1 or f2 Features: > Only for vip (flag "a") > You can only do it 2 times per match > I have competitive servers so the result need's to be 4 yes to kick someone

A place to start is here:
https://wiki.alliedmods.net/Counter-...e_UserMessages

Also what you need to do yourself ( I forgot if I'm in request forum or scripting help but it'll help all )
https://developer.valvesoftware.com/...of_CS:GO_Cvars

The list of cvars allows me to CTRL + F this cvar: sv_vote_quorum_ratio

The cvar should be set to 0.8 which means 80% of voters needed to succeed ( 4 divided by 5 = 0.8 )

[Powerlord]

Originally Posted by eyal282 A place to start is here: https://wiki.alliedmods.net/Counter-...e_UserMessages Also what you need to do yourself ( I forgot if I'm in request forum or scripting help but it'll help all ) https://developer.valvesoftware.com/...of_CS:GO_Cvars The list of cvars allows me to CTRL + F this cvar: sv_vote_quorum_ratio The cvar should be set to 0.8 which means 80% of voters needed to succeed ( 4 divided by 5 = 0.8 )

Bearing in mind that I haven't touched the CS:GO voting system in at least 3 years....

You'd probably want to hook the callvote console command unless you really want to reimplement the entire vote system in a plugin (the NativeVotes plugin has an API for this, but it's probably out of date since I haven't touched it in years).

Of course, you have to check which vote is being called before you decide to handle it. As I recall, the first argument to callvote will be the vote type with "Kick" being the kick vote type. The second argument is the userid that the person is trying to start a vote to kick.

[Trum]

Originally Posted by eyal282 A place to start is here: https://wiki.alliedmods.net/Counter-...e_UserMessages Also what you need to do yourself ( I forgot if I'm in request forum or scripting help but it'll help all ) https://developer.valvesoftware.com/...of_CS:GO_Cvars The list of cvars allows me to CTRL + F this cvar: sv_vote_quorum_ratio The cvar should be set to 0.8 which means 80% of voters needed to succeed ( 4 divided by 5 = 0.8 )

Im looking for someone to code a plugin, i can 't code myself.

[Bacardi]

these are from csgo

] listissues 
---Vote commands---
callvote Kick <userID>
--- End Vote commands---
---Vote commands---
callvote ChangeLevel <mapname>
callvote ScrambleTeams
callvote SwapTeams
--- End Vote commands---

nvm

*edit
Like this ?

PHP Code:

int votecalls[MAXPLAYERS] = {2,...};


public void OnPluginStart()
{
    AddCommandListener(listen, "callvote");
    HookEventEx("round_announce_match_start", round_announce_match_start, EventHookMode_PostNoCopy);
}

public void round_announce_match_start(Event event, const char[] name, bool dontBroadcast)
{
    for(int a = 0; a < sizeof(votecalls); a++) votecalls[a] = 2;
}

public Action listen(int client, const char[] command, int args)
{
    if(!IsClientInGame(client)) return Plugin_Handled;

    char buffer[MAX_NAME_LENGTH];
    GetCmdArg(1, buffer, sizeof(buffer));

    if(!StrEqual(buffer, "kick", false)) return Plugin_Continue;

    GetCmdArg(2, buffer, sizeof(buffer));

    int userid = StringToInt(buffer);
    int target = GetClientOfUserId(userid);

    if(target == 0)
    {
        PrintToChat(client, "[SM] Call vote Kick - Invalid UserId %i", userid);
        return Plugin_Handled;
    }

    if(!CheckCommandAccess(client, "callvote_kick", ADMFLAG_RESERVATION))
    {
        PrintToChat(client, "[SM] Call vote Kick - is restricted");
        return Plugin_Handled;
    }

    if(!CanUserTarget(client, target))
    {
        PrintToChat(client, "[SM] Call vote Kick - you can't target %N", target);
        return Plugin_Handled;
    }


    if(votecalls[client] <= 0)
    {
        PrintToChat(client, "[SM] Call vote Kick - you used all 2 call votes in this match");
        return Plugin_Handled;
    }

    PrintToChat(client, "[SM] Call vote Kick - %i vote calls remaining", --votecalls[client]);

    return Plugin_Continue;
} 


[zwolofmeister]

Ill test this out later