[5aloOod]

hello everyone
i need little help in this code to make it work only with ct

PHP Code:

#include <amxmodx> 
#include <amxmisc> 
#include <cstrike> 
#include <fun> 
#include <hamsandwich> 
#include <engine> 
#include <fakemeta> 
#include <fakemeta_util> 
#include <colorchat> 

#define PLUGIN "Class Menu" 
#define VERSION "1.0" 
#define AUTHOR "Blizzard" 

new ClassName[33]; 

enum 
{ 
    CLASS_NONE, 
    CLASS_1, 
    CLASS_2, 
    CLASS_3, 
    CLASS_4, 
    CLASS_5, 
    CLASS_6, 
    CLASS_7, 
    CLASS_8, 
    CLASS_9, 
    CLASS_10, 
    CLASS_11, 
     
    ALL_CLASSES 
} 

new const CLASSES[ALL_CLASSES][] = 
{ 
    "None", 
    "Leone", 
    "Commando", 
    "Machine Gun", 
    "Rambo", 
    "Schmidt", 
    "Krieg", 
    "IDF Defender", 
    "Rifle", 
    "Maverick", 
    "Clarion", 
    "Bullpup" 
} 
     

public plugin_init() { 

    register_plugin(PLUGIN, VERSION, AUTHOR) 
    register_clcmd( "say /class", "ClassMenu" ); 

    RegisterHam(Ham_Spawn, "player", "fwd_Player_Spawn", 1); 
} 

public client_connect(id) 
{ 
    ClassName[id] = CLASS_NONE; 
     
    // USE THIS TO SHOW CLASS MENU ONCE AFTER CONNECTING TO SERVER 
    // THIS COULD CAUSE PROBLEMS IF PLAYER JOINS TEAM AND DOESNT SPAWN STAYS DEAD TILL NEXT ROUND! 
    //set_task(10.0, "ClassMenu", id);  
    // UNCOMMENT ABOVE TO USE = // <= DELETE THESE 
     
} 

/* THIS STARTS THE HUD MESSAGE LOOP */ 
public fwd_Player_Spawn(id) 
{ 
    set_task(1.0, "ShowHud", id); 
    ClassName[id] = CLASS_NONE; 
    strip_user_weapons(id); 
    give_item(id, "weapon_knife"); 
     
    ClassMenu(id);  // USE THIS TO SHOW MENU EVERY SPAWN ONLY 
     
} 

/* THIS SHOWS HUD PLAYER CLASS AND RE LOOPS IT */ 
public ShowHud(id) 
{ 
    set_hudmessage(255, 255, 0, 0.01, 0.18, 0, _, 1.0, _, _, 1); 
    show_hudmessage(id, "Class: %s", CLASSES[ClassName[id]]); 

    set_task(1.0, "ShowHud", id); 
     
} 

