[klashfire]

(well, actually the server. Not the game itself.)
yeah, I kind of know why, even before I tested it, but I need a better alternative.
The plugin is not yet complete, but should be functional.

The plugin's purpose is to set a HUD element based timer for whatever purpose the player needs it for.

PHP Code:

#pragma semicolon 1

#include <sourcemod>

public void OnPluginStart() {
    RegAdminCmd("sm_timer", Command_SetTimer, ADMFLAG_SLAY, "Set a timer countdown.");
}

public Action Command_SetTimer(client, args) {

    char arg1[32];
    char arg2[32];
    char TimerResult[128];
    
    if (args < 2 || args > 3) {
        ReplyToCommand(client, "[SM] Usage: sm_timer <minutes> <seconds> (<timer result>)");
        return Plugin_Handled;
    }
    
    GetCmdArg(1, arg1, sizeof(arg1));
    GetCmdArg(2, arg2, sizeof(arg2));
    
    int Minutes = StringToInt(arg1);
    int Seconds = StringToInt(arg2);
    
    GetCmdArg(3, TimerResult, sizeof(TimerResult));
    
    if (Seconds > 60 || Seconds < 0 || Minutes < 0 || Minutes > 60) {
        ReplyToCommand(client, "[SM] Seconds and Minutes must be an intiger value between 0 and 60");
        return Plugin_Handled;
    }
    
    int oldTime = GetTime();

    int timerTime = Seconds + (Minutes * 60);
    
    for (int i = 0; i - oldTime <= timerTime; i = GetTime()) {
        if (i - oldTime == 60) {
            oldTime += 60;
            Minutes--;
        }
        
        Seconds = (timerTime - (i - oldTime)) % 60;
        
        PrintCenterText(client, "%d:%d", Minutes, Seconds);
    }

    
    return Plugin_Handled;
} 


The plugin crashes tf2 most likely by the constant spam of PrintCentertext() in the for loop.
Can someone give me a good alternative that wouldn't present constant spam or at least not crash TF2?


P.S. checking if a second has passed before using PrintCenterText() might work, but I'm not quite sure.
EDIT: nope. That didn't help. Same result.

[DJ Tsunami]

A for loop is not asynchronous, so while you are looping everything else is blocked.

Repeatable Timers

Create a repeatable timer with a 1 second interval, and PrintCenterText until the time has passed.

[klashfire]

Originally Posted by DJ Tsunami A for loop is not asynchronous, so while you are looping everything else is blocked. Repeatable Timers Create a repeatable timer with a 1 second interval, and PrintCenterText until the time has passed.

It seems I have no idea what I'm doing. Any help with this?

PHP Code:

#pragma semicolon 1

#include <sourcemod>

public void OnPluginStart() {
    RegAdminCmd("sm_timer", Command_SetTimer, ADMFLAG_SLAY, "Set a timer countdown.");
}

public Action Command_SetTimer(client, args) {

    char arg1[32];
    char arg2[32];
    char TimerResult[128];
    
    if (args < 2 || args > 3) {
        ReplyToCommand(client, "[SM] Usage: sm_timer <minutes> <seconds> (<timer result>)");
        return Plugin_Handled;
    }
    
    GetCmdArg(1, arg1, sizeof(arg1));
    GetCmdArg(2, arg2, sizeof(arg2));
    
    Minutes = StringToInt(arg1);
    Seconds = StringToInt(arg2);
    
    GetCmdArg(3, TimerResult, sizeof(TimerResult));
    
    if (Seconds > 60 || Seconds < 0 || Minutes < 0 || Minutes > 60) {
        ReplyToCommand(client, "[SM] Seconds and Minutes must be an intiger value between 0 and 60");
        return Plugin_Handled;
    }
    
    timerTime = Seconds + (Minutes * 60);
    
    CreateTimer(1.0, Timer_ShowTimeLeft, _, TIMER_REPEAT);
    
    
    return Plugin_Handled;
}

public Action Timer_ShowTimeLeft(Handle timer)
{
    // Create a global variable visible only in the local scope (this function).
    static int secondCounter = 0;
    static int minuteHandler = 0;
 
    if (secondCounter >= timerTime) {
        secondCounter = 0;
        return Plugin_Stop;
    }
    if (MinuteHandler == 60) {
        Minutes--;
        minuteHandler = 0;
    }
    if (Seconds < 1) {
        Seconds = 60;
    }
    
    PrintCenterTextAll("%d:%d", Minutes, Seconds)
    secondCounter++;
    MenuHandler++;
    Seconds--;
    return Plugin_Continue;
} 


got 11 errors:

/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(23) : error 008: must be a constant expression; assumed zero
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(24) : error 008: must be a constant expression; assumed zero
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(33) : error 008: must be a constant expression; assumed zero
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(33) : warning 203: symbol is never used: "timerTime"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(47) : error 017: undefined symbol "timerTime"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(51) : error 017: undefined symbol "MinuteHandler"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(52) : error 017: undefined symbol "Minutes"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(52) : warning 215: expression has no effect
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(55) : error 017: undefined symbol "Seconds"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(56) : error 017: undefined symbol "Seconds"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(56) : warning 215: expression has no effect
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(59) : error 017: undefined symbol "Minutes"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(61) : error 017: undefined symbol "MenuHandler"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(61) : warning 215: expression has no effect
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(62) : error 017: undefined symbol "Seconds"
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(62) : warning 215: expression has no effect
/home/groups/sourcemod/upload_tmp/phps5XZ5w.sp(53) : warning 204: symbol is assigned a value that is never used: "minuteHandler"

[xines]

I'm not familiar with the new syntax due to lazyness...

