[LegacyCode]

Hello,

so, I made this: https://forums.alliedmods.net/showpo...&postcount=172
But I'm 99.9% certain that my edit is far from being good, so I would like to ask for help here
I know I'm still making dumb mistakes, please bear with me.

One player reported a "CL_Flush Entity Packet" error but I'm not sure if it's related to the edit I made.

Edited lines:

Global scope

PHP Code:

#define MIN_CTS_BOMBSITE 7
#define HUD_BOMBSITE_DURATION 4.0
#define TASK_SHOW_BLOCK 3000
new bool:g_BlockBombsite,
    bool:g_HasBombsiteBlock,
    g_CountCTs, g_HudBombsiteBlocked,
    g_BlockBombsiteStr[2] 


PHP Code:

public plugin_precache() {
    [...]
    g_HudBombsiteBlocked = CreateHudSyncObj()
} 


Modified DrawLine

PHP Code:

public draw_block_line(Float:x1, Float:y1, Float:z1, Float:x2, Float:y2, Float:z2, color[3]) {
    new start[3]
    new stop[3]

    start[0] = floatround( x1 )
    start[1] = floatround( y1 )
    start[2] = floatround( z1 )

    stop[0] = floatround( x2 )
    stop[1] = floatround( y2 )
    stop[2] = floatround( z2 )

    message_begin( MSG_BROADCAST, SVC_TEMPENTITY )

    write_byte( TE_BEAMPOINTS )

    write_coord(start[0])
    write_coord(start[1])
    write_coord(start[2])

    write_coord(stop[0])
    write_coord(stop[1])
    write_coord(stop[2])

    write_short( spr_dot )

    write_byte( 1 )    // framestart
    write_byte( 1 )    // framerate
    write_byte( 4 )    // life in 0.1's
    write_byte( 25 )    // width
    write_byte( 0 )     // noise

    write_byte( color[0] )   // r, g, b
    write_byte( color[1] )   // r, g, b
    write_byte( color[2] )   // r, g, b

    write_byte( 200 )      // brightness
    write_byte( 0 )       // speed

    message_end()
} 


Modified ShowZoneBox to work without editor (show to all players)

PHP Code:

public show_zone_cross(entity)
{
    entity -= TASK_SHOW_BLOCK
    if (!pev_valid(entity)) return

    new Float:pos[3]
    pev(entity, pev_origin, pos)

    new Float:mins[3], Float:maxs[3]
    pev(entity, pev_mins, mins)
    pev(entity, pev_maxs, maxs)

    mins[0] += pos[0]
    mins[1] += pos[1]
    mins[2] += pos[2]
    maxs[0] += pos[0]
    maxs[1] += pos[1]
    maxs[2] += pos[2]

    // x
    draw_block_line(maxs[0], maxs[1], maxs[2], maxs[0], mins[1], mins[2], zone_color_red)
    draw_block_line(maxs[0], maxs[1], mins[2], maxs[0], mins[1], maxs[2], zone_color_red)
    draw_block_line(mins[0], maxs[1], maxs[2], mins[0], mins[1], mins[2], zone_color_red)
    draw_block_line(mins[0], maxs[1], mins[2], mins[0], mins[1], maxs[2], zone_color_red)
    // y
    draw_block_line(mins[0], mins[1], mins[2], maxs[0], mins[1], maxs[2], zone_color_red)
    draw_block_line(maxs[0], mins[1], mins[2], mins[0], mins[1], maxs[2], zone_color_red)
    draw_block_line(mins[0], maxs[1], mins[2], maxs[0], maxs[1], maxs[2], zone_color_red)
    draw_block_line(maxs[0], maxs[1], mins[2], mins[0], maxs[1], maxs[2], zone_color_red)
    // z
    draw_block_line(maxs[0], maxs[1], maxs[2], mins[0], mins[1], maxs[2], zone_color_red)
    draw_block_line(maxs[0], mins[1], maxs[2], mins[0], maxs[1], maxs[2], zone_color_red)
    draw_block_line(maxs[0], maxs[1], mins[2], mins[0], mins[1], mins[2], zone_color_red)
    draw_block_line(maxs[0], mins[1], mins[2], mins[0], maxs[1], mins[2], zone_color_red)
} 


Execute on each Event_RoundStart()

PHP Code:

check_bombsite_availability()
{
    new n_Players, a_Players[32]
    get_players( a_Players, n_Players )

    // reset
    g_CountCTs = 0
    g_HasBombsiteBlock = false

    for ( new i; i < n_Players; i++ )
    {
        if ( cs_get_user_team(a_Players[i]) == CS_TEAM_CT )
            g_CountCTs++
    }

    g_BlockBombsite = !(g_CountCTs >= MIN_CTS_BOMBSITE)

    for ( new i; i < maxzones; i++ )
    {
        new z = zone[i]
        new zm = pev(z, ZONEID)

        if ( ZONEMODE:zm == ZM_BLOCK_ALL_BOMBSITE_A || ZONEMODE:zm == ZM_BLOCK_ALL_BOMBSITE_B )
        {
            g_HasBombsiteBlock = true

            if ( g_BlockBombsite )
            {
                set_pev( z, pev_solid, SOLID_BBOX )

                remove_task( TASK_SHOW_BLOCK + z )
                set_task( 0.2, "show_zone_cross", TASK_SHOW_BLOCK + z, _, _, "b" )

                if ( ZONEMODE:zm == ZM_BLOCK_ALL_BOMBSITE_A )
                    formatex( g_BlockBombsiteStr, charsmax(g_BlockBombsiteStr), "A" )
                else
                    formatex( g_BlockBombsiteStr, charsmax(g_BlockBombsiteStr), "B" )
            }
            else
            {
                set_pev( z, pev_solid, SOLID_NOT )

                if ( task_exists( TASK_SHOW_BLOCK + z ) )
                    remove_task( TASK_SHOW_BLOCK + z )
            }
        }
    }

    if ( g_BlockBombsite && n_Players > 0 && g_HasBombsiteBlock )
    {
        for ( new i; i < n_Players; i++ )
        {
            if ( !is_user_connected(a_Players[i]) ) continue

            if ( is_user_alive(a_Players[i]) )
            {
                set_hudmessage( 255, 0, 0, -1.0, 0.2, 0, 3.0, HUD_BOMBSITE_DURATION, 0.5, 1.0, -1 )
                ShowSyncHudMsg( a_Players[i], g_HudBombsiteBlocked, "%L", a_Players[i], "WALKGUARD_BLOCK_BOMBSITE_HUD", MIN_CTS_BOMBSITE, g_BlockBombsiteStr )
            }
        }

        return
    }

    return
} 


PHP Code:

public Event_RoundStart() {
    [...]
    check_bombsite_availability()
} 


PHP Code:

public ZoneTouch(player, zone) {
    [...]

    if ( ZONEMODE:zm == ZM_BLOCK_ALL_BOMBSITE_A || ZONEMODE:zm == ZM_BLOCK_ALL_BOMBSITE_B )
    {
        if ( g_BlockBombsite )
        {
            client_print( player, print_center, "%L", player, "WALKGUARD_BLOCK_BOMBSITE_PRINT", g_BlockBombsiteStr, MIN_CTS_BOMBSITE )
        }
    }

    [...]
} 


I hope you guys can help make this code great again.
A message that only shows once after all bombsites are enabled again would be cool too, and I already had it working, but then I got lost again and ended up deleting it...

- LegacyCode

[LegacyCode]

Hello,

so I've just encountered a "Reliable channel overflowed" when touching a block like this.
This only happened for the first time on a map where I have like 8+ of these blocks.
What could it be?

//e:
I can only think of "client_print()" in "ZoneTouch()"... but I guess some expert can enlighten me here. Will test without client_print().

//e2:
I set sv_gravity to 200 and spam-touched (jump + duck) the block. This also happens with only one of these blocks, but only with client_print() and sv_gravity not being 800. Does anyone know how to solve this?
Only allow printing the message once every x seconds for a player?

//e3:
This whole stuff lags the server like hell, I suppose because it shows the crosses the whole time. I really need your help

- LegacyCode

[JusTGo]

your are sending to many messages, if you remove the show crosses and client_print you will not get more over flows

[LegacyCode]

Hello,

yeah, that's what I thought. But I need an indicator for a blocked zone, preferably that red cross.
Any ideas how I can accomplish this without a massive performance hit?