/* CLASS MENU */     
public ClassMenu(id) 
{ 
new menu = menu_create("\rClass Menu :^n\yMade By Cheese.", "menu_handler"); 

menu_additem(menu, "\wLeone", "1", 0); 
menu_additem(menu, "\wCommando", "2", 0); 
menu_additem(menu, "\wMachine Gun", "3", 0); 
menu_additem(menu, "\wRambo", "4", 0); 
menu_additem(menu, "\wSchmidt", "5", 0); 
menu_additem(menu, "\wKrieg", "6", 0); 
menu_additem(menu, "\wIDF Defender", "7", 0); 
menu_additem(menu, "\wRifle", "8", 0); 
menu_additem(menu, "\wMaverick", "9", 0); 
menu_additem(menu, "\wClarion", "10", 0); 
menu_additem(menu, "\wBullpup", "11", 0); 

menu_setprop(menu, MPROP_EXIT, MEXIT_ALL); 
menu_display(id, menu, 0); 

} 
public menu_handler(id, menu, item) 
{ 
if( item == MENU_EXIT ) 
{ 
    menu_destroy(menu); 
    return PLUGIN_HANDLED; 
     
} 
new data[6], iName[64]; 
new access, callback; 

menu_item_getinfo(menu, item, access, data,5, iName, 63, callback); 
new key = str_to_num(data); 
switch(key) 
     
{ 
case 1: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Leone^x03 ^x04[Shotgun][Deagle][HE Grenade]^x04"); 
    give_item(id, "weapon_xm1014"); 
    give_item(id, "weapon_deagle"); 
    give_item(id, "weapon_hegrenade"); 
    cs_set_user_bpammo( id, CSW_XM1014, 200 ); 
    cs_set_user_bpammo( id, CSW_DEAGLE, 200 ); 
    ClassName[id] = CLASS_1; 
     
} 
case 2: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class^x03 Commando^x03 ^x04[Dak Dak][Usp][HE Grenade]^x04"); 
    give_item(id, "weapon_sg550"); 
    give_item(id, "weapon_usp"); 
    give_item(id, "weapon_flashbang"); 
    cs_set_user_bpammo( id, CSW_SG550, 200 ); 
    cs_set_user_bpammo( id, CSW_USP, 200 ); 
    ClassName[id] = CLASS_2; 
} 
case 3: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Machine Gun^x03 ^x04[Mp5][Glock][Smoke Grenade]^x04"); 
    give_item(id, "weapon_mp5navy"); 
    give_item(id, "weapon_glock18"); 
    give_item(id, "weapon_smokegrenade"); 
    cs_set_user_bpammo( id, CSW_MP5NAVY, 200 ); 
    cs_set_user_bpammo( id, CSW_GLOCK18, 200 ); 
    ClassName[id] = CLASS_3; 
} 
case 4: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Rambo^x03 ^x04[Ak47][Five-Seven][HE Grenade]^x04"); 
    give_item(id, "weapon_ak47"); 
    give_item(id, "weapon_fiveseven"); 
    give_item(id, "weapon_hegrenade"); 
    cs_set_user_bpammo( id, CSW_AK47, 200 ); 
    cs_set_user_bpammo( id, CSW_FIVESEVEN, 200 ); 
    ClassName[id] = CLASS_4; 
} 
case 5: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Schmidt^x03 ^x04[Scout][Deagle][Flash Bang]^x04"); 
    give_item(id, "weapon_scout"); 
    give_item(id, "weapon_deagle"); 
    give_item(id, "weapon_flashbang"); 
    cs_set_user_bpammo( id, CSW_SCOUT, 200 ); 
    cs_set_user_bpammo( id, CSW_DEAGLE, 200 ); 
    ClassName[id] = CLASS_5; 
} 
case 6: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Krieg^x03 ^x04[Krieg 552][Usp][Smoke Grenade]^x04"); 
    give_item(id, "weapon_sg552"); 
    give_item(id, "weapon_usp"); 
    give_item(id, "weapon_smokegrenade"); 
    cs_set_user_bpammo( id, CSW_SG552, 200 ); 
    cs_set_user_bpammo( id, CSW_USP, 200 ); 
    ClassName[id] = CLASS_6; 
} 
case 7: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03IDF Defender^x03 ^x04[Galil][Glock][He Grenade]^x04"); 
    give_item(id, "weapon_galil"); 
    give_item(id, "weapon_glock18"); 
    give_item(id, "weapon_hegrenade"); 
    cs_set_user_bpammo( id, CSW_GALIL, 200 ); 
    cs_set_user_bpammo( id, CSW_GLOCK18, 200 ); 
    ClassName[id] = CLASS_7; 
} 
case 8: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Rifle^x03 ^x04[Sniper][Five-Seven][Flash Bang]^x04"); 
    give_item(id, "weapon_awp"); 
    give_item(id, "weapon_fiveseven"); 
    give_item(id, "weapon_flashbang"); 
    cs_set_user_bpammo( id, CSW_AWP, 200 ); 
    cs_set_user_bpammo( id, CSW_FIVESEVEN, 200 ); 
    ClassName[id] = CLASS_8; 
} 
case 9: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class ^x03Maverick^x03 ^x04[M4a1][Deagle][Smoke Grenade]^x04"); 
    give_item(id, "weapon_m4a1"); 
    give_item(id, "weapon_deagle"); 
    give_item(id, "weapon_smokegrenade"); 
    cs_set_user_bpammo( id, CSW_M4A1, 200 ); 
    cs_set_user_bpammo( id, CSW_DEAGLE, 200 ); 
    ClassName[id] = CLASS_9; 
} 
case 10: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class^x03 Clarion^x03 ^x04[Famas][Usp][He Grenade]^x04"); 
    give_item(id, "weapon_famas"); 
    give_item(id, "weapon_usp"); 
    give_item(id, "weapon_hegrenade"); 
    cs_set_user_bpammo( id, CSW_FAMAS, 200 ); 
    cs_set_user_bpammo( id, CSW_USP, 200 ); 
    ClassName[id] = CLASS_10; 
} 
case 11: 
{ 
    ColorChat(id, RED,"^x04[ Class ]^x01 You Have Chosen The Class^x03 Bullpup^x03 ^x04[Aug][Glock][Flash Bang]^x04"); 
    give_item(id, "weapon_aug"); 
    give_item(id, "weapon_glock18"); 
    give_item(id, "weapon_flashbang"); 
    cs_set_user_bpammo( id, CSW_AUG, 200 ); 
    cs_set_user_bpammo( id, CSW_GLOCK18, 200 ); 
    ClassName[id] = CLASS_11; 
} 
} 

