[GasmoN]

At the end of every round, I want to loop through all players and their weapons. And remove weapons flagged with certial flag. For that, I need entity ID from all their weapons, so how can I retreive it?

PHP Code:

    new i;
    new weapons[32], iWeapons
    get_user_weapons(id, weapons, iWeapons)
    
    for (i = 0; i <= iWeapons; i++)
    {      
             // How to get Entity ID here for all weapons that player have in inventory?
            // Something like new iEnt = get_weapon_ent_id(iWeapons[i])
    } 


[Natsheh]

Engine

get_player_weapon_entity(id, CSW_ID)
{
    static ent, szClassname[24]; ent = -1;
    get_weaponname(CSW_ID, szClassname, charsmax(szClassname));
    while ( (ent=find_ent_by_class(ent, szClassname)) > 0 && entity_get_edict(ent, EV_ENT_owner) != id ) { }
    
    return ent;
}

Or most common sense.

ent = find_ent_by_owner(-1, "weapon_class", owner);

or
Hamsandwich

PHP Code:

new g_user_weapon_ent_pointer[32][32];

public plugin_init()
{
    
    for ( new i=CSW_P228; i <= CSW_P90; i++)
    {
        if(get_weaponname(i, szWpn, charsmax(szWpn)))
        {
            RegisterHam(Ham_Item_AddToPlayer, szWpn, "fw_weapon_addtoplayer_post", true);
            RegisterHam(Ham_Item_Kill, szWpn, "fw_weapon_kill_post", true);
        }
    }
}


public fw_weapon_addtoplayer_post(ent, player)
{
    static szClassname[32];
    entity_get_string(ent, EV_SZ_classname, szClassname, charsmax(szClassname));
    g_user_weapon_ent_pointer[player - 1][ get_weaponid(szClassname)-1 ] = ent;
}

public fw_weapon_kill_post(ent)
{
    new player = entity_get_edict(ent, EV_ENT_owner);
    
    static szClassname[32];
    entity_get_string(ent, EV_SZ_classname, szClassname, charsmax(szClassname));
    
    g_user_weapon_ent_pointer[player - 1][ get_weaponid(szClassname)-1 ] = 0;
} 


[GasmoN]

Thank you, this is how I fixed this

At the end of every round, I added pf_check_weapon_life()
If anyone know any better way, I would like to hear it.

PHP Code:

public zp_fw_gamemodes_end() // Round just ended.
{
    pf_check_weapon_life();
}

stock pf_check_weapon_life()
{
    new i;
    
    for(i = 1; i <= g_maxplayers; i++)
    {
        if(is_user_alive(i))
        {
            pf_check_user_inventory(i);
        }
    }
}

stock pf_check_user_inventory(id) 
{
    new weapons[32], num
    get_user_weapons(id, weapons, num)
    
    for (new i = 0; i < num; i++) 
    {
        if (weapons[i] > 0) 
        {
            new iEnt = pf_find_weapon_ent_id(id, weapons[i]);
            new iEntLife = entity_get_int(iEnt, ENT_INDENT_LIFE);
            
            switch(iEntLife)
            {
                case ENT_KEY_LIFE_ONEROUND:
                {
                    fm_strip_user_gun(id, weapons[i]);
                }
            }            
        }
    }
}

stock pf_find_weapon_ent_id(id, CSW_ID)
{
    static ent, szClassname[24]; ent = -1;
    get_weaponname(CSW_ID, szClassname, charsmax(szClassname));
    
    while ((ent = find_ent_by_class(ent, szClassname)) > 0 && entity_get_edict(ent, EV_ENT_owner) != id) { }
    return (ent > 0 && entity_get_edict(ent, EV_ENT_owner) == id) ? ent:0;
} 


[Natsheh]

PHP Code:

stock pf_find_weapon_ent_id(id, CSW_ID)
{
    static ent, szClassname[24]; ent = -1;
    get_weaponname(CSW_ID, szClassname, charsmax(szClassname));
    
    while ((ent = find_ent_by_class(ent, szClassname)) > 0 && entity_get_edict(ent, EV_ENT_owner) != id) { }
    return ent;
} 


it will be more common sense and faster to use..

stock pf_find_weapon_ent_id(id, CSW_ID)
{
    static szClassname[24];
    get_weaponname(CSW_ID, szClassname, charsmax(szClassname));
    return find_ent_by_owner(-1, szClassname, id);
}

since i forgot about the find_ent_by_owner native.

[GasmoN]

