[EasySoft]

How can I create only one time timer?

So I want to write CreateTimer(sdfsdf, sdfdsfsdf)

And this function should be executed only once not on every x seconds.

[retsam]

CreateTimer(1.0, SomethingHere);

or for client

CreateTimer(1.0, SomethingHere, client);


Goes to >>>>

public Action:SomethingHere(Handle:timer) or public Action:SomethingHere(Handle:timer, any:client)

[EasySoft]

Originally Posted by retsam CreateTimer(1.0, SomethingHere); or for client CreateTimer(1.0, SomethingHere, client);

Yes I've tried that but this timer is repeating on every 1 second.
I need something like Sleep in C;

[retsam]

Impossible. That timer does not repeat. You must be doing something wrong.

You must have it under some event or something in the game thats making it run multiple times.

[EasySoft]

Originally Posted by retsam Impossible. That timer does not repeat. You must be doing something wrong. You must have it under some event or something in the game thats making it run multiple times.

Hmmm thank you I'll check that.

Look

on every spawn I give timer for every client.

But the next spawn I want the old timers to bi destroyed.

They all stay in memory?

[=MaTi=]

They do. Just kill them at the end of each round.

EDIT: If player can respawn before the end of the round, you should also kill the timer when he dies.

[bl4nk]

Here's a simple plugin that will send a message 60 seconds after a player spawns. If the player respawns, the old timer will be stopped and a new timer will be started.

PHP Code:

#pragma semicolon 1

#include <sourcemod>

new Handle:g_hSpawnTimers[MAXPLAYERS+1] = {INVALID_HANDLE};

public OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn);
}

public OnClientDisconnect(client)
{
    if (g_hSpawnTimers[client] != INVALID_HANDLE)
    {
        KillTimer(g_hSpawnTimers[client]);
        g_hSpawnTimers[client] = INVALID_HANDLE;
    }
}

public Event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    if (client > 0 && g_hSpawnTimers[client] != INVALID_HANDLE)
    {
        KillTimer(g_hSpawnTimers[client]);
        g_hSpawnTimers[client] = INVALID_HANDLE;
    }

    g_hSpawnTimers[client] = CreateTimer(60.0, Timer_Callback, GetClientUserId(client));
}

public Action:Timer_Callback(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0)
    {
        PrintToChatAll("Player \"%N\" spawned 60 seconds ago!", client);
        g_hSpawnTimers[client] = INVALID_HANDLE;
    }

    return Plugin_Continue;
} 


I hope this is a good enough example to give you an idea of where to start.

[EasySoft]

Ok thank you great example.