[Napoleon_be]

I'm trying to display the current online vips on the server but i'm having some trouble.

This is how my current code looks like, and it's showing the message on a new line every single time.
How do i fix this?

PHP Code:

public VipsOnline(id) 
{
    new szPlayers[32], iNum, szName[33];
    get_players(szPlayers, iNum);
    
    for(new i; i < iNum; i++)
    {
        if(get_user_flags(szPlayers[i]) & VIP_LEVEL)
        {
            get_user_name(szPlayers[i], szName, charsmax(szName));
            ColorChat(id, GREEN, "Online Vips: %s |", szName);
        }
    }
} 


[OciXCrom]

You're displaying the message for each loop cycle. Only get the names in the loop and store them in a variable using "formatex" and/or "format", then display the formatted message (the variable) outside the loop.

[Natsheh]

PHP Code:

public check_vips(id)
{
    new sBuffer[128], sVipname[32], sSlots[34], userid, vs, i
    
    formatex(sBuffer, charsmax(sBuffer), "!t[-!gV!tI!gP's!t-] !gOnline: ")
    
    new z;
    if((z = get_vips_online()) > 0)
    {
        new players[32], pnum
        get_players(players, pnum, "ch")
        
        for(i = 0; i < pnum; i++)
        {
            userid = players[i]
            
            if(!(get_user_vip(userid) & read_flags(szFLAG)))
                continue;
            
            vs ++;
            get_user_name(userid, sVipname, charsmax(sVipname))
            formatex(sSlots, charsmax(sSlots), "!t%s!g%s", sVipname, z == vs ? ".":", ")
            add(sBuffer, charsmax(sBuffer), sSlots)
        }
    }
    else
    {
        add(sBuffer, charsmax(sBuffer), "!tThere is no vip's !gOnline!")
    }
    
    chat_message(id, sBuffer)
}

stock get_vips_online()
{
    new players[32], pnum, vs, i, userid
    get_players(players, pnum, "ch")
    
    for(i = 0; i < pnum; i++)
    {
        userid = players[i]
        
        if(!(get_user_vip(userid) & read_flags(szFLAG)))
            continue;
        
        vs ++;
    }
    
    return vs
} 


Heres an example.

[Napoleon_be]

I'm currently using this code which i kinda stole from another plugin. The problem is that it doesn't show the vips correctly. For players without the VIP flag, it will always show "No vips online", while people who have the VIP flag will always get a message that outputs all the player names in the server. Any idea how i can fix this?

PHP Code:

public VipsOnline(id) {
    new bool:IsFirst = true, szMessage[256], iLen, TempID;
    
    for(TempID = 0; TempID <= get_maxplayers(); TempID++)
    {
        if( !is_user_connected(TempID) || !(get_user_flags(id) & VIP_LEVEL) )
        {
            continue;
        }
        
        if( !IsFirst )
        {
            szMessage[iLen++] = ' ';
            szMessage[iLen++] = '|';
            szMessage[iLen++] = ' ';
        }
        
        szMessage[iLen++] = '^x04';
        szMessage[iLen] = EOS;
        
        iLen += get_user_name(TempID, szMessage[iLen], charsmax(szMessage) - iLen);
        
        szMessage[iLen++] = '^x01';
        szMessage[iLen] = EOS;
        
        IsFirst = false;
    }
    
    if( IsFirst )
    {

        ColorChat(id, GREEN, "There are no vips online.");
        return PLUGIN_HANDLED;
    }
    else
    {
        ColorChat(id, TEAM_COLOR, "Online Vips: %s", szMessage);
        return PLUGIN_HANDLED;        
    }
    
    return PLUGIN_CONTINUE
} 


EDIT: I might've found the reason for this isue, i was using "id" instead of "TempID" on this line

PHP Code:

if( !is_user_connected(TempID) || !(get_user_flags(id) & VIP_LEVEL) ) 


[OciXCrom]

It's because you're checking the flags of "id" (the person who used the command") instead of "TempID" (the loop-element).

Please use "get_players" instead of looping all indexes from 1 to 32.

[Napoleon_be]

something like this?

PHP Code:

public VipsOnline(id) {
    new bool:IsFirst = true;
    new szMessage[256], iLen, szPlayers[32], iNum;
    
    get_players(szPlayers, iNum);
    
    for(new i; i < iNum; i++)
    {
        if(!is_user_connected(szPlayers[i]) || !(get_user_flags(szPlayers[i]) & VIP_LEVEL))
        {
            continue;
        }
        
        if(!IsFirst)
        {
            szMessage[iLen++] = ' ';
            szMessage[iLen++] = '|';
            szMessage[iLen++] = ' ';
        }
        
        szMessage[iLen++] = '^x04';
        szMessage[iLen] = EOS;
        
        iLen += get_user_name(szPlayers[i], szMessage[iLen], charsmax(szMessage) - iLen);
        
        szMessage[iLen++] = '^x01';
        szMessage[iLen] = EOS;
        
        IsFirst = false;
    }
    
    if(IsFirst)
    {

        ColorChat(id, GREEN, "There are no vips online.");
        return PLUGIN_HANDLED;
    }
    else
    {
        ColorChat(id, TEAM_COLOR, "Online Vips: %s", szMessage);
        return PLUGIN_HANDLED;        
    }
    
    return PLUGIN_CONTINUE;
} 


[OciXCrom]

You don't need "is_user_connected". Use the flags provided by "get_players" - https://www.amxmodx.org/api/amxmodx/get_players

Even though this will probably work, what happens if you have more VIP users than the message can display?

[Napoleon_be]

Originally Posted by OciXCrom You don't need "is_user_connected". Use the flags provided by "get_players" - https://www.amxmodx.org/api/amxmodx/get_players Even though this will probably work, what happens if you have more VIP users than the message can display?

Yea my bad, will edit this.

And that's a good question, i don't know to be honest lol.

[OciXCrom]

You can add a limit, e.g. 4 players max on a line. If the loop reaches 4, print the message and clear the formatex, then set the counter to 0 again.