[Napoleon_be]

I'm trying to set player models according to which weapon the player is currently wearing, but without success. I'm having this error in my game console with every single model


Error: could not load file models/player/wbm4a1/wbm4a1.mdl

[OciXCrom]

How are you setting the model? Show the code.

[Napoleon_be]

Tried using some code u provided me earlier, here it is.

PHP Code:

#include <amxmodx>
#include <cstrike>

#define PLUGIN "FFA: WeaponBased PlayerModels"
#define VERSION "1.0"
#define AUTHOR "NapoleoN#"

enum _:ModelsInfo
{
    szName[32],
    iWeapon,
    CsTeams:iTeams
}

new szWeapons[][ModelsInfo] =
{
    { "wbknife", CSW_KNIFE },         // Knife
    { "wbawp", CSW_AWP },             // AWP
    { "wbfamas", CSW_FAMAS, CS_TEAM_CT },     // Famas
    { "wbm4a1", CSW_M4A1, CS_TEAM_CT },     // M4A1
    { "wbak47", CSW_AK47, CS_TEAM_T },     // AK47 
    { "wbgalil", CSW_GALIL, CS_TEAM_T },     // Galil
    { "wbtmp", CSW_TMP, CS_TEAM_CT },     // TMP
    { "wbump45", CSW_UMP45 },         // Ump45
    { "wbscout", CSW_SCOUT },         // Scout
    { "wbxm1014", CSW_XM1014 },         // XM1014
    { "wbaug", CSW_AUG, CS_TEAM_CT },     // AUG
    { "wbsg550", CSW_SG550, CS_TEAM_CT },     // SG550
    { "wbmp5navy", CSW_MP5NAVY },         // MP5 Navy
    { "wbm249", CSW_M249 },             // M249
    { "wbm3", CSW_M3 },             // M3
    { "wbg3sg1", CSW_G3SG1, CS_TEAM_T },     // G3SG1
    { "wbsg552", CSW_SG552, CS_TEAM_T }     // SG552
};

precache_player_model(szModel[])
{
    static szFile[128];
    formatex(szFile, charsmax(szFile), "models/player/wbmodels/%s/%s.mdl", szModel, szModel);
    precache_model(szFile);
    replace(szFile, charsmax(szFile), ".mdl", "T.mdl");

    if(file_exists(szFile))
    {
        precache_model(szFile);
    }
}

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_event("CurWeapon", "CheckWeapons", "be", "1=1");
}

public plugin_precache()
{
    for(new i; i < sizeof(szWeapons); i++)
    {
        precache_player_model(szWeapons[i][szName]);
    }
}

public CheckWeapons(id)
{
    for(new i; i < sizeof(szWeapons); i++)
    {
        if(get_user_weapon(id) == szWeapons[i][iWeapon])
        {
            if(cs_get_user_team(id) & szWeapons[i][iTeams]) 
            {
                cs_set_user_model(id, szWeapons[i][szName]);
                break;
            }
        }
    }
} 


[HamletEagle]

I am not sure, but I do not think you can have subfolders for player models. For example a model called test.mdl should be inside models/player/test/test.mdl not models/player/subfolder/test/test.mdl

[Napoleon_be]

Originally Posted by HamletEagle I am not sure, but I do not think you can have subfolders for player models. For example a model called test.mdl should be inside models/player/test/test.mdl not models/player/subfolder/test/test.mdl

I'll try that out.

[OciXCrom]

That's right. Player model paths are hardcoded in the engine. You musy obey the path rule for all models, so don't change the one I put in the function.

[Napoleon_be]

Thanks for the help, that solved my problem

[Napoleon_be]

One more question about the code, as u can see i specify models to be set only for certain teams since certain guns are only available to T's or CT's. So the problem is that i have empty spaces that should fill in the team, causing my models not to be set, how can i fix this?

Current code:

PHP Code:

