[Bugsy]

Originally Posted by instinctpt1 @Bugsy can i ask you, why arent you checking this on DeathMsg event and get players count accordingly instead of adding a task to be executed every second ? And why not use get_playersnum_ex ( http://www.amxmodx.org/api/amxmisc/get_playersnum_ex ) ?

1. I was doing that, but he then decided he wants the slay to only occur after X seconds have passed in a round. If I only check on death and the round seconds have not yet reached the desired seconds, the slay needs to be delayed until the seconds are reached. Using a task allows for this.

2. Because I code with the assumption not everyone is using 1.9.

[instinctpt1]

But why not adding the deathevent check and check for delay in it?
I mean suppose last of remaining players other than the alive one from CT died, we should only then check for how many seconds have passed, if they are less than delay time, then set a task to check again just after delay time, if he is still alive then slay !
.
.
Or i interpreted it wrong ?

[Bugsy]

Suppose slay should only occur if 90 or more seconds have passed in the round.
Suppose all other conditions for HUD/slay are met at 5 seconds into the round.

I now need to trigger the HUD/slay in 85 seconds.

Options are:
- Begin the HUD/slay using a set_task() with an 85 second interval
- Keep checking conditions every 1 second and start HUD when all conditions are met.

Either way does the same thing, and I am doing the latter. There are obviously many ways to handle this.

[Bugsy]

Here's what I think you are suggesting:

Spoiler

PHP Code:


#include <amxmodx>

new const Version[] = "0.5";

new g_pSlayNoBots , g_pSlayWithBots , g_pSlayDelay , g_pPluginStartDelay;
new g_Bots , g_iSeconds , g_iSlayID;
new g_szName[ 33 ] , g_shHUD , g_iRoundStartTime;

public plugin_init() 
{
    register_plugin( "Slay CT" , Version , "bugsy" );

    register_event( "HLTV" , "NewRound" , "a" , "1=0" , "2=0" );
    register_event( "DeathMsg" , "DeathMsg" , "a" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );
    
    g_pSlayNoBots = register_cvar( "sct_nobotslay" , "3" );
    g_pSlayWithBots = register_cvar( "sct_botslay" , "5" );
    g_pSlayDelay = register_cvar( "sct_slaydelay" , "5" );
    g_pPluginStartDelay = register_cvar( "sct_rounddelayseconds" , "30" );
    
    g_shHUD = CreateHudSyncObj();
}

public client_putinserver( id )
{
    g_Bots |= ( is_user_bot( id ) << ( id & 31 ) );
}

public client_disconnect( id )
{
    g_Bots &= ~( 1 << ( id & 31 ) );
    
    if ( id == g_iSlayID )
        remove_task( g_iSlayID );
}

public NewRound()
{
    g_iRoundStartTime = get_systime();
}

public RoundEnd()
{
    remove_task( g_iSlayID );
}

public DeathMsg()
{
    new iPlayers[ 32 ] , iNum , iStartDelay , iSysTime;
    
    if ( !g_iSlayID && ( get_playersnum() > get_pcvar_num( g_Bots ? g_pSlayWithBots : g_pSlayNoBots ) ) )
    {
        iStartDelay = get_pcvar_num( g_pPluginStartDelay );
        iSysTime = get_systime();
        
        get_players( iPlayers , iNum , "ae" , "CT" );
        if ( iNum == 1 )
        {
            if ( ( iSysTime - g_iRoundStartTime ) >= iStartDelay )
            {
                set_task( 1.0 , "DisplayHUD" , ( g_iSlayID = iPlayers[ 0 ] ) , .flags="a" , .repeat=( g_iSeconds = get_pcvar_num( g_pSlayDelay ) + 1 ) );
            }
            else
            {
                set_task( float( iStartDelay - ( iSysTime - g_iRoundStartTime ) ) , "StartHUD" , ( g_iSlayID = iPlayers[ 0 ] ) );
            }
        }
    }
}

public StartHUD( id )
{
    set_task( 1.0 , "DisplayHUD" , id , .flags="a" , .repeat=( g_iSeconds = get_pcvar_num( g_pSlayDelay ) + 1 ) );
}

public DisplayHUD( id )
{
    if ( g_szName[ 0 ] == EOS )
        get_user_name( id , g_szName , charsmax( g_szName ) );
    
    if ( --g_iSeconds >= 1 ) 
    {
        set_hudmessage( 0 , 170 , 255 , -1.0 , 0.40 , 0 , 0.0 , 1.0 , 0.0 , 0.0 , -1 );
        ShowSyncHudMsg( 0 , g_shHUD , "%s will be slayed in %d second%s!" , g_szName , g_iSeconds , g_iSeconds > 1 ? "s" : "" );
    }
    else
    {
        user_kill( id );
        g_iSlayID = 0;
        g_szName[ 0 ] = EOS;
    }
} 


[instinctpt1]

Exactly !

[Stefanos]

will be tested in 1 hour.

[Stefanos]

can you give me latest code, i got confused

[Bugsy]

https://forums.alliedmods.net/showpo...1&postcount=49

[Stefanos]

before i upload that. My player reported me a new bug, he was last, countdown was up, he died before countdown, when new round started, he got slayed.

[Bugsy]

Not sure, I don't think it's possible since the code shows HUD OR kills. Are you running anything else that would slay a player?

PHP Code:

    if ( --g_iSeconds >= 1 ) 
    {
        set_hudmessage( 0 , 170 , 255 , -1.0 , 0.40 , 0 , 0.0 , 1.0 , 0.0 , 0.0 , -1 );
        ShowSyncHudMsg( 0 , g_shHUD , "%s will be slayed in %d second%s!" , g_szName , g_iSeconds , g_iSeconds > 1 ? "s" : "" );
    }
    else
    {
        user_kill( id );
        g_iSlayID = 0;
        g_szName[ 0 ] = EOS;
    }