return PLUGIN_HANDLED; 
} 


thanks for your attention

[Blizzard_87]

PHP Code:

public fwd_Player_Spawn(id)  
{  
    if( is_user_alive( id ) )
    {
        set_task(1.0, "ShowHud", id);  
        ClassName[id] = CLASS_NONE;  
        strip_user_weapons(id);  
        give_item(id, "weapon_knife");  
     
        if( cs_get_user_team( id ) == CS_TEAM_CT )
        {
             ClassMenu(id);  // USE THIS TO SHOW MENU EVERY SPAWN ONLY  
        }
    }      
} 


plus this looks like a very old plugin that cheese badly coded which i added the enums for the class hud display... wow old lol and bad coding from me also...

i should recode this whole thing so its better lol...

[5aloOod]

thanks for your replay
even the code bad coded it works fine xD

[wickedd]

@Blizzard 87

Terrorist can still see the menu.

PHP Code:

register_clcmd( "say /class", "ClassMenu" ) 


[Blizzard_87]

Originally Posted by wickedd @Blizzard 87 Terrorist can still see the menu. PHP Code: register_clcmd( "say /class", "ClassMenu" )

Oh haha. Did this on my phone. Can't believe I forgot that part.

If the OP wants i'll re write whole plugin so it's alot better and alot less code.

[5aloOod]

Originally Posted by wickedd @Blizzard 87 Terrorist can still see the menu. PHP Code: register_clcmd( "say /class", "ClassMenu" )

yeah you are right
and the hud message shows to terrorist

[Blizzard_87]

Originally Posted by 5aloOod yeah you are right and the hud message shows to terrorist

Sorry. I've almost finished re making whole plugin.

Also added client command to enable dis able the hud message.

[5aloOod]

Originally Posted by Blizzard_87 Sorry. I've almost finished re making whole plugin. Also added client command to enable dis able the hud message.

no problem thanks for re making the plugin

[Blizzard_87]

Originally Posted by 5aloOod no problem thanks for re making the plugin

Will get to finishing it later on. So keep eye on this thread in couple hours from now.

EDIT:

Here ya go...

Cvars:

cm_team_mode "2" // default
"0" - plugin off
"1" - terrorist only
"2" - ct only
"3" - both teams

SOURCE

#include < amxmodx >
#include < hamsandwich >
#include < fun >
#include < cstrike >

#pragma semicolon 1

#if AMXX_VERSION_NUM >= 183
    #define ColorChat   client_print_color
    #define RED  print_team_red
    #define BLUE        print_team_blue
    #define GREY        print_team_grey
    #define DEFAULT  print_team_default
#else
    #include < colorchat >
#endif