new szWeapons[][ModelsInfo] =
{
    { "wbknife", CSW_KNIFE },         // Knife    - DOESN'T WORK - REPLACED
    { "wbawp", CSW_AWP },             // AWP        - DOESN'T WORK - REPLACED
    { "wbfamas", CSW_FAMAS, CS_TEAM_CT },     // Famas    - WORKS
    { "wbm4a1", CSW_M4A1, CS_TEAM_CT },     // M4A1     - WORKS
    { "wbak47", CSW_AK47, CS_TEAM_T },     // AK47     - DOESN'T WORK - REPLACED
    { "wbgalil", CSW_GALIL, CS_TEAM_T },     // Galil    - DOESN'T WORK - REPLACED
    { "wbtmp", CSW_TMP, CS_TEAM_CT },     // TMP        - DOESN'T WORK - REPLACED
    { "wbump45", CSW_UMP45 },         // Ump45    - DOESN'T WORK - REPLACED
    { "wbscout", CSW_SCOUT },         // Scout    - DOESN'T WORK - REPLACED
    { "wbxm1014", CSW_XM1014 },         // XM1014    - DOESN'T WORK - REPLACED
    { "wbaug", CSW_AUG, CS_TEAM_CT },     // AUG         - DOESN'T WORK - REPLACED
    { "wbsg550", CSW_SG550, CS_TEAM_CT },     // SG550    - WORKS
    { "wbmp5navy", CSW_MP5NAVY },         // MP5 Navy    - DOESN'T WORK - REPLACED
    { "wbm249", CSW_M249 },             // M249        - DOESN'T WORK - REPLACED
    { "wbm3", CSW_M3 },             // M3        - DOESN'T WORK - REPLACED
    { "wbg3sg1", CSW_G3SG1, CS_TEAM_T },     // G3SG1    - WORKS
    { "wbsg552", CSW_SG552, CS_TEAM_T }     // SG552    - DOESN'T WORK - REPLACED
}; 


how i set my models

PHP Code:

public CheckWeapons(id)
{
    for(new i; i < sizeof(szWeapons); i++)
    {
        if(get_user_weapon(id) == szWeapons[i][iWeapon])
        {
            if(cs_get_user_team(id) & szWeapons[i][iTeams]) 
            {
                cs_set_user_model(id, szWeapons[i][szName]);
                break;
            }
        }
        else
        {
            cs_reset_user_model(id);
        }
    }
} 


[Bugsy]

Try this:

PHP Code:

new szWeapons[][ ModelsInfo ] =
{
    { "wbknife", CSW_KNIFE , CS_TEAM_UNASSIGNED },         // Knife    - DOESN'T WORK - REPLACED
    { "wbawp", CSW_AWP , CS_TEAM_UNASSIGNED },             // AWP        - DOESN'T WORK - REPLACED
    { "wbfamas", CSW_FAMAS, CS_TEAM_CT },     // Famas    - WORKS
    { "wbm4a1", CSW_M4A1, CS_TEAM_CT },     // M4A1     - WORKS
    { "wbak47", CSW_AK47, CS_TEAM_T },     // AK47     - DOESN'T WORK - REPLACED
    { "wbgalil", CSW_GALIL, CS_TEAM_T },     // Galil    - DOESN'T WORK - REPLACED
    { "wbtmp", CSW_TMP, CS_TEAM_CT },     // TMP        - DOESN'T WORK - REPLACED
    { "wbump45", CSW_UMP45 , CS_TEAM_UNASSIGNED},         // Ump45    - DOESN'T WORK - REPLACED
    { "wbscout", CSW_SCOUT , CS_TEAM_UNASSIGNED},         // Scout    - DOESN'T WORK - REPLACED
    { "wbxm1014", CSW_XM1014 , CS_TEAM_UNASSIGNED},         // XM1014    - DOESN'T WORK - REPLACED
    { "wbaug", CSW_AUG, CS_TEAM_CT },     // AUG         - DOESN'T WORK - REPLACED
    { "wbsg550", CSW_SG550, CS_TEAM_CT },     // SG550    - WORKS
    { "wbmp5navy", CSW_MP5NAVY , CS_TEAM_UNASSIGNED},         // MP5 Navy    - DOESN'T WORK - REPLACED
    { "wbm249", CSW_M249 , CS_TEAM_UNASSIGNED},             // M249        - DOESN'T WORK - REPLACED
    { "wbm3", CSW_M3 , CS_TEAM_UNASSIGNED},             // M3        - DOESN'T WORK - REPLACED
    { "wbg3sg1", CSW_G3SG1, CS_TEAM_T },     // G3SG1    - WORKS
    { "wbsg552", CSW_SG552, CS_TEAM_T }     // SG552    - DOESN'T WORK - REPLACED
}; 

public CheckWeapons(id)
{
    new iWeapon = get_user_weapon( id );
    new CsTeams:csTeam = cs_get_user_team( id );
    
    for ( new i = 0 ; i < sizeof( szWeapons ) ; i++ )
    {
        if ( iWeapon == szWeapons[ i ][ WeaponID ] )
        {
            if ( ( szWeapons[ i ][ TeamID ] == CS_TEAM_UNASSIGNED ) || ( csTeam == szWeapons[ i ][ TeamID ] ) ) 
            {
                cs_set_user_model( id , szWeapons[ i ][ szModel ] );
            }
            else
            {
                cs_reset_user_model( id );
            }
            
            break;
        }
    }
} 


[Napoleon_be]

Awesome, thanks Bugsy. Worked like a charm