How to use native for this ?

grs4 · **Author**

I want to return a value from one plugin which is using enums, when i'm using this native in other plugin, it returns badly values. Can you help me ?

PHP Code:


			
enum e_PlayerInfo {
    PLAYER_NICK[33],
    PLAYER_LEVEL,
    PLAYER_EXP,
    PLAYER_COINS,
    PLAYER_POINTS,
    PLAYER_ULTRA_POINTS,
    PLAYER_MEGA_POINTS,
    PLAYER_HEALTH,
    PLAYER_SPEED,
    PLAYER_GRAVITY,
    PLAYER_MONEY,
    PLAYER_DAMAGE,
    PLAYER_LONG_JUMP,
    Float:PLAYER_LONG_JUMP_TIME,
    PLAYER_JUMPS,
    PLAYER_INVISIBLE,
    PLAYER_LIGHTING,
    Float:PLAYER_LIGHTING_TIME,
    PLAYER_STRENGHT,
    PLAYER_RESPAWN,
    PLAYER_CRITICAL,
    PLAYER_FAST_STATS,
    bool:PLAYER_VIP,
    PLAYER_TARGET
}

new any:g_PlayerInfo[ MAX_PLAYER+1 ][ e_PlayerInfo ]

....
register_native("exp_get_user_info", "_get_user_info", 1);
...
public any:_get_user_info(index, e_PlayerInfo:iInfo) {
    if(is_user_connected(index))
        return g_PlayerInfo[index][iInfo]
    return 0
}

.inc file:

PHP Code:


			
enum e_PlayerInfo {
    NOTHING_0,
    PLAYER_LEVEL,
    PLAYER_EXP,
    PLAYER_COINS,
    PLAYER_POINTS,
    PLAYER_ULTRA_POINTS,
    PLAYER_MEGA_POINTS,
    PLAYER_HEALTH,
    PLAYER_SPEED,
    PLAYER_GRAVITY,
    PLAYER_MONEY,
    PLAYER_DAMAGE,
    PLAYER_LONG_JUMP,
    NOTHING_1,
    PLAYER_JUMPS,
    PLAYER_INVISIBLE,
    PLAYER_LIGHTING,
    NOTHING_2,
    PLAYER_STRENGHT,
    PLAYER_RESPAWN,
    PLAYER_CRITICAL,
    PLAYER_FAST_STATS
}

native any:exp_get_user_info(index, e_PlayerInfo:iInfoType)

and the plugin

PHP Code:


			
/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <expmod>

#define PLUGIN "Plugin"
#define VERSION "1.0"
#define AUTHOR "GT Team"


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /test", "test")
}

public test(id) {
    for(new i = 1; i < _:e_PlayerInfo; i++)  {
        client_print(id, 3, "%d : %d", i, exp_get_user_info(id, e_PlayerInfo:i))
    }
}

and it returns random values:

PHP Code:


			
1 : 84
2 : 82
3 : 73
4 : 75
5 : 69
6 : 82
7 : 45
8 : 45
9 : 77
10 : 99
11 : 80
12 : 114
13 : 48
14 : 32
15 : 58
16 : 68
17 : 0
Welcome to Counter-Strike
18 : 0

Its definitly stupid. . Do i something wrong ?

.Dare Devil. · 02-05-2015 , 07:57 Re: How to use native for this ?