#define PLUGIN "Class Menu"
#define VERSION "0.0.1"
#define AUTHOR "Blizzard_87"

#define cm(%0)      ( sizeof(%0) - 1 )

#define Set(%1)             ( BitHud |= ( 1 << ( %1 & 31 ) ) )
#define Clear(%1)           ( BitHud &= ~( 1 << ( %1 & 31 ) ) )
#define Check(%1)           ( BitHud & ( 1 << ( %1 & 31 ) ) )

new BitHud;

// Enum Structure
enum _:mData 
{
    m_szClassName[ 32 ],
    m_szClassDesc[ 64 ],
    m_szPrimary[ 32 ],
    m_iPriBpAmmo,
    m_szSecondary[ 32 ],
    m_iSecBpAmmo,
    m_szGrenade[ 32 ]
};

// Constants
new g_mPlayerData[  ][ mData ] = 
{
    { "None", "None", "None", 0, "None", 0, "None" },
    { "Leone", "[Shotgun][Deagle][HE Grenade]", "weapon_xm1014", 200, "weapon_deagle", 200, "weapon_hegrenade" },
    { "Commando", "[Dak Dak][Usp][FlashBang]", "weapon_sg550", 200, "weapon_usp", 200, "weapon_flashbang" },
    { "Mp5 Navy", "[Mp5][Glock][Smoke Grenade]", "weapon_mp5navy", 200, "weapon_glock18", 200, "weapon_smokegrenade" },
    { "Rambo", "[Ak47][Five-Seven][HE Grenade]", "weapon_ak47", 200, "weapon_fiveseven", 200, "weapon_hegrenade" },
    { "Schmidt", "[Scout][Deagle][Flash Bang]", "weapon_scout",200, "weapon_deagle", 200, "weapon_flashbang" },
    { "Krieg", "[Krieg 552][Usp][Smoke Grenade]", "weapon_sg552", 200, "weapon_usp", 200, "weapon_smokegrenade" },
    { "IDF Defender", "[Galil][Glock][He Grenade]", "weapon_galil", 200, "weapon_glock18", 200, "weapon_hegrenade" },
    { "Rifle", "[Sniper][Five-Seven][Flash Bang]", "weapon_awp", 200, "weapon_fiveseven", 200, "weapon_flashbang" },
    { "Maverick", "[M4a1][Deagle][Smoke Grenade]", "weapon_m4a1", 200, "weapon_deagle", 200, "weapon_smokegrenade" },
    { "Clarion", "[Famas][Usp][He Grenade]", "weapon_famas", 200, "weapon_usp", 200, "weapon_hegrenade" },
    { "Bullpup", "[Aug][Glock][Flash Bang]", "weapon_aug", 200, "weapon_glock18", 200, "weapon_flashbang" }
};
    

// Integers
new g_iPlayerClass[ 33 ], g_iTeamMode;

// Cvars
new g_pTeamMode;

public plugin_init( ) 
{
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    // Register Ham
    RegisterHam( Ham_Spawn, "player", "CBasePlayer_Spawn_P", .Post = 1 );
    RegisterHam( Ham_Killed, "player", "CBasePlayer_Killed_P", .Post = 1 );
    
    // Register Events
    register_event( "HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0" );
    
    // Register Client Commands
    register_clcmd( "say /class", "ClCmd_CheckMode" );
    register_clcmd( "say /hud", "ClCmd_ClassHud" );
    
    // Register Cvars
    g_pTeamMode = register_cvar( "cm_team_mode", "0" ); // 0 - Plugin Off | 1 - Terrorist Only | 2 - CT Only | 3 - Both Teams
    g_iTeamMode = get_pcvar_num( g_pTeamMode );
    
    // Set Perm Hud Task
    set_task( 1.0, "Func_ClassHud", 100, "", 0, "b" );
}

//  Public Functions  //

public client_putinserver( index )
{
    g_iPlayerClass[ index ] = 0;
    Set( index );
}

public Event_HLTV_New_Round( )
{
    g_iTeamMode = get_pcvar_num( g_pTeamMode );
}

