[Solved] Sorting Problem

Celena Luna · **Author**

I am trying thing to do with sort but I still don't understand how to use it.

PHP Code:


			
enum

{

    PLAYER_ID = 0,

    PLAYER_SCORE

}

//Testing

Player_Score[0] = 100

Player_Score[1] = 200

Player_Score[2] = 300

...

Player_Score[32] = 3300



...



//Begin Sorting

public SortKills()

{

    new iCount = 0

    for(new i=0; i < sizeof(Player_Score); i++)

    {

        Ranking[iCount][PLAYER_ID] = i

        Ranking[iCount][PLAYER_SCORED] = Player_Score[i]

        iCount++

    }



    SortCustom2D(Ranking , iCount, "SortKills_Sort")

}



public SortKills_Sort(iElem1[], iElem2[])

{

    new iKills1 = iElem1[PLAYER_SCORED]

    new iKills2 = iElem2[PLAYER_SCORED]



    if(iKills1 > iKills2)

        return -1

    else if(iKills1 < iKills2)

        return 1

    

    return 0

}

After that, I make a test function

PHP Code:


			
public test_fuction(id)

{

    new name[33][33]

    for(new i=0; i<sizeof(name); i++)

    {

        if(is_user_connected(Ranking[i][PLAYER_ID]))

        {

            get_user_name(Ranking[i][PLAYER_ID], name[i], sizeof(name[]))

        }

        else

        {

            formatex(name[i], sizeof(name[]), "NONE")

        }

    }

    client_print(id, print_chat, "Rank 1:%i || Rank 2:%i || Rank 3: %i", Ranking[0][PLAYER_SCORED], Ranking[1][PLAYER_SCORED], Ranking[2][PLAYER_SCORED])

    client_print(id, print_chat, "Rank 1:%s || Rank 2:%s || Rank 3: %s", name[0], name[1], name[2])



}

But the score is all 0 and the name is all NONE

Please help

P/S: I did search but I still don't understand how to use it.

Saint Sinner · 03-02-2018 , 16:18 Re: Sorting Problem

You must to use a save data to make a rank or top 15... like fvault, nvault, adv_vault....

Natsheh · 03-02-2018 , 17:40 Re: Sorting Problem

PHP Code:


			
#include <amxmodx>

new Top15Player[33][2];

enum
{
    ID,
    KILLS
}

public plugin_init()
{
    register_clcmd("say /top15fraggers", "show_top15fraggers")
}

public show_top15fraggers(id)
{
    GetTop15PlayerInGame();
    
    new motd[1024], iLen;
    
    iLen = formatex(motd, charsmax(motd), "<!DOCTYPE HTML><html><head><title>Top15Fraggers</title></head><body>");
    
    new players[32], pnum;
    get_players(players, pnum, "h");
    
    if( pnum > 15 ) pnum = 15;
    
    for(new i, szName[32]; i < pnum; i++)
    {
        get_user_name(Top15Player[i][ID], szName, charsmax(szName))
        iLen += formatex(motd[iLen], charsmax(motd)-iLen, "<p>%d. %s with %d Kills!</p><br>", i+1, szName, Top15Player[i][KILLS]);
    }
    
    iLen += formatex(motd[iLen], charsmax(motd)-iLen, "</body></html>");
    
    show_motd(id, motd, "Top15 Fraggers InGame!");
}

GetTop15PlayerInGame()
{
    for(new z; z < sizeof Top15Player; z++) arrayset(Top15Player[z], 0, sizeof Top15Player[]);
    
    new players[32], pnum;
    get_players(players, pnum, "h");
    
    for(new i, player; i < pnum; i++)
    {
        player = players[i];
        Top15Player[i][ID] = player;
        Top15Player[i][KILLS] = get_user_frags(player);
    }
    
    SortCustom2D(Top15Player, sizeof Top15Player, "MySortFunc");
}

public MySortFunc(const elem1[], const elem2[], const array[], data[], data_size)
{
    if(elem1[ID] == 0 && elem2[ID] == 0) return 0;
    if(elem1[ID] == 0) return 1;
    if(elem2[ID] == 0) return -1;
    if(elem1[KILLS] > elem2[KILLS]) return -1;
    if(elem1[KILLS] < elem2[KILLS]) return 1;
    return 0;
}

This code will retrieve the top15 fraggers connected!!!

try to understand the code. its so simple

Celena Luna · 03-09-2018 , 16:37 Re: Sorting Problem

I managed to make it work. Thank ^^