[BoredGamer]

Hello!

I'm willing to pay for this service via Paypal. Send me a PM if ur interested.
Just have a reasonable price, or feel free to script it for free!

Anyhows, I need someone to write this script for me.

Mod. Counter-Strike:Source
Function. <PlayerA> writes a command in console e.g "dont_kill_me".
This will remove some hitboxes from him e.g head, chest, stomach, making him harder to kill for everyone else.
At new round <PlayerA> hitboxes should be reset to normal.
-OR- if thats not possible have the command be activated all time for the player by "dont_kill_me 1" and then deactivate and set to normal hitboxes by "dont_kill_me 0".
This command should only affect the player that uses it, not all players on the server.

I dont need any fancy code. Keep it clean and simple.
No notices, information or echo in console.
This command should be accessed by anyone on the server.

Hope someone can help me with this, thanks!

[NoS]

I see a problem with this, since everyone can type it in and nobody will die for an entire round.

[SuperShadow]

Sounds like god mode to me. How about this: http://forums.alliedmods.net/showthread.php?p=909479

[BoredGamer]

I dont need GodMode because then you cant kill them. I just need a simple script that removes some hitboxes but still have the player to be able to get killed (in the leg or something).

[DieTeetasse]

Use SDKHooks: https://forums.alliedmods.net/showthread.php?t=106748

Use TraceAttack:

PHP Code:

Action:public(victim, &attacker, &inflictor, &Float:damage, &damagetype, &ammotype, hitbox, hitgroup) 


and check for the specific hitbox. If it is change the damage to 0.0 and it would be (almost) the same if you would remove the hitbox.

[BoredGamer]

I dont have any script knowledge.
And I'm still willing to pay $$$ whoever helps me out with this.

[BoredGamer]

$100 , Anyone?

[canadianjeff]

this plugin was never made?

[Teamkiller324]

wouldn't be hard to make.

[Bacardi]

What a necro post

PHP Code:


#include <sdkhooks>
// ---------------------------
//  Hit Group standards
// ---------------------------
#define    HITGROUP_GENERIC    0
#define    HITGROUP_HEAD        1
#define    HITGROUP_CHEST        2
#define    HITGROUP_STOMACH    3
#define HITGROUP_LEFTARM    4    
#define HITGROUP_RIGHTARM    5
#define HITGROUP_LEFTLEG    6
#define HITGROUP_RIGHTLEG    7
#define HITGROUP_GEAR        10            // alerts NPC, but doesn't do damage or bleed (1/100th damage)


enum struct Player {
    bool enabled;
    
    void ToggleDontKillMe()
    {
        this.enabled = !this.enabled;
    }
    
    bool IsDontKillMe()
    {
        return this.enabled;
    }
}

Player player[MAXPLAYERS+1];

public void OnPluginStart()
{
    HookEvent("round_start", round_start, EventHookMode_PostNoCopy);

    RegConsoleCmd("dont_kill_me", dont_kill_me, "Player is harder to kill, missing head, chest, stomach hitgroups");
    
    for(int i = 1; i <= MaxClients; i++)
        if(IsClientInGame(i)) OnClientPutInServer(i);
}

public void round_start(Event event, const char[] name, bool dontBroadcast)
{
    for(int x = 1 ; x <= MaxClients; x++) player[x].enabled = false;
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_TraceAttack, TraceAttack);
}

public Action dont_kill_me(int client, int args)
{
    if(!client || !IsClientInGame(client)) return Plugin_Handled;

    player[client].ToggleDontKillMe();
    
    return Plugin_Handled;
}



public Action TraceAttack(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &ammotype, int hitbox, int hitgroup)
{
    if(!player[victim].IsDontKillMe()) return Plugin_Continue;

    switch(hitgroup)
    {
        case HITGROUP_HEAD, HITGROUP_CHEST, HITGROUP_STOMACH:
        {
            return Plugin_Handled;
        }
    }
    
    //PrintToServer("%N dont_kill_me hitbox %i, hitgroup %i", victim, hitbox, hitgroup);    
    return Plugin_Continue;
}