[Shadows Adi]

Hello,
I have this code and should give a point stored in a vault if it is headshot. More details down:

PHP Code:

new wpn, clip, ammo
        wpn = get_user_weapon(iAttacker, clip, ammo)
        if(iAttacker != iVictim && wpn == CSW_KNIFE )
        {
            if(g_iIsHeadshot)
            {
                pdData[iAttacker][Kills] += 1
                pdData[iAttacker][Headshot] += 1
            }
            else
            {
                pdData[iAttacker][Kills] += 1
            }
        } 


The problem is it count the kills, deaths, damage, but not the headshots.
See this picture:
Click for ScreenShot

[thEsp]

As for CS, read 3rd byte of DeathMsg event.

[Bugsy]

Would need to see more code.. e.g. where is the code you posted executed?

[Shadows Adi]

This is registered event:

PHP Code:

RegisterHam(Ham_Killed, "player", "fw_PlayerKilled", 1) 


And this is the public of the function:

PHP Code:

public fw_PlayerKilled(iVictim, iAttacker, shouldgib)
{
    if( iVictim == iAttacker || !is_user_connected(iAttacker) || !is_user_connected(iVictim) )
        return HAM_IGNORED

    if(is_user_connected(iAttacker) && is_user_alive(iAttacker))
    {
        new g_iIsHeadshot = read_data(3);
        new szName[33]
        get_user_name(iVictim, szName, charsmax(szName))
        new aName[32]
        get_user_name(iAttacker, aName, charsmax(aName))
        
        new wpn, clip, ammo
        wpn = get_user_weapon(iAttacker, clip, ammo)
        if(iAttacker != iVictim && wpn == CSW_KNIFE )
        {
            if(g_iIsHeadshot)
            {
                pdData[iAttacker][Kills] += 1
                pdData[iAttacker][Headshot] += 1
            }
            else
            {
                pdData[iAttacker][Kills] += 1
            }
        }
        if(!is_user_alive(iVictim) && iVictim != iAttacker && wpn == CSW_KNIFE )
        {
            pdData[iVictim][Deaths]  += 1
        }
        return HAM_HANDLED
    }
    return PLUGIN_HANDLED
} 


[thEsp]

Adi, you're doing it wrong. You don't have to read arguments from Handsandwich forwards with read_x() functions. There are none passed in that way, however they are directly passed. Check this link for more details: http://amxmodx.org/api/ham_const. In your case, you should register "DeathMsg" (that's probably the last resort).

Here's a little example: http://amxxmodx.ru/core/amxmodxinc/7...h-sobytiy.html.

[Bugsy]

Use DeathMsg. I started out making comments on your code but it got messy since there are a ton of things wrong. I removed things that were not needed, including getting the player names.

PHP Code:

register_event( "DeathMsg" , "DeathMsg" , "a" , "4=knife" , "1>0" );

public DeathMsg()
{
    new iKiller = read_data( 1 );
    new iVictim = read_data( 2 );

    pdData[iVictim][Deaths]++;
    pdData[iKiller][Kills]++;
    pdData[iKiller][Headshot] += read_data( 3 );
} 


[+ARUKARI-]

If you are using Fakemeta
You may be able to use this.

PHP Code:

new isHeadShot = (get_pdata_int(iVictim, 75) == HIT_HEAD); 


[Bugsy]

Yeah, that will work, I've used it my aimbot detection plugin but forgot about it. But still, I don't see a reason to not use DeathMsg, which provides the advantage of having condition filters and it's easy to get weapon name/headshot.

PHP Code:

const m_LastHitGroup = 75;
#define XO_PLAYER 5

if ( get_pdata_int( iVictim , m_LastHitGroup , XO_PLAYER ) == HIT_HEAD )
{

} 


[Shadows Adi]

Solved, thank you all for your help. I've been used @Bugsy's way.