[SkumTomteN]

Can i make so only me can fly?, or only give me an invisible parachute, i just want it to fit my model.

[ANTICHRISTUS]

• if you want an invisible parachute, search this keyword (don't edit) in my posts: parachute+null
• if you want it only for you, edit the flag in the .sma

[DarkGod]

Originally Posted by LordOfNothing press E when you are in air and you need flag A (admin_immunity) PHP Code: #include <amxmodx> #include <fun> #include <fakemeta> #include <engine> #include <amxmisc> public plugin_init() {     register_forward(FM_PlayerPreThink, "ScanPlayer"); } public ScanPlayer(id) {     if(!get_user_frags(id) & ADMIN_IMMUNITY)         return PLUGIN_HANDLED     if(get_user_button(id) & IN_USE)     {         set_user_gravity(id, 0.3);     }else{         set_user_gravity(id, 1.0);     }     return PLUGIN_CONTINUE }

if(!(get_user_flags(id) & ADMIN_IMMUNITY))

A bit silly method and doesn't work well with anything else that changes your gravity, so you know.

[Kia]

Originally Posted by DarkGod if(!(get_user_flags(id) & ADMIN_IMMUNITY)) A bit silly method and doesn't work well with anything else that changes your gravity, so you know.

You won't really fly, you also need to play with the players velocity.

[DarkGod]

As I said, it's a silly method.

[SkumTomteN]

I used the one you said antichristus, and it worked well, a bit laggy when falling down, the intention was that i could glide in air with the wings, and it worked! , thank you all

[yokomo]

Hi, you can use this, it is the same method as JetPack but more efficient. To fly you need to hold jump+duck button, have fun.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

new bool:bHasJetPack[33]

public plugin_init()
{
    register_plugin("I Believe I Can Fly", "0.0.1", "wbyokomo")
    
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled")
    RegisterHam(Ham_Player_Jump, "player", "OnPlayerJump")
}

public client_putinserver(id)
{
    bHasJetPack[id] = false
    if(get_user_flags(id) & ADMIN_BAN) bHasJetPack[id] = true;
}

public client_disconnect(id)
{
    bHasJetPack[id] = false
}

public OnPlayerKilled(id)
{
    bHasJetPack[id] = false
}

public OnPlayerJump(id)
{
    if(bHasJetPack[id])
    {
        static button, flag
        button = pev(id, pev_button)
        flag = pev(id, pev_flags)
        
        if((button & IN_DUCK) && !(flag & FL_ONGROUND))
        {
            static Float:vVelocity[3], Float:vAngles[3], Float:vForward[3]
            pev(id, pev_velocity, vVelocity)
            pev(id, pev_angles, vAngles)
            vAngles[2] = 0.0
            angle_vector(vAngles, ANGLEVECTOR_FORWARD, vForward)
            vAngles = vForward
            vAngles[0] *= 300.0
            vAngles[1] *= 300.0
            vVelocity[0] = vAngles[0]
            vVelocity[1] = vAngles[1]
            if(vVelocity[2] < 300.0) vVelocity[2] += 35.0;
            set_pev(id, pev_velocity, vVelocity)
        }
    }
} 


[ConnorMcLeod]

Cleaned up :

1 thing you have to fix though is that you remove JP on kill but don't never give it back

PHP Code:

public OnPlayerJump(id)
{
    if( bHasJetPack[id] && pev(id, pev_button) & IN_DUCK && ~pev(id, pev_flags) & FL_ONGROUND )
    {
        static Float:vVelocity[3], Float:upSpeed
        pev(id, pev_velocity, vVelocity)
        upSpeed = vVelocity[2] + 35.0
        velocity_by_aim(id, 300, vVelocity)
        vVelocity[2] = upSpeed > 300.0 ? 300.0 : upSpeed
        set_pev(id, pev_velocity, vVelocity)
    }
} 


[yokomo]

Originally Posted by ConnorMcLeod Cleaned up : 1 thing you have to fix though is that you remove JP on kill but don't never give it back PHP Code: public OnPlayerJump(id) {     if( bHasJetPack[id] && pev(id, pev_button) & IN_DUCK && ~pev(id, pev_flags) & FL_ONGROUND )     {         static Float:vVelocity[3], Float:upSpeed         pev(id, pev_velocity, vVelocity)         upSpeed = vVelocity[2] + 35.0         velocity_by_aim(id, 300, vVelocity)         vVelocity[2] = upSpeed > 300.0 ? 300.0 : upSpeed         set_pev(id, pev_velocity, vVelocity)     } }

Yea you are right, i forgot to set it back on player spawn.
Code fixed and thanks to Connor:

PHP Code:

#include <amxmodx> 
#include <fakemeta> 
#include <hamsandwich> 

new bool:bHasJetPack[33] 

public plugin_init() 
{ 
    register_plugin("I Believe I Can Fly", "0.0.2", "wbyokomo")
    
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled") 
    RegisterHam(Ham_Player_Jump, "player", "OnPlayerJump") 
} 

public client_putinserver(id) 
{ 
    bHasJetPack[id] = false
} 

public client_disconnect(id) 
{ 
    bHasJetPack[id] = false 
} 

public OnPlayerSpawn(id)
{
    if(is_user_alive(id) && get_user_flags(id) & ADMIN_BAN) bHasJetPack[id] = true;
}

public OnPlayerKilled(id) 
{ 
    bHasJetPack[id] = false 
} 

public OnPlayerJump(id) 
{ 
    if(bHasJetPack[id] && pev(id, pev_button) & IN_DUCK && ~pev(id, pev_flags) & FL_ONGROUND)
    {
        static Float:vVelocity[3], Float:upSpeed
        pev(id, pev_velocity, vVelocity)
        upSpeed = vVelocity[2] + 35.0
        velocity_by_aim(id, 300, vVelocity)
        vVelocity[2] = upSpeed > 300.0 ? 300.0 : upSpeed
        set_pev(id, pev_velocity, vVelocity)
    }
}