[TheBladerX]

Still :/ while falling on map for example 1hp, that is 1-2 seconds so I thought you can make something that will activate it after 5 seconds.. That doesn't work :/

[zmd94]

Just edit 10.0 value into anything less or more:

public logevent_round_start()
{
    // Free parachute after 10s of round start. ;)
    set_task(10.0, "FreePara")
}

[TheBladerX]

Still gives parachute immediately, this is weird.. But thanks for help

[TheBladerX]

Ah I think I know what's wrong. I ment to activate parachute after 5 seconds not first 5 seconds

[zmd94]

I have updated the code:

https://forums.alliedmods.net/showpo...&postcount=230

[new_holland6]

Hello there! How are you? If there is anyone who get bored, can help me with my server?, it's everything working except parachute. In fact i put the plugin, if i wrote amx_plugins in comsole it show me its working, in chat it gives me the message from parachute.txt, but it doesen't work to activate on E, even if the plugin is tested on other servers. Anyway i had in the begining another plugin, but it wasn't working properly, if one player use the parachute , the other ones doesent have it anymore... so i remplaced it with this one, but now its not working at all. Its for FREE parachute, so the reason it doesent work because i didn't buy it is not a valid one... Because also chat print is : You allready have a parachute! I dont know whats wrong. If anyone can help me i would be really happy. Thanks!!!

[zmd94]

If you want to give parachute to all players for free, just use this:

https://forums.alliedmods.net/showthread.php?t=175775

Although it is in ZP section, you still can use that plugin in regular CS1.6 mods. I have tested it and it is working well in my server.

[TheBladerX]

Looks like mine doesn't work, still... Can you set 5 seconds after player respawn, please?

[zmd94]

Just try below:

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define _PLUGIN         "[ZP] Parachute"
#define _VERSION             "1.0"
#define _AUTHOR           "H.RED.ZONE"

#define PARACHUTE_MODEL "models/parachute.mdl"

#define MAX_PLAYERS    32

#define MarkUserHasParachute(%0)    g_bitHasParachute |= (1<<(%0&31))
#define ClearUserHasParachute(%0)    g_bitHasParachute &= ~(1<<(%0&31))
#define HasUserParachute(%0)        g_bitHasParachute & (1<<(%0&31))

new g_bitHasParachute 

new g_iUserParachute[MAX_PLAYERS+1]

new Float:g_flEntityFrame[MAX_PLAYERS+1]

new g_iModelIndex
new g_pCvarFallSpeed

new const PARACHUTE_CLASS[] = "parachute"

enum {
    deploy,
    idle,
    detach
}

public plugin_init() {
    register_plugin(_PLUGIN, _VERSION, _AUTHOR)

    g_pCvarFallSpeed = register_cvar("parachute_fallspeed", "30")
    
    register_forward( FM_CmdStart, "fw_Start" )
    
    RegisterHam(Ham_Spawn, "player", "fw_PlayerRespawn", 1)
    RegisterHam(Ham_Killed, "player", "Ham_CBasePlayer_Killed_Post", 1)
}

public plugin_precache() {
    g_iModelIndex = precache_model(PARACHUTE_MODEL)
}

public fw_PlayerRespawn(id)
{
    // Free parachute after 10s of round start. ;)
    set_task(5.0, "FreePara")
}

public FreePara() 
{
    new iPlayers[32], iPlayerCount, i, id
    
    get_players(iPlayers, iPlayerCount, "a") 
    for(i = 0; i < iPlayerCount; i++)
    {
        id = iPlayers[i]

        if( HasUserParachute(id) ) 
        {
            new iEnt = g_iUserParachute[id]
            if( iEnt ) 
            {
                RemoveUserParachute(id, iEnt)
            }
        }
            
        MarkUserHasParachute(id)
    }
}

public client_disconnect(id) {
    if( HasUserParachute(id) ) {
        new iEnt = g_iUserParachute[id]
        if( iEnt ) {
            RemoveUserParachute(id, iEnt)
        }
        ClearUserHasParachute(id)
    }
}

public Ham_CBasePlayer_Killed_Post( id ) {
    if( HasUserParachute(id) ) {
        new iEnt = g_iUserParachute[id]
        if( iEnt ) {
            RemoveUserParachute(id, iEnt)
        }
        ClearUserHasParachute(id)
    }
}

