[Survival]

Hi, can some one create auto witch team, which will work with 32 players.
Or fix this one https://forums.alliedmods.net/showthread.php?t=137016, bcz with nikhilgupta345 my server with 32 players crashing.

Thanks for your help.

[nikhilgupta345]

Try this. I re-wrote the plugin:

PHP Code:

// Includes
////////////

#include < amxmodx >
#include < amxmisc >
#include < cstrike >

// Integers
////////////

new g_iCurrentRound;

// PCVars
//////////

new g_pRoundToSwitch;

public plugin_init()
{
    register_plugin( "Switch Teams", "1.1", "nikhilgupta345" );
    
    register_clcmd( "say /roundnumber", "CmdDisplayRound" );
    
    register_logevent( "Event_RoundEnd", 2, "1=Round_End" );
    
    register_event( "TextMsg", "Event_GameRestart", "a", "2&#Game_C", "2&#Game_W" ); // Event for "Game Commencing" TextMsg and "Game Will Restart in X Seconds" TextMsg
    
    g_pRoundToSwitch = register_cvar( "amx_atsrounds", "15" );
}

public Event_GameRestart( id )
{
    g_iCurrentRound = 1;
}

public Event_RoundEnd()
{
    if( g_iCurrentRound >= get_pcvar_num( g_pRoundToSwitch ) )
    {
        new iPlayers[ 32 ], iNum;
        get_players( iPlayers, iNum );
        
        new iPlayer;
        new CsTeams:iTeam;
        
        for( new i = 0; i < iNum; i++ )
        {
            iPlayer = iPlayers[ i ];
            
            iTeam = cs_get_user_team( iPlayer );
            
            if( iTeam == CS_TEAM_CT || iTeam == CS_TEAM_T )
            {
                add_delay( iPlayer );
            }
        }
        
        g_iCurrentRound = 0;
    }
    
    g_iCurrentRound++;
}

public ChangeTeam( id )
{
    switch( cs_get_user_team( id ) )
    {
        case CS_TEAM_CT: cs_set_user_team( id, CS_TEAM_T );
        case CS_TEAM_T: cs_set_user_team( id, CS_TEAM_CT );
    }
}

public CmdDisplayRound( id )
{    
    client_print( id, print_chat, "[ATS] It is currently round %d.", g_iCurrentRound );
    return PLUGIN_HANDLED;
}

add_delay( id )
{
    set_task( 0.1 * (1 + ((id-1) / 8)), "ChangeTeam", id );
} 


[joaquimandrade]

Just for your information (don't know if you are aware of that), you can make this:

PHP Code:

add_delay( id )
{
    switch( id )
    {
        case 1..8: set_task( 0.1, "ChangeTeam", id );
        case 9..16: set_task( 0.2, "ChangeTeam", id );
        case 17..24: set_task( 0.3, "ChangeTeam", id );
        case 25..32: set_task( 0.4, "ChangeTeam", id );
     }
} 


PHP Code:

add_delay( id )
{
    set_task( 0.1 * (1 + ((id-1) / 8)), "ChangeTeam", id );
} 


[Survival]

nikhilgupta345, server crashing wiyh error:

[nikhilgupta345]

Originally Posted by joaquimandrade Just for your information (don't know if you are aware of that), you can make this: PHP Code: add_delay( id ) {     switch( id )     {         case 1..8: set_task( 0.1, "ChangeTeam", id );         case 9..16: set_task( 0.2, "ChangeTeam", id );         case 17..24: set_task( 0.3, "ChangeTeam", id );         case 25..32: set_task( 0.4, "ChangeTeam", id );      } }  PHP Code: add_delay( id ) {     set_task( 0.1 * (1 + ((id-1) / 8)), "ChangeTeam", id ); }

Didn't feel like doing the math when I wrote it. Just took it from my old plugin. Thanks for doing the math for me Added.

Originally Posted by Survival nikhilgupta345, server crashing wiyh error:

Hmm, that's wierd. Try running it as the only 3rd party plugin running on the server.