[LukeyB]

sometimes when a bot starts defusing, they will look up and press the use button again to cancel the defuse and will keep doing this until the bomb explodes. I am trying to block them from moving their crosshair and pressing the use key when they are defusing. It doesn't seem to be working. They can still move their crosshair when defusing.

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta>
#include <fun>
new g_max
public plugin_init()
{
register_plugin("bombdefusing", "1.0", "LB")
register_event("BarTime", "event_defusing", "be", "1=5", "1=10")
g_max = get_maxplayers()
}
public event_defusing(id, uc_handle)
{
new buttons = get_uc(uc_handle,UC_Buttons)
for ( new id=1; id<=g_max; id++ )
{
if ( is_user_alive(id) && is_user_bot(id) && buttons & IN_USE)
{
buttons &= ~IN_USE
buttons &= ~IN_RELOAD
set_uc(uc_handle,UC_Buttons,buttons)
static Float:angles[3]
pev(id, pev_v_angle, angles);
angles[0]=0.0
set_pev(id, pev_angles, angles);
set_pev(id,pev_fixangle,1)
}
}
} 


[Doc-Holiday]

I didnt look at the actual code but the event im pretry sure is only called one time at defuse start

[LukeyB]

I'm not sure the best way to go about resolving the bug. Maybe when they press IN_USE, stop them from standing up or moving crosshair.

they seem to press in_use before they crouch then crouch and start defusing then stand up and let go of in_use which stops defusing then do it over and over...really annoying. I am sure it's resolvable, but just not sure where to start now.

Anyone have an idea?

[ConnorMcLeod]

Try this :

With http://forums.alliedmods.net/showpos...28&postcount=2

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "0.0.1"
#define PLUGIN "Bot Defuse Fix"

const IsDefusing = (1<<8)
#define is_user_defusing(%0)    ( get_pdata_int(%0,232,5) & IsDefusing )

new HamHook:g_iHhPlayerPostThink, HamHook:g_iHhBotPlayerPostThink
new g_iDefuser
new Float:g_flVecAngles[3]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_event("TextMsg", "Event_TxtMsg_Defusing", "be", "1=4", "2&#Defusing_Bomb_With")
    DisableHamForward
    (
        g_iHhPlayerPostThink = RegisterHam(Ham_Player_PostThink, "player", "CBasePlayer_PostThink", false)
    )
}

public cz_bot_ham_registerable( id )
{
    DisableHamForward
    (
        g_iHhBotPlayerPostThink = RegisterHam(Ham_Player_PostThink, "player", "CBasePlayer_PostThink", false)
    )
}

public Event_TxtMsg_Defusing( id )
{
    if( !is_user_bot(id) )
    {
        return
    }
    g_iDefuser = id
    pev(id, pev_v_angle, g_flVecAngles)
    SetForwards( true )
}

public CBasePlayer_PostThink( id )
{
    if( !g_iDefuser )
    {
        SetForwards( false )
        return HAM_IGNORED
    }
    if( id == g_iDefuser )
    {
        if( !is_user_defusing(id) )
        {
            g_iDefuser = 0
            SetForwards( false )
            return HAM_IGNORED
        }
        static buttons ; buttons = pev(id, pev_button)
        if( buttons & IN_RELOAD )
        {
            set_pev(id, pev_button, buttons & ~IN_RELOAD)
        }
        set_pev(id, pev_angles, g_flVecAngles)
        set_pev(id, pev_fixangle, 1)
        return HAM_HANDLED
    }
    return HAM_IGNORED
}

SetForwards( bool:bOnOff )
{
    if( bOnOff )
    {
        if( g_iHhPlayerPostThink )
        {
            EnableHamForward( g_iHhPlayerPostThink )
        }
        if( g_iHhBotPlayerPostThink )
        {
            EnableHamForward( g_iHhBotPlayerPostThink )
        }
    }
    else
    {
        if( g_iHhPlayerPostThink )
        {
            DisableHamForward( g_iHhPlayerPostThink )
        }
        if( g_iHhBotPlayerPostThink )
        {
            DisableHamForward( g_iHhBotPlayerPostThink )
        }
    }
} 


[LukeyB]

Thanks, but it doesn't work. They still stand up when crouched and cancel defusing.

[ConnorMcLeod]

Originally Posted by LukeyB sometimes when a bot starts defusing, they will look up and press the use button again to cancel the defuse and will keep doing this until the bomb explodes. I am trying to block them from moving their crosshair and pressing the use key when they are defusing. It doesn't seem to be working. They can still move their crosshair when defusing.

...

[LukeyB]

Originally Posted by LukeyB I'm not sure the best way to go about resolving the bug. Maybe when they press IN_USE, stop them from standing up or moving crosshair. they seem to press in_use before they crouch then crouch and start defusing then stand up and let go of in_use which stops defusing then do it over and over...really annoying. I am sure it's resolvable, but just not sure where to start now. Anyone have an idea?

...this explains it better. it's not just moving the crosshair causing the bug as was able to get them not to move their crosshair and they still stand up and stop defusing.

[LukeyB]

Is there a way to just stop the bot from standing up when defusing? Hoping this will fix bug.
Forcing them to hold down use key may also work.

[LukeyB]

video of bug: http://www.dailymotion.com/video/x59...-cz_videogames

[LukeyB]

Resolved with Orpheu...

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fakemeta>
#include <orpheu>
#include <orpheu_advanced>
#include <orpheu_memory>
public plugin_init()
{        
    OrpheuRegisterHook(OrpheuGetFunction("PM_Duck"),"OnPM_Duck")
}
public OrpheuHookReturn:OnPM_Duck()
{
    new OrpheuStruct:ppmove = get_ppmove()
    new id = OrpheuGetStructMember(ppmove,"player_index") + 1
    if(is_user_alive(id) && is_user_bot(id) && pev(id, pev_button) & IN_USE)
    {
        return OrpheuSupercede
    }
    return OrpheuIgnored
}
OrpheuStruct:get_ppmove()
{        
    return OrpheuGetStructFromAddress(OrpheuStructPlayerMove,OrpheuMemoryGet("ppmove"))
}