[micazoid]

Hiho everybody,

simple question but google cant give me an answer:

I can Target at one Team only via @t or @ct in Counterstrike.

How can I target at Axis or Allies in Day of Defeat Source?

Thanks for ur replies.

[Seta00]

Well Axis are clearly the terrorists.

[sinblaster]

Originally Posted by Seta00 Well Axis are clearly the terrorists.

That all depends on what angle your shooting them at.

[Bacardi]

• 1 How to Target

Found only in Cs:s (@t @ct) and TF2 (@red @blue)

Rest is @all @alive @dead @humans @bots...

*edit
@aim

[micazoid]

Well, then there is no @axis @allies......

I read how to target. This was why the question came up in my mind.

[Seta00]

File a bug report.

[psychonic]

Requires SM 1.4-hg2996 or later

#include <sourcemod>

#define ALLIES 2
#define AXIS 3
 
 public OnPluginStart()
 {
    AddMultiTargetFilter("@allies", FilterAllies, "Allies", false)
    AddMultiTargetFilter("@axis", FilterAxis, "Axis", false)
 }
 
 public bool:FilterAllies(const String:pattern[], Handle:clients)
 {
    for (new i = 1; i <= MaxClients; i++) {
       if (IsClientInGame(i) && GetClientTeam(i) == ALLIES)
          PushArrayCell(clients, i)
    }
 
    return true
 }
 
  public bool:FilterAxis(const String:pattern[], Handle:clients)
 {
    for (new i = 1; i <= MaxClients; i++) {
       if (IsClientInGame(i) && GetClientTeam(i) == AXIS)
          PushArrayCell(clients, i)
    }
 
    return true
 }

[Bacardi]

That was fast like thunderbolt

[micazoid]

O.O

Psychonic thats cool. Thank you very much. I just have to compile it.
You should release this. I think I am not the only one with this question.

Thanks Thanks Thanks Thanks Thanks Thanks

[alpetras]

this one's for HL2MP/HL2DM
thanks psychonic for the help

#include <sourcemod>

#define COMBINE 2
#define REBELS 3
 
public OnPluginStart()
{
    AddMultiTargetFilter("@combine", FilterCombine, "Combine", false)
    AddMultiTargetFilter("@blue", FilterCombine, "Combine", false)
    AddMultiTargetFilter("@rebels", FilterRebels, "Rebels", false)
    AddMultiTargetFilter("@red", FilterRebels, "Rebels", false)
}
 
public bool:FilterCombine(const String:pattern[], Handle:clients)
{
    for (new i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && GetClientTeam(i) == COMBINE)
            PushArrayCell(clients, i)
    }
    
    return true
}
 
public bool:FilterRebels(const String:pattern[], Handle:clients)
{
    for (new i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && GetClientTeam(i) == REBELS)
            PushArrayCell(clients, i)
    }
    
    return true
}