[cosmicfugue]

First I apologize for my bad english.

I Have surf server in csgo but there are bodies and weapons everywhere. I want auto body, gun, bloody clear who can help me ?

Thanks For Helping.

[iskenderkebab33]

uhh? this https://forums.alliedmods.net/showpo...02&postcount=5 to remove weapons or with Console CMD mp_death_drop_gun 0

and

remove body https://forums.alliedmods.net/showthread.php?p=622834

[LenHard]

PHP Code:

#include <sourcemod>
#include <sdktools_functions>
#include <sdktools_entinput>

#pragma newdecls required
#pragma semicolon 1

public void OnPluginStart() {
    HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre);
}

public void Event_PlayerDeath(Event hEvent, const char[] sEventName, bool bDontBroadcast)
{
    int client = GetClientOfUserId(hEvent.GetInt("userid"));
    
    if (0 < client <= MaxClients && IsClientInGame(client))
    {        
        int iRagdoll = GetEntPropEnt(client, Prop_Send, "m_hRagdoll");
        if (IsValidEdict(iRagdoll)) AcceptEntityInput(iRagdoll, "Kill");
        
        int offset = FindDataMapInfo(client, "m_hMyWeapons") - 4;
        
        for (int i = 0; i < 48; i++) 
        {
            offset += 4;
    
            int iWeapon = GetEntDataEnt2(client, offset);
            
            if (IsValidEdict(iWeapon)) 
            {
                int iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iPrimaryAmmoType") * 4);
                SetEntData(client, iAmmo, 0, 4, true);
        
                iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iSecondaryAmmoType") * 4);
                SetEntData(client, iAmmo, 0, 4, true);
        
                if (RemovePlayerItem(client, iWeapon)) 
                    AcceptEntityInput(iWeapon, "Kill");
            }
        }
    }
} 


[Ilusion9]

CS:GO CVARS:

PHP Code:


weapon_max_before_cleanup 20 (maximum 20 dropped weapons on map)
- If set to non-zero, will remove the oldest dropped weapon to maintain the specified number of dropped weapons in the world. 


or

PHP Code:


weapon_auto_cleanup_time 10 (seconds)
- If set to non-zero, weapons will delete themselves after the specified time (in seconds) if no players are near. 


[cosmicfugue]

Originally Posted by LenHard PHP Code: #include <sourcemod> #include <sdktools_functions> #include <sdktools_entinput> #pragma newdecls required #pragma semicolon 1 public void OnPluginStart() {     HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre); } public void Event_PlayerDeath(Event hEvent, const char[] sEventName, bool bDontBroadcast) {     int client = GetClientOfUserId(hEvent.GetInt("userid"));          if (0 < client <= MaxClients && IsClientInGame(client))     {                 int iRagdoll = GetEntPropEnt(client, Prop_Send, "m_hRagdoll");         if (IsValidEdict(iRagdoll)) AcceptEntityInput(iRagdoll, "Kill");                  int offset = FindDataMapInfo(client, "m_hMyWeapons") - 4;                  for (int i = 0; i < 48; i++)          {             offset += 4;                  int iWeapon = GetEntDataEnt2(client, offset);                          if (IsValidEdict(iWeapon))              {                 int iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iPrimaryAmmoType") * 4);                 SetEntData(client, iAmmo, 0, 4, true);                          iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iSecondaryAmmoType") * 4);                 SetEntData(client, iAmmo, 0, 4, true);                          if (RemovePlayerItem(client, iWeapon))                      AcceptEntityInput(iWeapon, "Kill");             }         }     } }

Thanks for helping,

but i have fun servers, what is the plugin enable code ? i dont want plugin playing in jailbreak and other maps, i want just surf? i have maps prefix but i need plugins enable code..

[LenHard]

Originally Posted by cosmicfugue Thanks for helping, but i have fun servers, what is the plugin enable code ? i dont want plugin playing in jailbreak and other maps, i want just surf? i have maps prefix but i need plugins enable code..

PHP Code:

#include <sourcemod> 
#include <sdktools_functions> 
#include <sdktools_entinput> 

#pragma newdecls required 
#pragma semicolon 1 

ConVar gCV_Enable;

public void OnPluginStart() 
{ 
    gCV_Enable = CreateConVar("cleanup_enable", "1", "Enables the clean up plugin.", FCVAR_NOTIFY, true, 0.0, true, 1.0);
    
    HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre); 
} 

public void Event_PlayerDeath(Event hEvent, const char[] sEventName, bool bDontBroadcast) 
{ 
    if (!gCV_Enable.BoolValue)
        return;
        
    int client = GetClientOfUserId(hEvent.GetInt("userid")); 
     
    if (0 < client <= MaxClients && IsClientInGame(client)) 
    {         
        int iRagdoll = GetEntPropEnt(client, Prop_Send, "m_hRagdoll"); 
        if (IsValidEdict(iRagdoll)) AcceptEntityInput(iRagdoll, "Kill"); 
         
        int offset = FindDataMapInfo(client, "m_hMyWeapons") - 4; 
         
        for (int i = 0; i < 48; i++)  
        { 
            offset += 4; 
     
            int iWeapon = GetEntDataEnt2(client, offset); 
             
            if (IsValidEdict(iWeapon))  
            { 
                int iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iPrimaryAmmoType") * 4); 
                SetEntData(client, iAmmo, 0, 4, true); 
         
                iAmmo = FindDataMapInfo(client, "m_iAmmo") + (GetEntProp(iWeapon, Prop_Data, "m_iSecondaryAmmoType") * 4); 
                SetEntData(client, iAmmo, 0, 4, true); 
         
                if (RemovePlayerItem(client, iWeapon))  
                    AcceptEntityInput(iWeapon, "Kill"); 
            } 
        } 
    } 
} 


cleanup_enable is the convar to enable/disable the plugin.