[Trayz]

Hello , i have an HideNSeek Server , and i need a plugin to block damage from ct´s doing understabs on terrorists.

I tried porting this (plugin) and my solution failed here´s my attempt.

If someone can help me i will apreciate.

[eyal282]

Originally Posted by Trayz Hello , i have an HideNSeek Server , and i need a plugin to block damage from ct´s doing understabs on terrorists. I tried porting this (plugin) and my solution failed here´s my attempt. If someone can help me i will apreciate.

Try getting their origins. Origin[2] is Z, also known as the height origin. If the CT's origin at the moment of the stab ( hook SDKHook_OnTakeDamage ) is lower than the terror's by X value ( be careful because if a CT crouches it reduces his origin so make it 75 or something ( Unsure ) he's definitely understabbing.

[Trayz]

Can you show me an example because i dont know how to check that

[eyal282]

Originally Posted by Trayz Can you show me an example because i dont know how to check that

new Float:Origin[3];
GetEntPropVector(client, Prop_Data, "m_vecOrigin", Origin);

Then tell me the following: if the height of the stabber is lower than the stabbed by say 75, it should be guaranteed to be an understab right? If you think yes, go ahead and test it. Then basically check

if(Origin[attacker] < Origin[victim] - 75)
{
// No damage? I think you wanted that.
}


ONE IMPORTANT THING!!!

You need this code to block out damage:

damage = 0.0;
return Plugin_Changed;

[Trayz]

Thank you @eyal282
If someone want the plugin code (this comes with HUD text for CS:GO)

PHP Code:

#include <sourcemod> 
#include <sdktools> 
#include <sdkhooks> 
#include <cstrike>

public void OnPluginStart() 
{
    for (int client = 1; client <= MaxClients; client++)
        if (IsValidClient(client))
            SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype) 
{
    if(IsValidClient(victim) && IsValidClient(attacker) && IsPlayerAlive(victim) && IsPlayerAlive(attacker))
    {
        if(victim == attacker)
            return Plugin_Continue;
        
        float iAPos[3], iVPos[3]; 
        char weapon_attacker[30];
        GetEntPropVector(victim, Prop_Data, "m_vecOrigin", iVPos);
        GetEntPropVector(attacker, Prop_Data, "m_vecOrigin", iAPos);
        GetClientWeapon(attacker, weapon_attacker, sizeof(weapon_attacker)); 
        
        if(GetClientTeam(victim) != CS_TEAM_T)
            return Plugin_Continue;
        
        if(!StrEqual("weapon_knife",weapon_attacker,true))
            return Plugin_Continue;

        if(iAPos[2] < iVPos[2] - 75)
        {
            char message[30];
            Format(message,sizeof(message),"Understab Blocked");
            SetHudTextParams(-1.0, 0.125, 2.0, 255, 255, 255, 255, 0, 0.25, 0.1, 0.2);
            ShowHudText(victim, -1, message);
            ShowHudText(attacker, -1, message);
            damage = 0.0;
            return Plugin_Changed;
        }
    }
    return Plugin_Continue;
}

stock bool IsValidClient(int client)
{
    if(client >= 1 && client <= MaxClients && IsClientConnected(client) && IsClientInGame(client))
    {
        return true;
    }
    
    return false;
} 


[eyal282]

Originally Posted by Trayz Thank you @eyal282 If someone want the plugin code (this comes with HUD text for CS:GO) PHP Code: #include <sourcemod>  #include <sdktools>  #include <sdkhooks>  #include <cstrike> public void OnPluginStart()  {     for (int client = 1; client <= MaxClients; client++)         if (IsValidClient(client))             SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); } public void OnClientPutInServer(int client) {     SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); } public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)  {     if(IsValidClient(victim) && IsValidClient(attacker) && IsPlayerAlive(victim) && IsPlayerAlive(attacker))     {         if(victim == attacker)             return Plugin_Continue;                  float iAPos[3], iVPos[3];          char weapon_attacker[30];         GetEntPropVector(victim, Prop_Data, "m_vecOrigin", iVPos);         GetEntPropVector(attacker, Prop_Data, "m_vecOrigin", iAPos);         GetClientWeapon(attacker, weapon_attacker, sizeof(weapon_attacker));                   if(GetClientTeam(victim) != CS_TEAM_T)             return Plugin_Continue;                  if(!StrEqual("weapon_knife",weapon_attacker,true))             return Plugin_Continue;         if(iAPos[2] < iVPos[2] - 75)         {             char message[30];             Format(message,sizeof(message),"Understab Blocked");             SetHudTextParams(-1.0, 0.125, 2.0, 255, 255, 255, 255, 0, 0.25, 0.1, 0.2);             ShowHudText(victim, -1, message);             ShowHudText(attacker, -1, message);             damage = 0.0;             return Plugin_Changed;         }     }     return Plugin_Continue; } stock bool IsValidClient(int client) {     if(client >= 1 && client <= MaxClients && IsClientConnected(client) && IsClientInGame(client))     {         return true;     }          return false; }

That's great .

Don't forget to mark as solved.

[Neuro Toxin]

Rather than checking for the knife class in a string, why not check for damagetype DMG_SLASH?

[eyal282]

Originally Posted by Neuro Toxin Rather than checking for the knife class in a string, why not check for damagetype DMG_SLASH?

Might be edited theoretically by another plugin into DMG_ACID or something ( I did that before )