Originally Posted by GasmoN Thank you, this is how I fixed this At the end of every round, I added pf_check_weapon_life() If anyone know any better way, I would like to hear it. PHP Code: public zp_fw_gamemodes_end() // Round just ended. {     pf_check_weapon_life(); } stock pf_check_weapon_life() {     new i;          for(i = 1; i <= g_maxplayers; i++)     {         if(is_user_alive(i))         {             pf_check_user_inventory(i);         }     } } stock pf_check_user_inventory(id)  {     new weapons[32], num     get_user_weapons(id, weapons, num)          for (new i = 0; i < num; i++)      {         if (weapons[i] > 0)          {             new iEnt = pf_find_weapon_ent_id(id, weapons[i]);             new iEntLife = entity_get_int(iEnt, ENT_INDENT_LIFE);                          switch(iEntLife)             {                 case ENT_KEY_LIFE_ONEROUND:                 {                     fm_strip_user_gun(id, weapons[i]);                 }             }                     }     } } stock pf_find_weapon_ent_id(id, CSW_ID) {     static ent, szClassname[24]; ent = -1;     get_weaponname(CSW_ID, szClassname, charsmax(szClassname));          while ((ent = find_ent_by_class(ent, szClassname)) > 0 && entity_get_edict(ent, EV_ENT_owner) != id) { }     return (ent > 0 && entity_get_edict(ent, EV_ENT_owner) == id) ? ent:0; }

Okay, so just a quick update. This started crashing server if there is more than 2 players. So after a while, I found another solution (I am writing this just in case someone need something like this).
The stock below is tested with 32/32 players while all of them had weapon that will be removed at the end of the round.

PHP Code:

stock pf_check_weapon_life()
{
    new iEntCount = entity_count();
    new iEntOwner;
    new iEntWeaponID;
    new iEnt;
    
    for (iEnt = 0; iEnt < iEntCount; iEnt++)
    {
        if(!is_valid_ent(iEnt))
        continue;
        
        iEntOwner = entity_get_edict(iEnt, EV_ENT_owner)
        
        if(is_user_alive(iEntOwner))
        {
            switch(entity_get_int(iEnt, ENT_INDENT_LIFE))
            {
                case ENT_KEY_LIFE_ONEROUND:
                {
                    iEntWeaponID = cs_get_weapon_id(iEnt);
                    
                    if(get_pdata_cbase(iEntOwner, m_pActiveItem) == iEnt)
                    ExecuteHamB(Ham_Weapon_RetireWeapon, iEnt);
                    
                    if(ExecuteHamB(Ham_RemovePlayerItem, iEntOwner, iEnt))
                    {
                        user_has_weapon(iEntOwner, iEntWeaponID, 0);
                        ExecuteHamB(Ham_Item_Kill, iEnt);
                    }                    
                }
            }
        }
    }
} 


[Natsheh]

previous method was much better you just now ruined it.

if it crashes thats means there's something going wrong in the code, debug and test when the crash acquires.


if you want to loop all players alive use this method its much faster

new players[32], pnum;
get_players(players, pnum, "ah"); // flag a to loop alive clients only, flag h is to skip HLTV

for(new i ; i < pnum; i++ )
{
   new player_index = players[ i ];
}

also you need to show what's the body of fm_strip_user_gun(id, weapons[i]); and how it works...

[GasmoN]

Before I was using one loop, and 2 other loops inside that one loop.
Now, I only loop entities with maximum number of created entities and check some conditions.
Why is that ruined?

fm_strip_user_gun already comes with fakemeta_util, I didn't looked up the stock itself how it's done. https://www.amxmodx.org/api/fakemeta...strip_user_gun

[Natsheh]

Originally Posted by GasmoN Before I was using one loop, and 2 other loops inside that one loop. Now, I only loop entities with maximum number of created entities and check some conditions. Why is that ruined? fm_strip_user_gun already comes with fakemeta_util, I didn't looked up the stock itself how it's done. https://www.amxmodx.org/api/fakemeta...strip_user_gun

there's nothing wrong by using two loops inside of each other and also i told you to update the code and use the other way, which its this way, the looping is done in the module which is much faster.

Originally Posted by Natsheh PHP Code: stock pf_find_weapon_ent_id(id, CSW_ID) {     static szClassname[24];     get_weaponname(CSW_ID, szClassname, charsmax(szClassname));     return find_ent_by_owner(-1, szClassname, id); }

and how's it better by looping all the existed entities ?