[jugule]

Use this code to display the name of the player who is "Simon". (Jailbreak)
only I only see the name in hud, the others don't see it. what would be the problem?

PHP Code:


for(new client = 1; client <= MaxClients; client++)  
    {
        if(IsClientInGame(client))
        {
            
                if(Warden == 1)
                {
    
                    SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);  
                    ShowHudText(client, 1, "%N is Simon", Warden);
                }
                else 
                {
                    SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);  
                    ShowHudText(client, 1, "No simon"]);
                }
            } 


Warden = it's "Simon." I mention again that only I see that they are "Simon", the other players, no.

[drespy]

Try to change HUD channel param, use automatic (-1).

PHP Code:

                {
    
                    SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);  
                    ShowHudText(client, -1, "%N is Simon", Warden);
                }
                else 
                {
                    SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);  
                    ShowHudText(client, -1, "No simon");
                } 


[jugule]

Originally Posted by drespy Try to change HUD channel param, use automatic (-1). PHP Code:                 {                          SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);                       ShowHudText(client, -1, "%N is Simon", Warden);                 }                 else                  {                     SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 1, 0, 0.1, 0.1, 0.1);                       ShowHudText(client, -1, "No simon");                 }

don't work

Full code:

PHP Code:

int Warden -1;

public void OnPluginStart()
{    
    RegConsoleCmd("sm_warden", Command_Warden);
}

public Action Command_Warden(int client) 
{
Warden = client;
PrintToChat(client, "you are simon!")
}

public Action Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast)  
{
CreateTimer(1.0, HudInfoJB, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action HudInfoJB(Handle timer)
{

    for(int client = 1; client <= MaxClients; client++)
    {
        if(IsValidClient(client))
        {
            if(Warden == 1)
            {
                
                   SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 5, 0, 0.1, 0.1, 0.1);  
                   ShowHudText(client, 1, "Simon is: %N", Warden);
            }
            else
            {
                    SetHudTextParams(-1.0, 0.0, 5.0, 74, 255, 255, 5, 0, 0.1, 0.1, 0.1);  
                    ShowHudText(client, 1, "No Simon!");
             }
        }
    }
} 


Simon's name does not appear. what do you think would be the solution? can you help me?

[MAGNAT2645]

You can also replace ShowHudText with ShowSyncHudText but you need to CreateHudSynchronizer first.

[Grey83]

Try this:

PHP Code:

int
    Warden = -1;
Handle
    hHUD;

public void OnPluginStart()
{
    hHUD = CreateHudSynchronizer();

    RegConsoleCmd("sm_warden", Command_Warden);
}

public void OnMapStart()
{
    Warden = -1;
    CreateTimer(1.0, HudInfoJB, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action Command_Warden(int client, int args)
{
    if(!client || Warden != -1) return Plugin_Handled;

    Warden = client;
    PrintToChat(client, "You are Simon!")

    return Plugin_Handled;
}

public void OnClientDisconnect(int client)
{
    if(client == Warden) Warden = -1;
}

public Action HudInfoJB(Handle timer)
{
    SetHudTextParams(-1.0, 0.0, 1.1, 74, 255, 255, 5, 0, 0.1, 0.1, 0.1);
    for(int i = 1; i <= MaxClients; i++) if(IsValidClient(i))
    {
        if(Warden != -1)
            ShowSyncHudText(i, hHUD, "Simon is: %N", Warden);
        else ShowSyncHudText(i, hHUD, "No Simon!");
    }
}

stock bool IsValidClient(int client)
{
    return IsClientInGame(client) && !IsFakeClient(client);
}