[PatriotGames]

This is probably easy for most of you, but the logic has me scratching my head.

A function exec the same nfty code for any one of the special infected (no tank) or the witch , with each having their own classId (1-6 for SI, 7 for witch).

How can we do a different valid client check for any classId and if true, run the same nifty code without writing it twice?

//client check for SI (classId 1-6):

if (class != 7 && IsClientInGame(client) && IsPlayerAlive(client) && GetClientTeam(client) == 3)  // Note: is it correct that GetClientTeam() does not exist for the Witch?
{
	nifty code;
}

// client check for Witch (classId 7):

if (class == 7 && IsValidWitch(witch))
{
	nifty code;
}

IsValidWitch(witch)
{
	if (witch != INVALID_ENT_REFERENCE && IsValidEdict(witch) && IsValidEntity(witch))
	{
		decl String:classname[32];
		GetEdictClassname(witch, classname, sizeof(classname));
		if(StrEqual(classname, "witch"))
		{
			return true;
		}
	}
	return false;
}

Thank you,
pg

[Psyk0tik]

Probably not the best way but here you go:

PHP Code:

void MyFunction(int client)
{
    if (bIsSpecialInfected(client) || bIsWitch(client))
    {
        // nifty code
    }
}

stock bool bIsSpecialInfected(int client)
{
    // Invalid client = no
    if (0 >= client || client > MaxClients || !IsClientInGame(client) || !IsPlayerAlive(client))
    {
        return false;
    }

    // Zombie class is 0, 7, or greater than 7 = no
    int iClass = GetEntProp(client, Prop_Send, "m_zombieClass");
    if (0 >= iClass || iClass >= 7)
    {
        return false;
    }

    // Client team is not infected = no
    if (GetClientTeam(client) != 3)
    {
        return false;
    }

    // If none of the above return false (no), then return true (yes)
    return true;
}

stock bool bIsWitch(int witch)
{
    // Entity must be valid
    if (witch != INVALID_ENT_REFERENCE && IsValidEntity(witch))
    {
        char sClassname[32];
        GetEntityClassname(witch, sClassname, sizeof(sClassname));
        if (StrEqual(sClassname, "witch"))
        {
            // Witch class = yes
            return true;
        }
    }

    // If the above does not return true (yes), then return false (no)
    return false;
} 


[PatriotGames]

Hi Crasher,

Thanks for your suggestion, it seems like a very reasonable solution.

Any reason why we couldn't simplify it further with this small change:

Original:

    // Zombie class is 0, 7, or greater than 7 = no
    int iClass = GetEntProp(client, Prop_Send, "m_zombieClass");
    if (0 >= iClass || iClass >= 7)
    {
        return false;
    }

    // Client team is not infected = no
    if (GetClientTeam(client) != 3)
    {
        return false;
    }

    // If none of the above return false (no), then return true (yes)
    return true;

Change:

stock bool bIsSpecialInfected(int client)
{
    // Invalid client = no
    if (0 >= client || client > MaxClients || !IsClientInGame(client) || !IsPlayerAlive(client))
    {
        return false;
    }

    // Zombie class is 0, 7, or greater than 7 = no  or is not on infected team
    int iClass = GetEntProp(client, Prop_Send, "m_zombieClass");
    if (0 >= iClass || iClass >= 7 || GetClientTeam(client) != 3)
    {
        return false;
    }

    // If none of the above return false (no), then return true (yes)
    return true;

Thank you,
pg

[Psyk0tik]

No particular reason. I just wanted to show an extra example of returning false from an if statement. You can actually check the team first before the zombie class since the zombie class would be 0 anyway if the client is a survivor or spectator.

[PatriotGames]

I appreciate your examples and the way you commented what was happening at each step, really helpful! Thanks for taking the time to do this.

pg

[Psyk0tik]

No problem; glad to help!