[srvmil]

Whenever CT shoots the Terrorist and dies, it should play the dead sound to the victim who died.

However, sound file is only for Terrorist as this is for mod, CT dead sound should remain default. Is there any ways to change the death sound for Terrorist?

I know there is a plugin that exist but it didn't work for CSGO as it won't play the file or something.
https://forums.alliedmods.net/showthread.php?p=2310483

[PinHeaDi]

PHP Code:

#include <sourcemod>
#include <cstrike>
#include <emitsoundany>

public void OnPluginStart()
{
    HookEvent("player_death", PlayerDeath);
}

public OnMapStart()
{
    AddFileToDownloadsTable("sound/sourcemod/customdeathsound/sound.mp3");
    PrecacheSoundAny("sourcemod/customdeathsound/sound.mp3");
} 

public Action PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    int team = GetClientTeam(client);

    if(team == CS_TEAM_T && IsValidClient(client))
    {
        EmitSoundToClientAny(client, "sourcemod/customdeathsound/sound.mp3");
    }

    return Plugin_Continue;
}

public bool IsValidClient(int client)
{
    if(client <= 0 ) return false;
    if(client > MaxClients) return false;
    if(!IsClientConnected(client)) return false;
    return IsClientInGame(client);
} 


[Franc1sco]

I did this plugin a few days ago for @srvmil

My plugin blocks the default death sound and emit a new one.

[Lannister]

Age of Empires death sounds incoming, seems like a really good idea, by the way, it is possible to add multiple sounds and play them randomly when a player dies? would be interesting to have that instead of just 1 sound.

Thanks!

[PinHeaDi]

Originally Posted by Lannister Age of Empires death sounds incoming, seems like a really good idea, by the way, it is possible to add multiple sounds and play them randomly when a player dies? would be interesting to have that instead of just 1 sound. Thanks!

PHP Code:

public Action OnNormalSoundPlayed(int clients[64], int &numClients, char sample[PLATFORM_MAX_PATH], int &entity, int &channel, float &volume, int &level, int &pitch, int &flags)
{
    if(entity && entity <= MaxClients)
    {
        if(StrContains(sample, "death") != -1 && GetClientTeam(entity) == CS_TEAM_T)
        {
            // Block current death sound and emit a new one
            switch(GetRandomInt(1, 5))
            {
                case 1: EmitSoundToAllAny("zr/zombie_die1.mp3");
                case 2: EmitSoundToAllAny("zr/zombie_die2.mp3");
                case 3: EmitSoundToAllAny("zr/zombie_die3.mp3");
                case 4: EmitSoundToAllAny("zr/zombie_die4.mp3");
                case 5: EmitSoundToAllAny("zr/zombie_die5.mp3");
            }
            return Plugin_Handled;
        }
    }
    return Plugin_Continue;
} 


Of course you must precache all souns(PrecacheSoundAny) and add them to the download table(AddFileToDownloadsTable).