1. pawn cannot return array ( unless there is pointer system i haven't heard about it )
as long as i know it can only return a cell what is 4 bytes ( can be int, can be float or any other what is 4byte )

My solution would be 2 natives.
One for floats or/and ints and the other one strings or/and arrays.

grs4 · 02-05-2015 , 13:31 Re: How to use native for this ?

thanks for answer. If you can see, i speccialy do in .inc values: NOTHING_0, NOTHING_1. because i dont want that end-user would get values in string or float. It doesnt matter i think. Thanks for answer btw.

I'm waiting for other solutions ;) (sr 4 english)

**Bugsy** · *Last edited by Bugsy; 02-05-2015 at 23:39.*

The data is not random STRIKER--McPr0

. This is doable, see below.

You will need to use the function according to the type of data you are trying to retrieve. Floats and strings are by-reference, while integers can be returned directly by the function.

Integer : exp_get_user_info( id , Item )
Float : exp_get_user_info( id , Item , FloatVariable )
String : exp_get_user_info( id , Item , StringVariable[] , MaxChars )

Output:

Code:

Integer value: 1234
Float value: 56.789001
String value: bugsy

nativetest.inc

PHP Code:


			
enum e_PlayerInfo 
{
    PLAYER_NICK[33],
    PLAYER_LEVEL,
    PLAYER_EXP,
    PLAYER_COINS,
    PLAYER_POINTS,
    PLAYER_ULTRA_POINTS,
    PLAYER_MEGA_POINTS,
    PLAYER_HEALTH,
    PLAYER_SPEED,
    PLAYER_GRAVITY,
    PLAYER_MONEY,
    PLAYER_DAMAGE,
    PLAYER_LONG_JUMP,
    Float:PLAYER_LONG_JUMP_TIME,
    PLAYER_JUMPS,
    PLAYER_INVISIBLE,
    PLAYER_LIGHTING,
    Float:PLAYER_LIGHTING_TIME,
    PLAYER_STRENGHT,
    PLAYER_RESPAWN,
    PLAYER_CRITICAL,
    PLAYER_FAST_STATS,
    bool:PLAYER_VIP,
    PLAYER_TARGET
}

native exp_get_user_info( id , e_PlayerInfo:iInfoType , {Float,_}:... );

Other plugin:

PHP Code:


			
#include <amxmodx>

enum e_PlayerInfo {
    PLAYER_NICK[33],
    PLAYER_LEVEL,
    PLAYER_EXP,
    PLAYER_COINS,
    PLAYER_POINTS,
    PLAYER_ULTRA_POINTS,
    PLAYER_MEGA_POINTS,
    PLAYER_HEALTH,
    PLAYER_SPEED,
    PLAYER_GRAVITY,
    PLAYER_MONEY,
    PLAYER_DAMAGE,
    PLAYER_LONG_JUMP,
    Float:PLAYER_LONG_JUMP_TIME,
    PLAYER_JUMPS,
    PLAYER_INVISIBLE,
    PLAYER_LIGHTING,
    Float:PLAYER_LIGHTING_TIME,
    PLAYER_STRENGHT,
    PLAYER_RESPAWN,
    PLAYER_CRITICAL,
    PLAYER_FAST_STATS,
    bool:PLAYER_VIP,
    PLAYER_TARGET
}

const MAX_PLAYER = 32;

new any:g_PlayerInfo[ MAX_PLAYER+1 ][ e_PlayerInfo ];

public plugin_natives()
{
    register_native( "exp_get_user_info" , "_get_user_info" );
}

public plugin_init() 
{
    //Set test data to array
    new id = 0;
    
    copy( g_PlayerInfo[ id ][ PLAYER_NICK ] , charsmax( g_PlayerInfo[][ PLAYER_NICK ] ) , "bugsy" );
    g_PlayerInfo[ id ][ PLAYER_LEVEL ] = 1234;
    g_PlayerInfo[ id ][ PLAYER_LONG_JUMP_TIME ] = 56.789;
}

public _get_user_info( iPlugins , iParams )
{
    new iPlayerID = get_param( 1 );
    new iItem = get_param( 2 );
    
    switch ( iParams )
    {
        case 2: return g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ];
        case 3: set_float_byref( 3 , g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ] );
        case 4: set_string( 3 , g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ] , get_param( 4 ) );
    }
    
    return 0;
}

Your plugin:

PHP Code:


			
#include <amxmodx>
#include <nativetest>

new const VERSION[] = "0.1";

public plugin_init() 
{
    register_plugin( "Native test" , VERSION , "bugsy" );
    
    register_concmd( "test" , "test" );
}

public test() 
{    
    new id = 0;
    
    server_print( "Integer value: %d" , exp_get_user_info( id , PLAYER_LEVEL ) );
    
    new Float:fTest;
    exp_get_user_info( id , PLAYER_LONG_JUMP_TIME , fTest );
    server_print( "Float value: %f" , fTest );

    new szNick[ 33 ];
    exp_get_user_info( id , PLAYER_NICK , szNick , charsmax( szNick ) );
    server_print( "String value: %s" , szNick );
}

.Dare Devil. · 02-06-2015 , 07:58 Re: How to use native for this ?

Quote:

Originally Posted by Bugsy

The data is not random STRIKER--McPr0

. This is doable, see below.

You will need to use the function according to the type of data you are trying to retrieve. Floats and strings are by-reference, while integers can be returned directly by the function.

Integer : exp_get_user_info( id , Item )
Float : exp_get_user_info( id , Item , FloatVariable )
String : exp_get_user_info( id , Item , StringVariable[] , MaxChars )

Output:

Code:

Integer value: 1234
Float value: 56.789001
String value: bugsy

nativetest.inc

PHP Code:


			
enum e_PlayerInfo 

{

    PLAYER_NICK[33],

    PLAYER_LEVEL,

    PLAYER_EXP,

    PLAYER_COINS,

    PLAYER_POINTS,

    PLAYER_ULTRA_POINTS,

    PLAYER_MEGA_POINTS,

    PLAYER_HEALTH,

    PLAYER_SPEED,