Also it should draw that red cross on all sites of the block, because someone could block a zone on the ground, etc.
I would like to avoid any custom stuff like textures/sprites, too.

- LegacyCode

[JusTGo]

you have to spawn an entity give it a model (wall model or any thing that you want). then remove it when not needed that way you don't need to keep sending the show cross each 0.2 sec

[LegacyCode]

Hello,

what I did for now:

- increasing the task time to 1.0 (instead of 0.2)
- only show one side of the block (x/y) by comparing the size with pev_size
(- always show top z)
- set a task when player touches a bombsite block, to only show the message every 5 seconds

This should at least decrease the performance hit a bit for now, as it only draws a max of 4 lines at once for a box instead of 12.

PHP Code:

public show_zone_cross(entity)
{
    entity -= TASK_SHOW_BLOCK
    if (!pev_valid(entity)) return

    new Float:pos[3]
    pev(entity, pev_origin, pos)

    new Float:size[3], Float:mins[3], Float:maxs[3]
    pev(entity, pev_size, size)
    pev(entity, pev_mins, mins)
    pev(entity, pev_maxs, maxs)

    mins[0] += pos[0]
    mins[1] += pos[1]
    mins[2] += pos[2]
    maxs[0] += pos[0]
    maxs[1] += pos[1]
    maxs[2] += pos[2]

    if ( size[0] < size[1] )
    {
        // x
        draw_block_line(maxs[0], maxs[1], maxs[2], maxs[0], mins[1], mins[2], zone_color_red)
        draw_block_line(maxs[0], maxs[1], mins[2], maxs[0], mins[1], maxs[2], zone_color_red)
    }
    else if ( size[0] > size[1] )
    {
        // y
        draw_block_line(mins[0], mins[1], mins[2], maxs[0], mins[1], maxs[2], zone_color_red)
        draw_block_line(maxs[0], mins[1], mins[2], mins[0], mins[1], maxs[2], zone_color_red)
    }

    // z
    draw_block_line(maxs[0], maxs[1], maxs[2], mins[0], mins[1], maxs[2], zone_color_red)
    draw_block_line(maxs[0], mins[1], maxs[2], mins[0], maxs[1], maxs[2], zone_color_red)
} 


Originally Posted by JusTGo you have to spawn an entity give it a model (wall model or any thing that you want). then remove it when not needed that way you don't need to keep sending the show cross each 0.2 sec

I want to avoid any custom models clients would have to download...

- LegacyCode

[JusTGo]

one model/sprite is not much

[LegacyCode]

Originally Posted by JusTGo one model/sprite is not much

Still, I myself used to have cl_allowdownload 0 and I'm only editing the already existing WalkGuard plugin here, which also doesn't require any downloads.

- LegacyCode

[LegacyCode]

Hello,

The lines now only show to the specific player (not like before via MSG_BROADCAST).
I'm now trying to apply a basic grid of points to the side where it shows the cross:

PHP Code:

                // y
                draw_block_line(mins[0], mins[1], mins[2], maxs[0], mins[1], maxs[2], {0,230,0}, p_userid)
                draw_block_line(maxs[0], mins[1], mins[2], mins[0], mins[1], maxs[2], {0,230,0}, p_userid)

                for ( new i_col; i_col < maxcols; i_col++ )
                    for ( new i_row; i_row < maxrows; i_row++ )
                        draw_block_line(
                            grid_x+(m[0]*i_col), grid_y, grid_z+(m[2]*i_row),
                            grid_x+(m[0]*i_col)+1, grid_y+1, grid_z+(m[2]*i_row)+1,
                            {255,255,255},
                            p_userid
                        ) 


I saw a "fm_trace_line()" function which I would use to check if any of those points are visible for the player.
If not, it doesn't draw the cross. Is this a "good" solution, or am I overthinking this? There must be a better way to deal with this...

//e:
Current status:


I currently use

PHP Code:

#define BLOCK_VISIBILITY_ACCURACY 11

// the check
fm_is_visible(p_userid, point_pos) && fm_is_in_viewcone(p_userid, point_pos) 


to define 11 points per col/row to check in combination with fm_is_visible & fm_is_in_viewcone.
Everything works now. Will test and optimize this a little further, hoping someone stumbles across this thread with better knowledge.

- LegacyCode

[JusTGo]

check your pm i sended you a plugin that does what you want.