[blanko]

Any way to make gravity different for CTs and Ts? Like Ts can jump way higher than cts?

[iceeedr]

An easy method would be this below, but there are better ways to achieve the same result.

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <cstrike>
#include <fun>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "arsmi"

new CvarCtGravity, CvarTrGravity

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	CvarCtGravity = register_cvar("amx_ct_gravity", "800")
	CvarTrGravity = register_cvar("amx_tr_gravity", "500")
	RegisterHam(Ham_Spawn,"player","fwPlayerSpawn",1)
}

public fwPlayerSpawn( id )
{
	if(!is_user_alive(id)) return
	
	switch(cs_get_user_team(id))
	{
		case CS_TEAM_T: set_user_gravity(id, get_pcvar_float(CvarTrGravity))

		case CS_TEAM_CT: set_user_gravity(id, get_pcvar_float(CvarCtGravity))
	}
}

[blanko]

Originally Posted by iceeedr An easy method would be this below, but there are better ways to achieve the same result. /* Plugin generated by AMXX-Studio */ #include <amxmodx> #include <amxmisc> #include <hamsandwich> #include <cstrike> #include <fun> #define PLUGIN "New Plug-In" #define VERSION "1.0" #define AUTHOR "arsmi" new CvarCtGravity, CvarTrGravity public plugin_init() { register_plugin(PLUGIN, VERSION, AUTHOR) CvarCtGravity = register_cvar("amx_ct_gravity", "800") CvarTrGravity = register_cvar("amx_tr_gravity", "500") RegisterHam(Ham_Spawn,"player","fwPlayerSpawn",1) } public fwPlayerSpawn( id ) { if(!is_user_connected(id) || !is_user_alive(id)) return new CsTeams:Team = cs_get_user_team(id) switch(Team) { case CS_TEAM_T: set_user_gravity(id, get_pcvar_float(CvarTrGravity)) case CS_TEAM_CT: set_user_gravity(id, get_pcvar_float(CvarCtGravity)) } }

nothing happened

[OciXCrom]

That means you have another plugin that's blocking the effects from this one

PS: iceeedr - "is_user_alive" also checks if the user is connected, you don't need both checks in there. Also the "Team" variable is unnecessary.

[iceeedr]

Originally Posted by OciXCrom That means you have another plugin that's blocking the effects from this one PS: iceeedr - "is_user_alive" also checks if the user is connected, you don't need both checks in there. Also the "Team" variable is unnecessary.

@Ocix You're right though, I've experienced some "invalid player" errors, when just check if the player is alive, I know in the documentation it's written that by obvious if someone is alive it's because they're connected but in reality I've experienced some problems with that ... and as for the variable, I really do not know what I was thinking at the time: D

[OciXCrom]

Nope, it's not possible to experience such errors. "is_user_alive" is the only thing you need in this case - you can even check the function's code in Github:

PHP Code:

static cell AMX_NATIVE_CALL is_user_alive(AMX *amx, cell *params) /* 1 param */
{
    int index = params[1];

    if (index < 1 || index > gpGlobals->maxClients)
    {
        return FALSE;
    } 


As you can see, the first thing it checks is if the user is connected. If you got errors, it was probably a different scenario.

[blanko]

Originally Posted by OciXCrom That means you have another plugin that's blocking the effects from this one PS: iceeedr - "is_user_alive" also checks if the user is connected, you don't need both checks in there. Also the "Team" variable is unnecessary.

I don't know how to solve this... what kind of plugin could be blocking this one, buddy?

[OciXCrom]

Probably some that is changing the gravity. If you don't know which one has such an option, try disabling all of them and then enable 1 by 1 to find it.

[PartialCloning]

It's not your plugins, the above plugin isn't setting the gravity correctly.

Try this:

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich> 

new gCvarGravity[4];

public plugin_init() 
{ 
    register_plugin("Team Specific Gravity", "1.0", "Partial Cloning");

    gCvarGravity[0] = get_cvar_pointer("sv_gravity");
    gCvarGravity[1] = register_cvar("sv_gravity_tt", "400");
    gCvarGravity[2] = register_cvar("sv_gravity_ct", "800");
    gCvarGravity[3] = register_cvar("sv_gravity_sp", "1900");

    RegisterHam(Ham_Spawn, "player", "HamOnPlayerSpawnPost", 1);
}

public HamOnPlayerSpawnPost(id)
{
    if(!is_user_alive(id))
        return HAM_IGNORED;

    set_pev(id, pev_gravity, get_pcvar_float(gCvarGravity[_:cs_get_user_team(id)]) / get_pcvar_float(gCvarGravity[0]));
    return HAM_IGNORED;
}