[Devil259]

donc cs_set_user_money(index,money-amount) suffirait

c'est bien ce qui me semblait.. pourtant ce stock revient dans plusieurs thread.. :/

[ConnorMcLeod]

Pas parce que tu trouves souvent le même bout de code qu'il ne faut pas être critique envers ce code.

Tu peux aussi utiliser :

PHP Code:

AddUserMoney(id, iMoney, bool:bFlash=true)
{
    cs_set_user_money(id, cs_get_user_money(id)+iMoney, bFlash)
} 


Suffit de passer une valeur négative pour enlever de l'argent.

Si c'est dans la cadre d'un achat, un stock plus évolué est nécessaire pour savoir si oui ou non le joueur a l'argent disponible.
Ce stock serait plutôt pour donner un bonus (comme quand on tue un adversaire) ou du malus (comme quand on TK).

[Devil259]

#include < amxmodx >

public plugin_init( )
{
    register_clcmd( "say" , "hookSay" )
}

public hookSay( id )
{
    new szArg[ 1024 ] , szInversed[ 1024 ]
    read_args( szArg , charsmax( szArg ) )
    remove_quotes( szArg )
    
    new iLen = strlen( szArg )
    
    for( new i = 0; i <= iLen; i++ )
    {
        szInversed[ i ] = szArg[ iLen-i ]
    }
    
    client_print( id , print_chat , "1 : %s" , szArg )
    client_print( id , print_chat , "2 : %s" , szInversed )
}

J'ai ce code, fait à l'arrache.

szInversed est censé marquer la phrase de szArg à l'envers, mais ça n'affiche rien. Quel est le problème ?

[Kidev]

PHP Code:

i <= iLen 


lol
Tu vois rien de bizarre la?

Essaye plutôt

PHP Code:

for( new i = iLen; i > 0; i-- ) 


Si tu veux juste l'afficher y'a besoin que de ça, en utilisant szArg[ i ] (il va la lire à l'envers). Si tu veux la sauvegarder faut faire une deuxième boucle imbriquée ou créer une variable et l'incrémenter dans cette boucle, comme tu le sens ;)

[ConnorMcLeod]

Il serait temps d'abandonner ce thread rempli de tout et n'importe quoi.
Le fait de tout mettre dans ce thread n'est bénéfique qu'à toi.
1 problème, 1 sujet, c'est plus clair, ça remonte mieux quand un autre membre fait une recherche, etc...

Devil ton problème est que szInversed[0] se met sur 0 ou EOS, ce qui indique la fin d'une string, donc la print s'arrête sur cette cellule. Tu dois retrancher 1 au réulstat de strlen( szArg ) affecté à iLen, comme je le fais dans l'exemple ci-dessous.

Kid je ne vois pas l'intérêt de commencer par le haut plutôt que par le bas. T'as pas saisi la logique là, peut importe le sens dans lequel on lit vu qu'on prend ensuite l'opposé comme valeur.
Ceci dit le 1er truc que tu as pointé est exact, c'est
for( new i = 0; i < iLen; i++ )
et pas
for( new i = 0; i <= iLen; i++ ) // Sauf qu'avec le fix -1 sur strlen il faut désormais laisser <=


Essaye ça :

PHP Code:

#include <amxmodx>

#define VERSION "0.0.1"
#define PLUGIN "Inverted Chat Lol"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_clcmd("say", "HostSay")
    register_clcmd("say_team", "HostSay")
}

public HostSay( id )
{
    new szSaid[192], szLol[192], iLen
    read_args(szSaid, charsmax(szSaid))
    remove_quotes(szSaid)
    iLen = strlen(szSaid) - 1
    for(new i ; i<=iLen; i++ )
    {
        szLol[i] = szSaid[iLen-i]
    }

    new szCmd[9]
    read_argv(0, szCmd, charsmax(szCmd))
    engclient_cmd(id, szCmd, szLol)
    return PLUGIN_HANDLED_MAIN
} 


Si tu veux une fonction pour inverser n'importe quelle string, mais sans garder en mémoire celle d'origine, utilise ça : http://forums.alliedmods.net/showpos...04&postcount=2