public CBasePlayer_Spawn_P( index )
{
    if( is_user_alive( index ) ) ClCmd_CheckMode( index );
}

public CBasePlayer_Killed_P( index )
{
    g_iPlayerClass[ index ] = 0;
}

public ClCmd_ClassHud( index )
{
    if( Check( index ) )
        Clear( index );
    else
        Set( index );
    return PLUGIN_HANDLED;
}

public ClCmd_CheckMode( index )
{
    if( is_user_alive( index ) )
    {
        switch( g_iTeamMode )
        {
            case 0: return PLUGIN_HANDLED;
            case 1:
            {
                if( get_user_team( index ) == 1 )
                    ClCmd_ClassMenu( index );
            }
            case 2:
            {
                if( get_user_team( index ) == 2 )
                    ClCmd_ClassMenu( index );
            }
            case 3:
            {
                ClCmd_ClassMenu( index );
            }
        }
        return PLUGIN_HANDLED;
    }
    return PLUGIN_HANDLED;
}

public ClCmd_ClassMenu( index )
{
    new szString[ 64 ];
    
    new menu = menu_create( "\rClass Menu:^n\yMade By Blizzard_87.", "ClassMenu_Handler" );
    
    for( new i = 1; i < sizeof( g_mPlayerData ); i++ )
    {
        formatex( szString, cm( szString ), "%s \y%s", g_mPlayerData[ i ][ m_szClassName ], g_mPlayerData[ i ][ m_szClassDesc ] );
        menu_additem( menu, szString );
    }
    
    menu_display( index, menu );
    return PLUGIN_HANDLED;
}

public ClassMenu_Handler( index, menu, item )
{
    if( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    
    g_iPlayerClass[ index ] = item + 1;
    
    Func_SetWeapons( index, g_iPlayerClass[ index ] );

    menu_destroy( menu );
    return PLUGIN_HANDLED;
}

public Func_ClassHud( )
{
    new iPlayers[ 32 ], iNum, i, Player;
    
    switch( g_iTeamMode )
    {
        case 0: return;
        case 1: get_players( iPlayers, iNum, "ce", "TERRORIST" );
        case 2: get_players( iPlayers, iNum, "ce", "CT" );
        case 3: get_players( iPlayers, iNum, "c" );
    }
    
    for( i = 0; i < iNum; i++ )
    {
        Player = iPlayers[ i ];
        
        if( Check( Player ) )
        {
            set_hudmessage( 255, 255, 0, -1.0, 0.05, 0, 0.0, 1.1, 0.0, 0.0, -1 );  
            show_hudmessage( Player, "Class: %s^nWeapons: %s", 
            g_mPlayerData[ g_iPlayerClass[ Player ] ][ m_szClassName ],
            g_mPlayerData[ g_iPlayerClass[ Player ] ][ m_szClassDesc ]);
        }
    }
}

//  Private Functions //
Func_SetWeapons( index, iClass )
{
    if( is_user_alive( index ) )
    {
        strip_user_weapons( index );
        
        give_item( index, "weapon_knife" );
        
        give_item( index, g_mPlayerData[ iClass ][ m_szPrimary ] );
        cs_set_user_bpammo( index, get_weaponid( g_mPlayerData[ iClass ][ m_szPrimary ] ), g_mPlayerData[ iClass ][ m_iPriBpAmmo ] );
        
        give_item( index, g_mPlayerData[ iClass ][ m_szSecondary] );
        cs_set_user_bpammo( index, get_weaponid( g_mPlayerData[ iClass ][ m_szSecondary ] ), g_mPlayerData[ iClass ][ m_iSecBpAmmo ] );
        
        give_item( index, g_mPlayerData[ iClass ][ m_szGrenade] );
        
        client_print_color( index, print_team_red, "^4[ Class ]^1 You Have Chosen The Class ^3%s ^4%s",
        g_mPlayerData[ g_iPlayerClass[ index ] ][ m_szClassName ],
        g_mPlayerData[ g_iPlayerClass[ index ] ][ m_szClassDesc] );
    }
}

Or to get plugin compiled click below.

[5aloOod]

tested and worked
thanks for your help