RemoveUserParachute(id, iEnt) {
    engfunc(EngFunc_RemoveEntity, iEnt)
    g_iUserParachute[id] = 0
}

CreateParachute(id) {
    static iszInfoTarget
    if( !iszInfoTarget ) {
        iszInfoTarget = engfunc(EngFunc_AllocString, "info_target")
    }

    new iEnt = engfunc(EngFunc_CreateNamedEntity, iszInfoTarget)
    if( iEnt > 0) {
        static iszClass = 0
        if( !iszClass ) {
            iszClass = engfunc(EngFunc_AllocString, PARACHUTE_CLASS)
        }
        set_pev_string(iEnt, pev_classname, iszClass)
        set_pev(iEnt, pev_aiment, id)
        set_pev(iEnt, pev_owner, id)
        set_pev(iEnt, pev_movetype, MOVETYPE_FOLLOW)

        static iszModel = 0
        if( !iszModel ) {
            iszModel = engfunc(EngFunc_AllocString, PARACHUTE_MODEL)
        }
        set_pev_string(iEnt, pev_model, iszModel)
        set_pev(iEnt, pev_modelindex, g_iModelIndex)

        set_pev(iEnt, pev_sequence, deploy)
        set_pev(iEnt, pev_gaitsequence, 1)
        set_pev(iEnt, pev_frame, 0.0)
        g_flEntityFrame[id] = 0.0
        g_iUserParachute[id] = iEnt
        MarkUserHasParachute(id)
        new Float:fVecOrigin[3]
        pev(id, pev_origin, fVecOrigin)
        
        return iEnt
    }
    return 0
}

public fw_Start(id) {
    if( ~HasUserParachute(id) || !is_user_alive(id) ) {
        return
    }

    new Float:flFrame
    new iEnt = g_iUserParachute[id]

    if(iEnt > 0 && pev(id, pev_flags) & FL_ONGROUND) {

        if( pev(iEnt, pev_sequence) != detach ) {
            set_pev(iEnt, pev_sequence, detach)
            set_pev(iEnt, pev_gaitsequence, 1)
            set_pev(iEnt, pev_frame, 0.0)
            g_flEntityFrame[id] = 0.0
            set_pev(iEnt, pev_animtime, 0.0)
            set_pev(iEnt, pev_framerate, 0.0)
            return
        }

        pev(iEnt, pev_frame, flFrame)
        if( flFrame > 252.0 ) {
            RemoveUserParachute(id, iEnt)
            return
        }

        flFrame += 2.0

        g_flEntityFrame[id] = flFrame
        set_pev(iEnt, pev_frame, flFrame)

        return
    }

    if( pev(id, pev_button) & IN_USE ) {
        new Float:fVecVelocity[3], Float:fVelocity_z
        pev(id, pev_velocity, fVecVelocity)
        fVelocity_z = fVecVelocity[2]

        if( fVelocity_z < 0.0 ) {
            if(iEnt <= 0) {
                iEnt = CreateParachute(id)
            }

            fVelocity_z = floatmin(fVelocity_z + 15.0, -get_pcvar_float(g_pCvarFallSpeed))
            fVecVelocity[2] = fVelocity_z
            set_pev(id, pev_velocity, fVecVelocity)

            if( pev(iEnt, pev_sequence) == deploy ) {
                flFrame = g_flEntityFrame[id]++

                if( flFrame > 100.0 ) {
                    set_pev(iEnt, pev_animtime, 0.0)
                    set_pev(iEnt, pev_framerate, 0.4)
                    set_pev(iEnt, pev_sequence, idle)
                    set_pev(iEnt, pev_gaitsequence, 1)
                    set_pev(iEnt, pev_frame, 0.0)
                    g_flEntityFrame[id] = 0.0
                }
                else {
                    set_pev(iEnt, pev_frame, flFrame)
                }
            }
        }
        else if(iEnt > 0) {
            RemoveUserParachute(id, iEnt)
        }
    }
    else if( iEnt > 0 && pev(id, pev_oldbuttons) & IN_USE ) {
        RemoveUserParachute(id, iEnt)
    }
} 


[TheBladerX]

Seems it works, finally thanks