[Spazman0]

I have just started SourcePawn, and I am hoping to write sourcemod plugins for my friend. However, as I do not have access to the server, I have no way to test my plugins before he loads them onto his server. I just thought I would warn you of that first.

I am trying to write a plugin that teleports a client to the place where the admin is looking. From the slap example found on the wiki and another teleport example that teleports to a saved spot, I've botched together what I hope should find a player and teleport them. However, I am not sure about how to go about where to teleport them to. Here is my botched together code:

#include <sourcemod>
#include <sdktools>

public OnPluginStart()
{
    RegAdminCmd("sm_tele", Command_tele, ADMFLAG_SLAY)
}


public Action:Command_tele(client, args)
{
    new String:arg1[32], String:arg2[32]
    GetCmdArg(1, arg1, sizeof(arg1))
    
    new target = FindTarget(client, arg1)
    if(target == -1)
    {
        return Plugin_Handled;
    }
    
    TeleportEntity(target, NULL_VECTOR, /*Angle of admin''s view*/, /*distance from admin?*/)
    
    new String:name[MAX_NAME_LENGTH]
    
    GetClientName(target, name, sizeof(name))
    
    ShowActivity2(client, "%s was Teleported!", name)
    LogAction(client, target, "\"%L\" teleported \"%L\" ", client, target)
    
    ReplyToCommand(client, "You Teleported %s.", name)
    
    return Plugin_Handled;
    
}

I am assuming that I will need some new variables to store the direction and distance of the admin's view, and I'm also assuming that these will need to be put into the TeleportEntity command.

I would like some help in figuring out what else I need to do to make this work. Also, if any of the code I have written could be improved, I'm all ears.

[Nican]

PHP Code:

new Float:vAngles[3], Float:vOrigin[3], Float:pos[3];
    
GetClientEyePosition(client,vOrigin);
GetClientEyeAngles(client, vAngles);
    
new Handle:trace = TR_TraceRayFilterEx(vOrigin, vAngles, MASK_SHOT, RayType_Infinite, TraceEntityFilterPlayer);
    
if(TR_DidHit(trace)){
    TR_GetEndPosition(pos, trace);
    
    pos[2] += 10.0; // make sure he does not get stuck to the floor, increse Z pos
    
    TeleportEntity( target, pos, NULL_VECTOR, NULL_VECTOR ); //Teleport target player on hitpos

}
CloseHandle(trace);
    
    
    
    
//Put this somewhere else on the code
public bool:TraceEntityFilterPlayer(entity, contentsMask){
     return entity > maxplayers || entity == 0;
} 


I guess you are looking for that...

[Greyscale]

public bool:TraceEntityFilterPlayer(entity, contentsMask){
     return entity > maxplayers;
} 

What if they are aiming at the world? (entity 0) that will return 0 and end the traceray

Shouldn't it be:

public bool:TraceEntityFilterPlayer(entity, contentsMask){
     return entity > maxplayers || !entity;
} 

[Nican]

Good point. but it seems it always has been working correctly with spray trace.

I am guessing it does not filter world...

Let me add a exception just in case...

[Spazman0]

Thanks Nican. I have put the code in like this, and it seems to compile all-right. However, as I can not test it, I have no idea whether or not it will work. I know from experience that just because something compiles does not mean its gonna work. So, can you tell me if you think this should work?

PHP Code:

#include <sourcemod>
#include <sdktools>

public OnPluginStart()
{
    RegAdminCmd("sm_tele", Command_tele, ADMFLAG_SLAY)
    
}

public bool:TraceEntityFilterPlayer(entity, contentsMask)
    {
        return entity > GetMaxClients() || !entity;
    } 

public Action:Command_tele(client, args)
{
    new Float:vAngles[3], Float:vOrigin[3], Float:pos[3];
    
    GetClientEyePosition(client,vOrigin);
    GetClientEyeAngles(client, vAngles);
    
    new String:arg1[32]
    GetCmdArg(1, arg1, sizeof(arg1))
    
    new target = FindTarget(client, arg1)
    if(target == -1)
    {
        return Plugin_Handled;
    }
    
    
    new Handle:trace = TR_TraceRayFilterEx(vOrigin, vAngles, MASK_SHOT, RayType_Infinite, TraceEntityFilterPlayer);
    
    if(TR_DidHit(trace))
    {
        TR_GetEndPosition(pos, trace);
    
        pos[2] += 10.0; 
    
        TeleportEntity( target, pos, NULL_VECTOR, NULL_VECTOR ); 

    }
    CloseHandle(trace);
    
    
     
    new String:name[MAX_NAME_LENGTH]
    
    GetClientName(target, name, sizeof(name))
    
    ShowActivity2(client, "%s was Teleported!", name)
    LogAction(client, target, "\"%L\" teleported \"%L\" ", client, target)
    
    ReplyToCommand(client, "You Teleported %s.", name)
    
    return Plugin_Handled;
    
} 


[Nican]

Originally Posted by Greyscale Shouldn't it be: public bool:TraceEntityFilterPlayer(entity, contentsMask){ return entity > maxplayers || !entity; }

Hm, both works, but I don't know with is better.

"!var" is suppose to be used on boolean values, since 0 is false, it would return true...

--------

Spazman0
This seems wrong:

PHP Code:

LogAction(client, target, "\"%L\" teleported \"%L\" ", client, target) 


client and target are not "%L" values, I think you meant to use "%N"
Read http://wiki.alliedmods.net/Format_Cl...Mod_Scripting) for more information

[Spazman0]

Ok, thanks Nican. I am currently in the process of downloading SCRDS to test my plugins.

EDIT:

I have tested the plugin and it is fully working. I am now going to submit it to unapproved plugins for anyone else who wants to use it.

[DiscoBBQ]

http://forums.alliedmods.net/showthread.php?t=69851

[bl4nk]

Originally Posted by Nican client and target are not "%L" values, I think you meant to use "%N" Read http://wiki.alliedmods.net/Format_Class_Functions_(SourceMod_Scripting) for more information

Sure they are. That link you linked proves it. Each just prints different information.

[Nican]

Oh shi... I confused %L with %T

I am going crazy...