[Javierko]

Hey coders,

on making some basic menu, i still dont know how to make item, that will after click make all player healt to 100..

Somebody knows? Thanks.

[Javierko]

I did it, but there is another problem and i dont know how to fix it..

I use CS_TEAM_T, and when my friend he have only bcdj, it works for him, but when iam in T team and his press this function my hp is still on the same.. And i have z flag... Somebody knows?

[8guawong]

nobody can help you if you don't show us your codes

[ESK0]

No code = No help

[Javierko]

Sorry guys, i forgot it.

PHP Code:

#define DEBUG

#define PLUGIN_NAME           "Menu"
#define PLUGIN_AUTHOR         "Javierko"
#define PLUGIN_DESCRIPTION    "Menu"
#define PLUGIN_VERSION        "1.0"
#define PLUGIN_URL            "hexmania.eu"

#define ITEMDRAW_DISABLED        (1<<0)

#include <sourcemod>
#include <cstrike>

public Plugin:myinfo =
{
    name = PLUGIN_NAME,
    author = PLUGIN_AUTHOR,
    description = PLUGIN_DESCRIPTION,
    version = PLUGIN_VERSION,
    url = PLUGIN_URL
};

public OnPluginStart()
{
    RegConsoleCmd("sm_menu", Command_Menu);
}

public Action:Command_Menu(client, args)
{
  Menu menu = new Menu(m_themenu);
  menu.SetTitle("Menu");
    menu.AddItem("item_1", "Set player HP on 100");
  //menu.ExitButton = true; //This is true by default
  menu.ExitBackButton = false; //You need this only if you want to add the "cancel" button to get to the previus menu
  menu.Display(client, MENU_TIME_FOREVER);
}

public int m_themenu(Menu menu, MenuAction action, int client, int index)
{
  if(action == MenuAction_Select)
  {
    char szItem[12];
    menu.GetItem(index, szItem, sizeof(szItem));
    if(StrEqual(szItem, "item_1", false))
    {
      SetEntityHealth(CS_TEAM_T, 100);
    }
  }
  else if(action == MenuAction_Cancel)
  {
    //Here you should display the old menu if exist
  }
  else if(action == MenuAction_End)
  {
    delete menu;
  }
  //You dont to check for this action: MenuCancel_ExitBack
} 


[xines]

Alrighty.

Spoiler

PHP Code:

#define PLUGIN_NAME           "Menu" 
#define PLUGIN_AUTHOR         "Javierko" 
#define PLUGIN_DESCRIPTION    "Menu" 
#define PLUGIN_VERSION        "1.0" 
#define PLUGIN_URL            "hexmania.eu" 

#include <sourcemod> 
#include <cstrike> 

public Plugin myinfo = 
{ 
    name = PLUGIN_NAME, 
    author = PLUGIN_AUTHOR, 
    description = PLUGIN_DESCRIPTION, 
    version = PLUGIN_VERSION, 
    url = PLUGIN_URL 
}; 

public void OnPluginStart() 
{ 
    RegConsoleCmd("sm_menu", Command_Menu); 
} 

public Action Command_Menu(int client, int args) 
{ 
    Menu menu = new Menu(m_themenu); 
    menu.SetTitle("Menu"); 
    menu.AddItem("item_1", "Set player HP on 100 (Terrorist)"); 
    //menu.ExitButton = true; //This is true by default
    menu.ExitBackButton = false; //You need this only if you want to add the "cancel" button to get to the previus menu 
    menu.Display(client, MENU_TIME_FOREVER);
    
    return Plugin_Handled;
} 

public int m_themenu(Menu menu, MenuAction action, int client, int index) 
{
    if(!IsValidClient(client)) return; //Client who fired this menu arent valid. so we return.

    if(action == MenuAction_Select) 
    {
        char szItem[12]; 
        menu.GetItem(index, szItem, sizeof(szItem));
        if(StrEqual(szItem, "item_1", false))
        {
            for (int i = 1; i <= MaxClients; i++) //Loop all client indexes
            {
                if(!IsValidClient(i)) continue; //If client is not valid, skip him.
            
                if(GetClientTeam(i) == CS_TEAM_T && IsPlayerAlive(i)) //is a Terrorist and alive.
                {
                    SetEntityHealth(i, 100); //Set our clients health to 100.
                }
            }
        }
    }
    else if(action == MenuAction_Cancel)
    {
        //Here you should display the old menu if exist
    }
    else if(action == MenuAction_End)
    {
        delete menu;
    }
    //You dont to check for this action: MenuCancel_ExitBack
}

stock bool IsValidClient(int client)
{
    return (1 <= client <= MaxClients && IsClientInGame(client));
} 


[Javierko]

Ok i will try, thanks

[Javierko]

Works perfectly, thank you..

Solved