But half of the errors is self explained and

PHP Code:

    Minutes = StringToInt(arg1);
    Seconds = StringToInt(arg2); 


Minutes and Seconds integers ain't defined anywhere in the code causing the:

error 017: undefined symbol "Minutes"
error 017: undefined symbol "Seconds"

[klashfire]

Originally Posted by xines I'm not familiar with the new syntax due to lazyness... But half of the errors is self explained and PHP Code:     Minutes = StringToInt(arg1);     Seconds = StringToInt(arg2);  Minutes and Seconds integers ain't defined anywhere in the code causing the: error 017: undefined symbol "Minutes" error 017: undefined symbol "Seconds"

yeah, I just edited it back to that when posting since I went through an unnecessary code fix. there was actually an 'int' before them, still returning the same error.

and yeah, I am not so familiar either with the new syntax, but a guy urged me to use it instead of the old one.

I believe most of the errors there are due to inconsistencies between global and local scope variables. Can you recommend a fix?

[xines]

Originally Posted by klashfire Can you recommend a fix?

This is tested and works on CSS, so give it a shot.

Guess this is more than the fix you requested:

PHP Code:

#pragma semicolon 1
#include <sourcemod>

int Minutes,
    Seconds,
    TimerTime,
    SecondCounter = 0;

char TimerResult[128],
    arg1[32],
    arg2[32];
    
bool TimerRunning;

public void OnPluginStart() 
{
    RegAdminCmd("sm_timer", Command_SetTimer, ADMFLAG_SLAY, "Set a timer countdown.");
}

public Action Command_SetTimer(client, args) 
{    
    if (args < 2 || args > 3) {
        ReplyToCommand(client, "[SM] Usage: sm_timer <minutes> <seconds> (<timer result>)");
        return Plugin_Handled;
    }
    
    if (TimerRunning == false) { //check if timer aint running
        TimerRunning = true;
    }
    else {
        ReplyToCommand(client, "[SM] Timer is already running, so you can't start a new one.");
        return Plugin_Handled;
    }
    
    GetCmdArg(1, arg1, sizeof(arg1));
    GetCmdArg(2, arg2, sizeof(arg2));
    GetCmdArg(3, TimerResult, sizeof(TimerResult));
    
    Minutes = StringToInt(arg1);
    Seconds = StringToInt(arg2);
    
    if (Seconds > 60 || Seconds < 0 || Minutes < 0 || Minutes > 60) {
        ReplyToCommand(client, "[SM] Seconds and Minutes must be an intiger value between 0 and 60");
        return Plugin_Handled;
    }
    
    TimerTime = Seconds + (Minutes * 60);

    CreateTimer(1.0, Timer_ShowTimeLeft, _, TIMER_REPEAT);

    return Plugin_Handled;
}

public Action Timer_ShowTimeLeft(Handle timer)
{
    if (SecondCounter >= TimerTime) {
        SecondCounter = 0;
        PrintToChatAll("%s", TimerResult); // print whatever stored in arg 3, when timer is done
        TimerRunning = false; // set to false for new timer to be ready for use
        return Plugin_Stop;
    }
    if (Minutes > 0 && Seconds < 1) {
        Minutes--;
        Seconds = 60;
    }
    
    PrintCenterTextAll("%d:%d", Minutes, Seconds);
    SecondCounter++;
    Seconds--;
    return Plugin_Continue;
} 


[klashfire]

Originally Posted by xines This is tested and works on CSS, so give it a shot. Guess this is more than the fix you requested: PHP Code: #pragma semicolon 1 #include <sourcemod> int Minutes,     Seconds,     TimerTime,     SecondCounter = 0; char TimerResult[128],     arg1[32],     arg2[32];      bool TimerRunning; public void OnPluginStart()  {     RegAdminCmd("sm_timer", Command_SetTimer, ADMFLAG_SLAY, "Set a timer countdown."); } public Action Command_SetTimer(client, args)  {         if (args < 2 || args > 3) {         ReplyToCommand(client, "[SM] Usage: sm_timer <minutes> <seconds> (<timer result>)");         return Plugin_Handled;     }          if (TimerRunning == false) { //check if timer aint running         TimerRunning = true;     }     else {         ReplyToCommand(client, "[SM] Timer is already running, so you can't start a new one.");         return Plugin_Handled;     }          GetCmdArg(1, arg1, sizeof(arg1));     GetCmdArg(2, arg2, sizeof(arg2));     GetCmdArg(3, TimerResult, sizeof(TimerResult));          Minutes = StringToInt(arg1);     Seconds = StringToInt(arg2);          if (Seconds > 60 || Seconds < 0 || Minutes < 0 || Minutes > 60) {         ReplyToCommand(client, "[SM] Seconds and Minutes must be an intiger value between 0 and 60");         return Plugin_Handled;     }          TimerTime = Seconds + (Minutes * 60);     CreateTimer(1.0, Timer_ShowTimeLeft, _, TIMER_REPEAT);     return Plugin_Handled; } public Action Timer_ShowTimeLeft(Handle timer) {     if (SecondCounter >= TimerTime) {         SecondCounter = 0;         PrintToChatAll("%s", TimerResult); // print whatever stored in arg 3, when timer is done         TimerRunning = false; // set to false for new timer to be ready for use         return Plugin_Stop;     }     if (Minutes > 0 && Seconds < 1) {         Minutes--;         Seconds = 60;     }          PrintCenterTextAll("%d:%d", Minutes, Seconds);     SecondCounter++;     Seconds--;     return Plugin_Continue; }

wow, thanks!

[xines]

Originally Posted by klashfire wow, thanks!

No problem .