[asherkin]

Originally Posted by snelvuur On the first page there is a plugin called scoutsdontteleport. Referring to that part.

Your best bet would be to port it to SM 1.5's forward and switch.

[Dr. McKay]

Yeah, this extension is now redundant because it's built into SourceMod 1.5 (and it's better). I've attached a version of the plugin in the OP that ought to work.

[snelvuur]

Thanks McKay

[snelvuur]

So since scouts are just going "hmm why cant i teleport?" i added

PrintHintText(client, "Scouts cannot use teleports, go run and be usefull");

But this would just trigger non-stop, which is not so nice. Whats the best way to make it only trigger once?

[Dr. McKay]

Originally Posted by snelvuur So since scouts are just going "hmm why cant i teleport?" i added PrintHintText(client, "Scouts cannot use teleports, go run and be usefull"); But this would just trigger non-stop, which is not so nice. Whats the best way to make it only trigger once?

Create a global array of size MAXPLAYERS + 1 and store the time when you call PrintHintText using GetTime. Then on subsequent calls to the forward, check if GetTime() - myArrayHere[client] <= 5, and if it is, don't do anything.

[snelvuur]

And there i thought i could just do a "wait(10)" or something. I'll look into it if i find some time, its a good learn for me.

[Dr. McKay]

This ought to work, take a look at it for learning:

PHP Code:

#include <sourcemod>
#include <tf2>
#include <tf2_stocks>

new Handle:g_hCvarEnabled;
new g_iMsgTime[MAXPLAYERS + 1];

public Plugin:myinfo = 
{
    name = "Scouts Can't Teleport",
    author = "Afronanny + Dr. McKay",
    description = "Scouts cannot take teleporters",
    version = "1.0",
    url = "http://www.afronanny.org/"
}

public OnPluginStart()
{
    CreateConVar("sm_teleportcheck_version", "1.0", _, FCVAR_NOTIFY);
    g_hCvarEnabled = CreateConVar("sm_teleportcheck_enabled", "1");
}

public Action:TF2_OnPlayerTeleport(client, teleporter, &bool:result)
{
    if (TF2_GetPlayerClass(client) == TFClass_Scout && GetConVarBool(g_hCvarEnabled))
    {
        if((GetTime() - g_iMsgTime[client]) > 5) {
            g_iMsgTime[client] = GetTime();
            PrintHintText(client, "Scouts cannot use teleports.\nGo run and be useful.");
        }
        result = false;
        return Plugin_Changed;
    } else {
        return Plugin_Continue;
    }
} 


[snelvuur]

The result looks easier then i thought, basicly you just store the time for the client and match that with the next action. Thanks for the lesson, i'll go try it out.

[CuriousG]

Originally Posted by snelvuur The result looks easier then i thought, basicly you just store the time for the client and match that with the next action. Thanks for the lesson, i'll go try it out.

And he even fixed your spelling mistake.

[AjudanteBR]

This plugin works on the "left 4 dead 2"?