    PLAYER_GRAVITY,

    PLAYER_MONEY,

    PLAYER_DAMAGE,

    PLAYER_LONG_JUMP,

    Float:PLAYER_LONG_JUMP_TIME,

    PLAYER_JUMPS,

    PLAYER_INVISIBLE,

    PLAYER_LIGHTING,

    Float:PLAYER_LIGHTING_TIME,

    PLAYER_STRENGHT,

    PLAYER_RESPAWN,

    PLAYER_CRITICAL,

    PLAYER_FAST_STATS,

    bool:PLAYER_VIP,

    PLAYER_TARGET

}



native exp_get_user_info( id , e_PlayerInfo:iInfoType , {Float,_}:... );

Other plugin:

PHP Code:


			
#include <amxmodx>



enum e_PlayerInfo {

    PLAYER_NICK[33],

    PLAYER_LEVEL,

    PLAYER_EXP,

    PLAYER_COINS,

    PLAYER_POINTS,

    PLAYER_ULTRA_POINTS,

    PLAYER_MEGA_POINTS,

    PLAYER_HEALTH,

    PLAYER_SPEED,

    PLAYER_GRAVITY,

    PLAYER_MONEY,

    PLAYER_DAMAGE,

    PLAYER_LONG_JUMP,

    Float:PLAYER_LONG_JUMP_TIME,

    PLAYER_JUMPS,

    PLAYER_INVISIBLE,

    PLAYER_LIGHTING,

    Float:PLAYER_LIGHTING_TIME,

    PLAYER_STRENGHT,

    PLAYER_RESPAWN,

    PLAYER_CRITICAL,

    PLAYER_FAST_STATS,

    bool:PLAYER_VIP,

    PLAYER_TARGET

}



const MAX_PLAYER = 32;



new any:g_PlayerInfo[ MAX_PLAYER+1 ][ e_PlayerInfo ];



public plugin_natives()

{

    register_native( "exp_get_user_info" , "_get_user_info" );

}



public plugin_init() 

{

    //Set test data to array

    new id = 0;

    

    copy( g_PlayerInfo[ id ][ PLAYER_NICK ] , charsmax( g_PlayerInfo[][ PLAYER_NICK ] ) , "bugsy" );

    g_PlayerInfo[ id ][ PLAYER_LEVEL ] = 1234;

    g_PlayerInfo[ id ][ PLAYER_LONG_JUMP_TIME ] = 56.789;

}



public _get_user_info( iPlugins , iParams )

{

    new iPlayerID = get_param( 1 );

    new iItem = get_param( 2 );

    

    switch ( iParams )

    {

        case 2: return g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ];

        case 3: set_float_byref( 3 , g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ] );

        case 4: set_string( 3 , g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ] , get_param( 4 ) );

    }

    

    return 0;

}

Your plugin:

PHP Code:


			
#include <amxmodx>

#include <nativetest>



new const VERSION[] = "0.1";



public plugin_init() 

{

    register_plugin( "Native test" , VERSION , "bugsy" );

    

    register_concmd( "test" , "test" );

}



public test() 

{    

    new id = 0;

    

    server_print( "Integer value: %d" , exp_get_user_info( id , PLAYER_LEVEL ) );

    

    new Float:fTest;

    exp_get_user_info( id , PLAYER_LONG_JUMP_TIME , fTest );

    server_print( "Float value: %f" , fTest );



    new szNick[ 33 ];

    exp_get_user_info( id , PLAYER_NICK , szNick , charsmax( szNick ) );

    server_print( "String value: %s" , szNick );

}

you don't need to separate floats and integer, at least i haven't had any problems using same native for floats and its. Is there something i dont know about?

**Bugsy** · *Last edited by Bugsy; 02-06-2015 at 18:14.*

Quote:

Originally Posted by .Dare Devil.

you don't need to separate floats and integer, at least i haven't had any problems using same native for floats and its. Is there something i dont know about?

Of course you don't need to, Pawn only has a single data type which is a 4-byte cell so it's all the same. You can either do it how I have it, or tag the native with 'any:' in the .inc and you can return Floats as you do integers. I think my approach is cleaner, at the expense of an extra line of code when used.

If you prefer to return floats and int's the same way, make the following change(s):

PHP Code:


			
//In the inc., tag the native with any:
native any:exp_get_user_info( id , e_PlayerInfo:iInfoType , {Float,_}:... );

//Optional: Remove the below line in the plugin containing the _get_user_info() native function. 
case 3: set_float_byref( 3 , g_PlayerInfo[ iPlayerID ][ e_PlayerInfo:iItem ] );

grs4 · 02-07-2015 , 16:50 Re: How to use native for this ?

I go check then reply an answer

(sr for english, be friendly for poles xD)