[AssKicR]

A plugin to change the team/class of players...

Engine Required....

The plugin accepts both text and numbers
Valid values for class&team are as follows
<class> = scout,sniper,soldier,demoman,medic,hwguy,pyro ,spy,engineer,random,civilian
<class> = 1-11
<team> = blue,red,yellow,green
<team> = 1-4

Worked fine back when i made it for AMX... plz post comments how it works with AMXx

[Waylay]

Maybe change team would be good but not class ?

[Shadow1975]

it's bugged when i amx_team someone then stay on the same team and then change color and with the class changeing it's bugged i am a hwguy i use the command amx_class to change me to a spy wheile now i am a spy with a hwguy gun hehehehe odd but true

[Slash The Mighty]

Originally Posted by Waylay Maybe change team would be good but not class ?

When you have a command for changeing clients team, then it wouldnt make sens not have 1 there can change the model/class.
If someone were sniper on a map where snipers arent allowed (posible with NeoTF), Then the Admin would be able to change it.
But if you couldn't change the class, then you had to kick him.
And some players doesn't kick just becose they use another class then wanted.
Nice job anyway AssKicR !. You got my vote!.

[bug]

Originally Posted by AssKicR A plugin to change the team/class of players... <team> = blue,red,yellow,green <team> = 1-4

Can you please add the ability to change a player to team 6 spectate?

[terrum]

Originally Posted by bug Can you please add the ability to change a player to team 6 spectate?

This doesn't change their team. It only changes their colour name. But yeah, I want team 6 spectate too. Can this be done? Thanks.

[HLM]

I think this is everything you wanted..

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>

#define PC_SCOUT 1 
#define PC_SNIPER 2 
#define PC_SOLDIER    3 
#define PC_DEMOMAN 4 
#define PC_MEDIC 5 
#define PC_HVYWEAP     6 
#define PC_PYRO 7
#define PC_SPY 8
#define PC_ENGINEER 9
#define PC_RANDOM    10
#define PC_CIVILIAN 11
/****************************************************************************************************/
public plugin_init()
{
    register_plugin("TFC Team/Class Changer", "1.0", "AssKicR")
    register_clcmd("amx_class", "admin_class",ADMIN_SLAY,"<nick> <class>")
    register_clcmd("amx_team", "admin_team",ADMIN_SLAY,"<nick> <team>")
    return PLUGIN_CONTINUE
}
/****************************************************************************************************/
public admin_class(id,level,cid) { 
    if (!cmd_access(id,level,cid,2)) return PLUGIN_HANDLED 

    new arg[32],class[32]
    read_argv(1,arg,31) 
    read_argv(2,class,31) 

    new player = cmd_target(id,arg,7) 
    if (!player) return PLUGIN_HANDLED 

    if (equal(class,"scout")) set_user_class(player,PC_SCOUT)
    else if (equal(class,"sniper")) set_user_class(player,PC_SNIPER)
    else if (equal(class,"soldier")) set_user_class(player,PC_SOLDIER)
    else if (equal(class,"demoman")) set_user_class(player,PC_DEMOMAN)
    else if (equal(class,"medic")) set_user_class(player,PC_MEDIC)
    else if (equal(class,"hwguy")) set_user_class(player,PC_HVYWEAP)
    else if (equal(class,"pyro")) set_user_class(player,PC_PYRO)
    else if (equal(class,"spy")) set_user_class(player,PC_SPY)
    else if (equal(class,"engineer")) set_user_class(player,PC_ENGINEER)
    else if (equal(class,"random")) set_user_class(player,PC_RANDOM)
    else if (equal(class,"civilian")) set_user_class(player,PC_CIVILIAN)
    else if (str_to_num(class)>0&&str_to_num(class)<12) set_user_class(player,str_to_num(class))
    else {
        new hcmd[32], hinfo[128], hflag
        get_concmd(cid,hcmd,31,hflag,hinfo,127,level)
        console_print(id,"Usage: %s %s",hcmd,hinfo)
        return PLUGIN_HANDLED 
    }
    return PLUGIN_HANDLED  
} 
/****************************************************************************************************/
public admin_team(id,level,cid) { 
    if (!cmd_access(id,level,cid,2)) return PLUGIN_HANDLED 

    new arg[32],team[32]
    read_argv(1,arg,31) 
    read_argv(2,team,31) 

    new player = cmd_target(id,arg,7) 
    if (!player) return PLUGIN_HANDLED 

    if (equal(team,"blue")) set_player_team(player,1)
    else if (equal(team,"red")) set_player_team(player,2)
    else if (equal(team,"yellow")) set_player_team(player,3)
    else if (equal(team,"green")) set_player_team(player,4)
    else if (equal(team,"random")) set_player_team(player,5)
    else if (equal(team,"spectate")) set_player_team(player,6)
    else if (str_to_num(team)>0&&str_to_num(team)<7) set_player_team(player,str_to_num(team))
    else {
        new hcmd[32], hinfo[128], hflag
        get_concmd(cid,hcmd,31,hflag,hinfo,127,level)
        console_print(id,"Usage: %s %s",hcmd,hinfo)
        return PLUGIN_HANDLED 
    }
    return PLUGIN_HANDLED  
} 
/****************************************************************************************************/
stock get_user_class(id) {
    new class = entity_get_int(id, EV_INT_playerclass)
    return class
}
/****************************************************************************************************/
stock set_user_class(id,class) {
    entity_set_int(id, EV_INT_playerclass,class)
    show_class(id,get_user_class(id))
    return
}
/****************************************************************************************************/
stock get_player_team(id) {
    new team = entity_get_int(id, EV_INT_team)
    return team
}
/****************************************************************************************************/
stock set_player_team(id,team) {
    entity_set_int(id, EV_INT_team,team)
    show_team(id,get_player_team(id))
    return
}
/****************************************************************************************************/
stock show_class(id,class) {
    new name[33]
    get_user_name(id,name,32)
    switch (class) {
        case PC_SCOUT: client_print(id,print_console,"%s is now a scout",name)
        case PC_SNIPER: client_print(id,print_console,"%s is now a sniper",name)
        case PC_SOLDIER: client_print(id,print_console,"%s is now a soldier",name)
        case PC_DEMOMAN: client_print(id,print_console,"%s is now a demoman",name)
        case PC_MEDIC: client_print(id,print_console,"%s is now a medic",name)
        case PC_HVYWEAP: client_print(id,print_console,"%s is now a hwguy",name)
        case PC_PYRO: client_print(id,print_console,"%s is now a pyro",name)
        case PC_SPY: client_print(id,print_console,"%s is now a spy",name)
        case PC_ENGINEER: client_print(id,print_console,"%s is now a engineer",name)
        case PC_RANDOM: client_print(id,print_console,"%s is now a random class",name)
        case PC_CIVILIAN: client_print(id,print_console,"%s is now a civilian",name)
    }
}
/****************************************************************************************************/
stock show_team(id,team) {
    new name[33]
    get_user_name(id,name,32)
    switch (team) {
        case 1:    client_print(id,print_console,"%s is now on blue team",name)
        case 2:    client_print(id,print_console,"%s is now on red team",name)
        case 3:    client_print(id,print_console,"%s is now on yellow team",name)
        case 4:    client_print(id,print_console,"%s is now on green team",name)
        case 5:    client_print(id,print_console, "%s is now on a random team",name)
        case 6:    client_print(id,print_console, "%s is now on spectator team",name)
    }
}
/****************************************************************************************************/